-
Notifications
You must be signed in to change notification settings - Fork 10
/
Copy pathannotations-dynamic_html.adb
1285 lines (1043 loc) · 40.8 KB
/
annotations-dynamic_html.adb
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
------------------------------------------------------------------------------
-- --
-- GNATcoverage --
-- --
-- Copyright (C) 2013-2024, AdaCore --
-- --
-- GNATcoverage is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This software is distributed in the hope that it will be useful --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
-- License for more details. You should have received a copy of the GNU --
-- General Public License distributed with this software; see file --
-- COPYING3. If not, go to http://www.gnu.org/licenses for a complete copy --
-- of the license. --
------------------------------------------------------------------------------
with Ada.Characters.Handling; use Ada.Characters.Handling;
with Ada.Directories; use Ada.Directories;
with Ada.Exceptions; use Ada.Exceptions;
with Ada.Text_IO;
with Ada.Text_IO.Unbounded_IO;
with GNATCOLL.JSON; use GNATCOLL.JSON;
with GNATCOLL.VFS; use GNATCOLL.VFS;
with GNAT.OS_Lib;
with GNAT.Regpat; use GNAT.Regpat;
with Annotations.Html;
with Hex_Images;
with Interfaces;
with Outputs;
with Project;
with Support_Files; use Support_Files;
with Switches; use Switches;
with Traces_Disa;
with Traces_Files; use Traces_Files;
-- This package generates a dynamic HTML report, i.e. an HTML document heavily
-- relying on JavaScript for presenting advanced graphical components.
--
-- It requires additional resources (CSS and JavaScript) to be installed as a
-- plugin to the GNATcoverage installation. It produces one HTML file
-- containing the JS application and multiple JS files containing the data
-- associatied with each source from the project being analyzed.
--
-- Splitting the coverage data into multiple JS files addresses a load-time
-- issue since the final set of data generated can be large enough (several
-- Mbs) for browsers to take several seconds to load the whole report. The
-- current implementation splits the coverage data of each source file in
-- separate JS file that are lazily loaded by the report application upon
-- request, i.e. when we need to display detailed coverage information for a
-- specific file.
package body Annotations.Dynamic_Html is
GNATquilt_Dir : constant String := Support_Files.In_Lib_Dir ("gnatquilt");
type Dynamic_Html is new Pretty_Printer with record
-- Pretty printer type for the Dynamic HTML annotation format
JSON : JSON_Value := Create_Object;
-- The JSON root. The Dynamic_Html builder will progressively populate
-- this node with children. It will then be written into a <script>
-- section in the final HTML document.
Current_Mapping : JSON_Value;
-- A line mapping structure, containing the coverage results for the
-- given line. This correspond to the mapping currently being generated
-- by the Dynamic_Html builder. It is stored in Current_Mappings by the
-- Pretty_Print_End_Line procedure.
Current_Mappings : JSON_Array;
-- The list of all mappings for the file being currently processed by
-- the builder. It is stored in the "sources" attributes of the JSON
-- root by Pretty_Print_End_File.
Current_SCOs : JSON_Array;
-- The SCOs list attached to the line currently being processed. It is
-- stored in the Current_Mapping by Pretty_Print_End_Line if not empty.
Current_Decision : JSON_Value;
-- The current decision being processed by the builder. It is stored in
-- Current_SCOs by the Pretty_Print_End_Decision procedure.
Current_Conditions : JSON_Array;
-- The condition list attached to the line currently being processed. It
-- is stored in the Current_Decision by Pretty_Print_End_Decision if not
-- empty.
Current_Insn_Set : JSON_Value;
-- The current instruction set being processed by the builder. It is
-- stored as "instruction_set" in the Current_Mapping by
-- Pretty_Print_End_Instruction_Set.
Current_Insn_Block : JSON_Value;
-- The current instruction block being processed by the builder. It is
-- stored in Current_Insn_Blocks by Pretty_Print_End_Symbol.
Current_Insn_Blocks : JSON_Array;
-- The instruction block list attached to the line currently being
-- processed. It is stored in Current_Insn_Set by
-- Pretty_Print_End_Instruction_Set if not empty.
Current_Insns : JSON_Array;
-- The instruction list attached to the line currently being processed.
-- It is stored in Current_Insn_Block by Pretty_Print_End_Symbol if not
-- empty.
Current_Source : JSON_Value;
-- The current source being processed by the builder
Source_List : JSON_Array;
-- The sources array in the index, containing all source mappings
Title_Prefix : Unbounded_String;
-- Prefix to use for titles in generated HTML documents
Scope_Metrics : JSON_Value;
-- The scoped metrics, e.g. stats for subprograms bodies in a package
-- body, organized in a tree fashion.
end record;
overriding function Format
(Pp : Dynamic_Html) return Annotation_Format_Family
is (Annotate_Html);
-----------------------------------------
-- Dynamic_Html's primitive operations --
-- (inherited from Pretty_Printer) --
-----------------------------------------
procedure Pretty_Print_Start (Pp : in out Dynamic_Html);
procedure Pretty_Print_End (Pp : in out Dynamic_Html);
procedure Pretty_Print_Start_File
(Pp : in out Dynamic_Html;
File : Source_File_Index;
Skip : out Boolean);
procedure Pretty_Print_End_File (Pp : in out Dynamic_Html);
procedure Pretty_Print_Scope_Entities
(Pp : in out Dynamic_Html;
File : Source_File_Index;
Scope_Entities : Scope_Entities_Tree);
procedure Pretty_Print_Start_Line
(Pp : in out Dynamic_Html;
Line_Num : Natural;
Info : Line_Info_Access;
Line : String);
procedure Pretty_Print_End_Line (Pp : in out Dynamic_Html);
procedure Pretty_Print_SCO
(Pp : in out Dynamic_Html'Class;
SCO : SCO_Id;
State : Line_State;
Kind : SCO_Kind);
procedure Pretty_Print_Statement
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State);
procedure Pretty_Print_Fun
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State);
procedure Pretty_Print_Call
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State);
procedure Pretty_Print_Start_Decision
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State);
procedure Pretty_Print_End_Decision (Pp : in out Dynamic_Html);
procedure Pretty_Print_Condition
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State);
procedure Pretty_Print_Message
(Pp : in out Dynamic_Html;
M : Message);
procedure Pretty_Print_Start_Instruction_Set
(Pp : in out Dynamic_Html;
State : Any_Line_State);
procedure Pretty_Print_End_Instruction_Set
(Pp : in out Dynamic_Html);
procedure Pretty_Print_Start_Symbol
(Pp : in out Dynamic_Html;
Name : String;
Offset : Pc_Type;
State : Line_State);
procedure Pretty_Print_End_Symbol (Pp : in out Dynamic_Html);
procedure Pretty_Print_Insn
(Pp : in out Dynamic_Html;
Pc : Pc_Type;
State : Insn_State;
Insn : Binary_Content;
Insn_Set : Insn_Set_Type;
Sym : Symbolizer'Class);
-------------------------------------------------
-- Wrappers for efficient unbounded string I/O --
-------------------------------------------------
-- These wrappers around New_Line and Write use GNAT-specific unbounded
-- string APIs to avoid copying full strings over the secondary stack.
procedure NL (Output : Ada.Text_IO.File_Type)
with Pre => Ada.Text_IO.Is_Open (Output);
-- Write a New_Line into Output
procedure W
(Item : String;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
with Pre => Ada.Text_IO.Is_Open (Output);
-- Write Item (String) into Output
procedure W
(Item : Unbounded_String;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
with Pre => Ada.Text_IO.Is_Open (Output);
-- Write Item (Unbounded String) into Output
procedure W
(Item : JSON_Value;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
with Pre => Ada.Text_IO.Is_Open (Output);
-- Write Item (JSON value) into Output
----------------------
-- Internal Helpers --
----------------------
procedure Set_SCO_Fields
(Obj : JSON_Value;
SCO : SCO_Id;
State : Line_State;
Kind : SCO_Kind);
-- Set the following field to the given JSON object:
-- * id
-- * text
-- * coverage
-- * range
function Src_Range (SCO : SCO_Id) return JSON_Array;
-- Return a JSON array for the range Sloc_Start .. Sloc_End from SCO
function Get_Hunk_Filename (File : Source_File_Index) return String;
-- Return the name of the file containing the coverage data for the
-- given source file.
function To_JSON (Stats : Counter_Array) return JSON_Value;
-- JSONify line statistics
function To_JSON (Ob_Stats : Ob_Stat_Array) return JSON_Array;
-- JSONify obligation statistics
procedure Write_Full_Report (Pp : Dynamic_Html'Class);
-- Dump the HTML file into Filename, inlining both JS and CSS resources
-- (see JS_Source and CSS_Source) and embedding the JSON object as well.
---------------
-- Installed --
---------------
function Installed return Boolean is
begin
return Exists (GNATquilt_Dir);
end Installed;
---------------------
-- Generate_Report --
---------------------
procedure Generate_Report
(Context : Coverage.Context_Access;
Report_Title : Command_Line.Parser.String_Option)
is
Pp : Dynamic_Html :=
(Need_Sources => True,
Context => Context,
Title_Prefix => Annotations.Html.Title_Prefix (Report_Title),
others => <>);
begin
Annotations.Generate_Report
(Pp,
Show_Details => True,
Subdir => "html");
end Generate_Report;
------------------------
-- Pretty_Print_Start --
------------------------
procedure Pretty_Print_Start (Pp : in out Dynamic_Html)
is
Traces : JSON_Array;
-- The array of trace records
procedure Append_Coverage_Info;
-- Generate generic coverage attributes
procedure Append_Traces_List;
-- Generate trace information record
--------------------------
-- Append_Coverage_Info --
--------------------------
procedure Append_Coverage_Info is
use Coverage;
begin
Pp.JSON.Set_Field ("coverageLevel", Coverage_Option_Value);
end Append_Coverage_Info;
------------------------
-- Append_Traces_List --
------------------------
procedure Append_Traces_List is
procedure Process_Trace (TF : Trace_File_Element);
-- Generate the record from the TF trace file and append it to the
-- JSON array Traces.
-------------------
-- Process_Trace --
-------------------
procedure Process_Trace (TF : Trace_File_Element) is
Orig_Context : constant String := Original_Processing_Context (TF);
Trace : constant JSON_Value := Create_Object;
begin
Trace.Set_Field ("filename", TF.Filename);
Trace.Set_Field ("kind", Image (TF.Kind));
Trace.Set_Field ("program", TF.Program_Name);
Trace.Set_Field ("date", TF.Time);
Trace.Set_Field ("tag", TF.User_Data);
-- For a trace that has been processed in an earlier run, provide
-- information on original coverage assessment context.
if Orig_Context /= "" then
Trace.Set_Field ("processed", Orig_Context);
end if;
Append (Traces, Trace);
end Process_Trace;
begin
Iterate_On_Traces_Files (Process_Trace'Access);
Pp.JSON.Set_Field ("traces", Traces);
end Append_Traces_List;
begin
Append_Coverage_Info;
Append_Traces_List;
end Pretty_Print_Start;
----------------------
-- Pretty_Print_End --
----------------------
procedure Pretty_Print_End (Pp : in out Dynamic_Html) is
begin
Pp.JSON.Set_Field ("sources", Pp.Source_List);
Write_Full_Report (Pp);
end Pretty_Print_End;
-----------------------------
-- Pretty_Print_Start_File --
-----------------------------
procedure Pretty_Print_Start_File
(Pp : in out Dynamic_Html;
File : Source_File_Index;
Skip : out Boolean)
is
use Coverage;
use Project;
Info : constant File_Info_Access := Get_File (File);
Source : constant JSON_Value := Create_Object;
Line_Stats : constant JSON_Value := Create_Object;
begin
Clear (Pp.Current_Mappings);
Clear (Pp.Current_SCOs);
Clear (Pp.Current_Conditions);
Pp.Scope_Metrics := JSON_Null;
Skip := False;
Source.Set_Field ("missingSource", not Info.Has_Source);
-- Compute the coverage stats and store them into a JSON dictionary
Line_Stats.Set_Field ("noCode", Info.Li_Stats (No_Code));
Line_Stats.Set_Field ("covered", Info.Li_Stats (Covered));
Line_Stats.Set_Field
("partiallyCovered", Info.Li_Stats (Partially_Covered));
Line_Stats.Set_Field ("notCovered", Info.Li_Stats (Not_Covered));
Line_Stats.Set_Field ("notCoverable", Info.Li_Stats (Not_Coverable));
Line_Stats.Set_Field
("undeterminedCoverage", Info.Li_Stats (Undetermined_Coverage));
Line_Stats.Set_Field
("disabledCoverage", Info.Li_Stats (Disabled_Coverage));
Line_Stats.Set_Field
("exemptedNoViolation", Info.Li_Stats (Exempted_No_Violation));
Line_Stats.Set_Field
("exemptedWithViolation", Info.Li_Stats (Exempted_With_Violation));
Line_Stats.Set_Field
("exemptedWithUndetCov",
Info.Li_Stats (Exempted_With_Undetermined_Cov));
-- Generate the JSON object for this source file
Source.Set_Field ("filename", Get_Unique_Name (File));
Source.Set_Field ("hunkFilename", Get_Hunk_Filename (File));
Source.Set_Field ("coverageLevel", Coverage_Option_Value);
Source.Set_Field ("liStats", Line_Stats);
Source.Set_Field ("enAllStats", To_JSON (Info.Ob_Stats));
-- Set the language for this source file
if Is_Project_Loaded then
-- If the project was loaded, get the language information from it
declare
Lang : constant String :=
Project.Project.Info (Create (+Info.Full_Name.all)).Language;
begin
case To_Language_Or_All (Lang) is
when Ada_Language =>
Source.Set_Field ("language", "ada");
when C_Language =>
Source.Set_Field ("language", "c");
when CPP_Language =>
Source.Set_Field ("language", "cpp");
when All_Languages =>
null;
end case;
end;
else
-- If no project was loaded, infer the language from the
-- source extension.
declare
Ext : constant String := Extension (Info.Simple_Name.all);
begin
if Ext in "adb" | "ads" | "ada.1" | "ada.2" then
Source.Set_Field ("language", "ada");
elsif Ext in "c" | "h" then
Source.Set_Field ("language", "c");
elsif Ext in "cpp" | "cc" | "hpp" then
Source.Set_Field ("language", "cpp");
end if;
end;
end if;
declare
P_Name : constant String :=
(if Is_Project_Loaded
then Project_Name (Info.Full_Name.all)
else "");
-- Note that P_Name can be "" here either because we don't have a
-- root project at all or because we were unable to find the project
-- to which the source pertains.
begin
Source.Set_Field
("project",
(if P_Name /= "" then P_Name else "Other Sources"));
end;
Pp.Current_Source := Source;
end Pretty_Print_Start_File;
---------------------------
-- Pretty_Print_End_File --
---------------------------
procedure Pretty_Print_End_File (Pp : in out Dynamic_Html) is
use Ada.Text_IO;
use Outputs;
Source : JSON_Value renames Pp.Current_Source;
Filename : constant String := Source.Get ("filename");
Hunk_Filename : constant String := Source.Get ("hunkFilename");
Output : File_Type;
Simplified : constant JSON_Value := Create_Object;
begin
if not Is_Empty (Pp.Current_Mappings) then
Source.Set_Field ("mappings", Pp.Current_Mappings);
end if;
Source.Set_Field ("scopeMetrics", Pp.Scope_Metrics);
-- Dump the JSON object containing the full coverage data for a specific
-- source file, wrapping it into a function call.
begin
Create_Output_File (Output, Hunk_Filename);
Put (Output, "REPORT[""" & Hunk_Filename & """] = ");
W
(Item => Unbounded_String'(Write (Source, Compact => True)),
Output => Output,
New_Line => False);
Close (Output);
exception
when Ex : others =>
if Is_Open (Output) then
Close (Output);
end if;
Warn
("hunk generation failed: " & Filename & ": " &
Exception_Information (Ex));
end;
-- Append a simplified "reference" entry to the index
Simplified.Set_Field ("filename", Filename);
Simplified.Set_Field ("liStats", JSON_Value'(Source.Get ("liStats")));
Simplified.Set_Field
("enAllStats", JSON_Value'(Source.Get ("enAllStats")));
Simplified.Set_Field
("coverageLevel", String'(Source.Get ("coverageLevel")));
Simplified.Set_Field ("hunkFilename", Hunk_Filename);
Simplified.Set_Field
("missingSource", Boolean'(Source.Get ("missingSource")));
if Source.Has_Field ("project") then
-- Project name is optional. Add it only when relevant
Simplified.Set_Field
("project", String'(Source.Get ("project")));
end if;
Append (Pp.Source_List, Simplified);
end Pretty_Print_End_File;
---------------------------------
-- Pretty_Print_Scope_Entities --
---------------------------------
procedure Pretty_Print_Scope_Entities
(Pp : in out Dynamic_Html;
File : Source_File_Index;
Scope_Entities : Scope_Entities_Tree)
is
use Scope_Entities_Trees;
function To_JSON
(Cur : Cursor;
Is_Root : Boolean := False) return JSON_Value;
-- Convert a scope entity to a JSON scoped metric: compute line and
-- obligation statistics for the given scope and recursively for
-- child scopes. Is_Root indicates whether the given Cur is the root
-- scope. Store the result as a JSON object, with the name and the line
-- of the scope.
-------------
-- To_JSON --
-------------
function To_JSON
(Cur : Cursor;
Is_Root : Boolean := False) return JSON_Value
is
Scope_Ent : constant Scope_Entity := Element (Cur);
Child : Cursor := First_Child (Cur);
Scope_Metrics_JSON : constant JSON_Value := Create_Object;
Children_Scope_Metrics_JSON : JSON_Array;
-- Representation of the scope metrics for the html format
File_Info : constant File_Info_Access := Get_File (File);
Line_Stats : constant Li_Stat_Array :=
Line_Metrics
(File_Info,
Scope_Ent.Start_Sloc.Line,
(if Is_Root then Last_Line (File_Info)
else Scope_Ent.End_Sloc.Line));
-- Adjust Scope_Ent.End_Sloc for the root node as it is
-- No_Local_Location by default.
Ob_Stats : constant Ob_Stat_Array :=
Obligation_Metrics (Scope_Ent.From, Scope_Ent.To);
begin
Scope_Metrics_JSON.Set_Field ("scopeName", Scope_Ent.Name);
Scope_Metrics_JSON.Set_Field ("scopeLine", Scope_Ent.Sloc.Line);
Scope_Metrics_JSON.Set_Field ("stats", To_JSON (Line_Stats));
Scope_Metrics_JSON.Set_Field ("enAllStats", To_JSON (Ob_Stats));
while Has_Element (Child) loop
Append (Children_Scope_Metrics_JSON, To_JSON (Child));
Child := Next_Sibling (Child);
end loop;
Scope_Metrics_JSON.Set_Field
("children", Create (Children_Scope_Metrics_JSON));
return Scope_Metrics_JSON;
end To_JSON;
begin
for Cur in Scope_Entities.Iterate_Children (Scope_Entities.Root) loop
Pp.Scope_Metrics := To_JSON (Cur, Is_Root => True);
end loop;
end Pretty_Print_Scope_Entities;
-----------------------------
-- Pretty_Print_Start_Line --
-----------------------------
procedure Pretty_Print_Start_Line
(Pp : in out Dynamic_Html;
Line_Num : Natural;
Info : Line_Info_Access;
Line : String)
is
Coverage_State : constant String :=
(1 => State_Char (Aggregated_State (Info.all)));
Mapping : constant JSON_Value := Create_Object;
Line_Obj : constant JSON_Value := Create_Object;
begin
Clear (Pp.Current_SCOs);
Clear (Pp.Current_Conditions);
Line_Obj.Set_Field ("lineNumber", Img (Line_Num));
Line_Obj.Set_Field ("src", Line);
Mapping.Set_Field ("coverage", Coverage_State);
Mapping.Set_Field ("line", Line_Obj);
Mapping.Set_Field ("messages", Empty_Array);
Pp.Current_Mapping := Mapping;
end Pretty_Print_Start_Line;
---------------------------
-- Pretty_Print_End_Line --
---------------------------
procedure Pretty_Print_End_Line (Pp : in out Dynamic_Html) is
begin
if not Is_Empty (Pp.Current_SCOs) then
Pp.Current_Mapping.Set_Field ("scos", Pp.Current_SCOs);
end if;
Append (Pp.Current_Mappings, Pp.Current_Mapping);
end Pretty_Print_End_Line;
----------------------
-- Pretty_Print_SCO --
----------------------
procedure Pretty_Print_SCO
(Pp : in out Dynamic_Html'Class;
SCO : SCO_Id;
State : Line_State;
Kind : SCO_Kind)
is
SCO_JSON : constant JSON_Value := Create_Object;
begin
Set_SCO_Fields (SCO_JSON, SCO, State, Kind);
Append (Pp.Current_SCOs, SCO_JSON);
end Pretty_Print_SCO;
----------------------------
-- Pretty_Print_Statement --
----------------------------
procedure Pretty_Print_Statement
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State) is
begin
Pretty_Print_SCO (Pp, SCO, State, Statement);
end Pretty_Print_Statement;
----------------------
-- Pretty_Print_Fun --
----------------------
procedure Pretty_Print_Fun
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State) is
begin
Pretty_Print_SCO (Pp, SCO, State, Fun);
end Pretty_Print_Fun;
-----------------------
-- Pretty_Print_Call --
-----------------------
procedure Pretty_Print_Call
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State) is
begin
Pretty_Print_SCO (Pp, SCO, State, Call);
end Pretty_Print_Call;
---------------------------------
-- Pretty_Print_Start_Decision --
---------------------------------
procedure Pretty_Print_Start_Decision
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State)
is
Decision_JSON : constant JSON_Value := Create_Object;
Conditions : JSON_Array;
begin
Clear (Pp.Current_Conditions);
Set_SCO_Fields (Decision_JSON, SCO, State, Decision);
Pp.Current_Conditions := Conditions;
Pp.Current_Decision := Decision_JSON;
end Pretty_Print_Start_Decision;
-------------------------------
-- Pretty_Print_End_Decision --
-------------------------------
procedure Pretty_Print_End_Decision (Pp : in out Dynamic_Html) is
begin
if not Is_Empty (Pp.Current_Conditions) then
Pp.Current_Decision.Set_Field ("conditions", Pp.Current_Conditions);
end if;
Append (Pp.Current_SCOs, Pp.Current_Decision);
end Pretty_Print_End_Decision;
----------------------------
-- Pretty_Print_Condition --
----------------------------
procedure Pretty_Print_Condition
(Pp : in out Dynamic_Html;
SCO : SCO_Id;
State : Line_State)
is
Condition_JSON : constant JSON_Value := Create_Object;
begin
Set_SCO_Fields (Condition_JSON, SCO, State, Condition);
Append (Pp.Current_Conditions, Condition_JSON);
end Pretty_Print_Condition;
----------------------------------------
-- Pretty_Print_Start_Instruction_Set --
----------------------------------------
procedure Pretty_Print_Start_Instruction_Set
(Pp : in out Dynamic_Html;
State : Any_Line_State)
is
Insn_Set : constant JSON_Value := Create_Object;
begin
Clear (Pp.Current_Insn_Blocks);
Insn_Set.Set_Field ("coverage", State_Char (State) & "");
Pp.Current_Insn_Set := Insn_Set;
end Pretty_Print_Start_Instruction_Set;
-------------------------------
-- Pretty_Print_Start_Symbol --
-------------------------------
procedure Pretty_Print_Start_Symbol
(Pp : in out Dynamic_Html;
Name : String;
Offset : Pc_Type;
State : Line_State)
is
use Hex_Images;
Coverage_State : constant String := State_Char (State) & "";
Insn_Block : constant JSON_Value := Create_Object;
begin
Clear (Pp.Current_Insns);
Insn_Block.Set_Field ("name", Name);
Insn_Block.Set_Field ("offset", Hex_Image (Offset));
Insn_Block.Set_Field ("coverage", Coverage_State);
Pp.Current_Insn_Block := Insn_Block;
end Pretty_Print_Start_Symbol;
-----------------------
-- Pretty_Print_Insn --
-----------------------
procedure Pretty_Print_Insn
(Pp : in out Dynamic_Html;
Pc : Pc_Type;
State : Insn_State;
Insn : Binary_Content;
Insn_Set : Insn_Set_Type;
Sym : Symbolizer'Class)
is
use Hex_Images;
use Traces_Disa;
Instruction : constant JSON_Value := Create_Object;
begin
Instruction.Set_Field ("address", Hex_Image (Pc));
Instruction.Set_Field ("coverage", Insn_State_Char (State) & "");
Instruction.Set_Field
("assembly", Disassemble (Insn, Pc, Insn_Set, Sym));
Append (Pp.Current_Insns, Instruction);
end Pretty_Print_Insn;
-----------------------------
-- Pretty_Print_End_Symbol --
-----------------------------
procedure Pretty_Print_End_Symbol (Pp : in out Dynamic_Html) is
begin
if not Is_Empty (Pp.Current_Insns) then
Pp.Current_Insn_Block.Set_Field ("instructions", Pp.Current_Insns);
end if;
Append (Pp.Current_Insn_Blocks, Pp.Current_Insn_Block);
end Pretty_Print_End_Symbol;
--------------------------------------
-- Pretty_Print_End_Instruction_Set --
--------------------------------------
procedure Pretty_Print_End_Instruction_Set
(Pp : in out Dynamic_Html) is
begin
if not Is_Empty (Pp.Current_Insn_Blocks) then
Pp.Current_Insn_Set.Set_Field
("instructionBlocks", Pp.Current_Insn_Blocks);
end if;
Pp.Current_Mapping.Set_Field ("instructionSet", Pp.Current_Insn_Set);
end Pretty_Print_End_Instruction_Set;
--------------------------
-- Pretty_Print_Message --
--------------------------
procedure Pretty_Print_Message
(Pp : in out Dynamic_Html;
M : Message)
is
use Hex_Images;
use Interfaces;
Message : constant JSON_Value := Create_Object;
begin
Message.Set_Field ("kind", To_Lower (M.Kind'Img));
if M.PC /= 0 then
Message.Set_Field ("address", Hex_Image (M.PC));
end if;
if M.SCO /= No_SCO_Id then
Message.Set_Field ("sco", Image (M.SCO, With_Sloc => False));
end if;
Message.Set_Field ("message", +M.Msg);
Pp.Current_Mapping.Get ("messages").Append (Message);
end Pretty_Print_Message;
-------
-- W --
-------
procedure W
(Item : String;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
is
use Ada.Text_IO;
begin
Put (File => Output, Item => Item);
if New_Line then
NL (Output => Output);
end if;
end W;
procedure W
(Item : Unbounded_String;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
is
use Ada.Text_IO.Unbounded_IO;
begin
Put (File => Output, Item => Item);
if New_Line then
NL (Output => Output);
end if;
end W;
procedure W
(Item : JSON_Value;
Output : Ada.Text_IO.File_Type;
New_Line : Boolean := True)
is
Item_US : constant Unbounded_String := Item.Write (Compact => True);
begin
W (Item_US, Output, New_Line);
end W;
--------
-- NL --
--------
procedure NL (Output : Ada.Text_IO.File_Type) is
use Ada.Text_IO;
begin
New_Line (File => Output);
end NL;
--------------------
-- Set_SCO_Fields --
--------------------
procedure Set_SCO_Fields
(Obj : JSON_Value;
SCO : SCO_Id;
State : Line_State;
Kind : SCO_Kind)
is
JSON_Annotations : JSON_Array;
begin
Obj.Set_Field ("id", Img (Integer (SCO)));
Obj.Set_Field ("text", SCO_Image (SCO));
Obj.Set_Field ("coverage", String'(1 => State_Char (State)));
Obj.Set_Field ("range", Src_Range (SCO));
for Annotation of SCO_Annotations (SCO) loop
Append (JSON_Annotations, Create (Annotation));
end loop;
Obj.Set_Field ("annotations", JSON_Annotations);
Obj.Set_Field ("kind", To_Lower (Kind'Image));
end Set_SCO_Fields;
---------------
-- Src_Range --
---------------
function Src_Range (SCO : SCO_Id) return JSON_Array
is
Sloc_Start : constant Source_Location := First_Sloc (SCO);
Sloc_End : constant Source_Location :=
End_Lex_Element (Last_Sloc (SCO));
R : JSON_Array;
Start_Arr : JSON_Array;
End_Arr : JSON_Array;
begin
Append (Start_Arr, Create (Sloc_Start.L.Line));
Append (Start_Arr, Create (Sloc_Start.L.Column));
Append (End_Arr, Create (Sloc_End.L.Line));
Append (End_Arr, Create (Sloc_End.L.Column));
Append (R, Create (Start_Arr));
Append (R, Create (End_Arr));
return R;