-
Notifications
You must be signed in to change notification settings - Fork 85
/
Copy pathpan_to_crepProofScript.sml
5189 lines (5068 loc) · 194 KB
/
pan_to_crepProofScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Correctness proof for --
*)
open preamble
panSemTheory panPropsTheory
crepLangTheory crepSemTheory crepPropsTheory
pan_commonTheory pan_commonPropsTheory
listRangeTheory pan_to_crepTheory
val _ = new_theory "pan_to_crepProof";
val _ = set_grammar_ancestry ["listRange", "crepProps", "pan_commonProps", "pan_to_crep"];
(* state relation *)
val s = ``(s:('a,'ffi) panSem$state)``
Definition excp_rel_def:
excp_rel ceids seids <=>
FDOM seids = FDOM ceids /\
(!e e' n n'.
FLOOKUP ceids e = SOME n /\
FLOOKUP ceids e' = SOME n' /\
n = n' ==> e = e')
End
Definition ctxt_fc_def:
ctxt_fc cvs em vs shs ns =
<|vars := FEMPTY |++ ZIP (vs, ZIP (shs, with_shape shs ns));
funcs := cvs; eids := em; vmax := list_max ns |>
End
Definition code_rel_def:
code_rel ctxt s_code t_code <=>
∀f vshs prog.
FLOOKUP s_code f = SOME (vshs, prog) ==>
FLOOKUP ctxt.funcs f = SOME vshs /\
let vs = MAP FST vshs;
shs = MAP SND vshs;
ns = GENLIST I (size_of_shape (Comb shs));
nctxt = ctxt_fc ctxt.funcs ctxt.eids vs shs ns in
FLOOKUP t_code f = SOME (ns, compile nctxt prog)
End
Definition state_rel_def:
state_rel ^s (t:('a,'ffi) crepSem$state) <=>
s.memory = t.memory ∧
s.memaddrs = t.memaddrs ∧
s.sh_memaddrs = t.sh_memaddrs ∧
s.clock = t.clock ∧
s.be = t.be ∧
s.ffi = t.ffi ∧
s.base_addr = t.base_addr
End
Definition locals_rel_def:
locals_rel ctxt (s_locals:mlstring |-> 'a v) t_locals <=>
no_overlap ctxt.vars /\ ctxt_max ctxt.vmax ctxt.vars /\
∀vname v.
FLOOKUP s_locals vname = SOME v ==>
∃ns vs. FLOOKUP (ctxt.vars) vname = SOME (shape_of v, ns) ∧
OPT_MMAP (FLOOKUP t_locals) ns = SOME vs ∧ flatten v = vs
End
Theorem code_rel_imp:
code_rel ctxt s_code t_code ==>
∀f vshs prog.
FLOOKUP s_code f = SOME (vshs, prog) ==>
FLOOKUP ctxt.funcs f = SOME vshs /\
let vs = MAP FST vshs;
shs = MAP SND vshs;
ns = GENLIST I (size_of_shape (Comb shs));
nctxt = ctxt_fc ctxt.funcs ctxt.eids vs shs ns in
FLOOKUP t_code f = SOME (ns, compile nctxt prog)
Proof
fs [code_rel_def]
QED
Theorem code_rel_empty_locals:
code_rel ctxt s.code t.code ==>
code_rel ctxt (empty_locals s).code (empty_locals t).code
Proof
fs [code_rel_def, empty_locals_def, panSemTheory.empty_locals_def]
QED
Theorem cexp_heads_eq:
!es. cexp_heads es = cexp_heads_simp es
Proof
Induct >>
rw [cexp_heads_def, cexp_heads_simp_def] >>
fs [] >>
every_case_tac >> fs []
QED
Theorem compile_exp_val_rel:
∀s e v (t :('a, 'b) state) ct es sh.
panSem$eval s e = SOME v ∧
state_rel s t ∧
code_rel ct s.code t.code ∧
locals_rel ct s.locals t.locals ∧
compile_exp ct e = (es, sh) ==>
MAP (eval t) es = MAP SOME (flatten v) ∧
LENGTH es = size_of_shape sh ∧
shape_of v = sh
Proof
ho_match_mp_tac panSemTheory.eval_ind >>
rpt conj_tac >> rpt gen_tac >> strip_tac
>- (
rename [‘Const w’] >>
fs [panSemTheory.eval_def] >> rveq >>
fs [flatten_def] >>
fs [compile_exp_def] >> rveq >>
fs [OPT_MMAP_def, eval_def,
panLangTheory.size_of_shape_def, shape_of_def])
>- (
rename [‘eval s (Var vname)’] >>
fs [panSemTheory.eval_def] >> rveq >>
fs [locals_rel_def] >>
first_x_assum drule >>
fs [] >> strip_tac >> fs [] >>
fs [compile_exp_def] >> rveq >>
fs [lookup_locals_eq_map_vars] >>
fs [opt_mmap_eq_some] >>
fs [MAP_MAP_o] >>
metis_tac [LENGTH_MAP, length_flatten_eq_size_of_shape])
>- (
rename [‘eval s (Label fname)’] >>
fs [panSemTheory.eval_def, option_case_eq] >> rveq >>
fs [flatten_def] >>
fs [compile_exp_def] >> rveq >>
fs [OPT_MMAP_def] >>
fs [eval_def] >> fs [code_rel_def] >>
cases_on ‘v1’ >>
last_x_assum drule_all >> strip_tac >>
fs [panLangTheory.size_of_shape_def, shape_of_def])
>- (
rename [‘eval s (Struct es)’] >>
rpt gen_tac >> strip_tac >> fs [] >>
fs [panSemTheory.eval_def, option_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
fs [MAP_MAP_o, MAP_FLAT, flatten_def] >>
fs [o_DEF] >>
rpt (pop_assum mp_tac) >>
MAP_EVERY qid_spec_tac [‘vs’, ‘es’] >>
Induct >> fs [] >>
rpt gen_tac >> strip_tac >> fs [OPT_MMAP_def] >>
rewrite_tac [AND_IMP_INTRO] >> strip_tac >> rveq >>
rename [‘_ = SOME vs’] >>
fs [] >>
last_x_assum mp_tac >>
impl_tac >-
metis_tac [] >>
strip_tac >> fs [] >>
last_x_assum (qspec_then ‘h’ mp_tac) >> fs [] >>
disch_then drule >> disch_then drule >>
cases_on ‘compile_exp ct h’ >> fs [])
>-
(
(* Field case *)
rename [‘eval s (Field index e)’] >>
rpt gen_tac >> strip_tac >> fs [] >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq >>
first_x_assum drule_all >> fs [shape_of_def] >>
strip_tac >> fs [] >> rveq >>
qpat_x_assum ‘_ = SOME (Struct _)’ kall_tac >>
qpat_x_assum ‘compile_exp _ _ = _’ kall_tac >>
rpt (pop_assum mp_tac) >>
MAP_EVERY qid_spec_tac
[‘ct’,‘cexp’ ,‘sh’ , ‘es’, ‘t’, ‘s’, ‘index’, ‘vs’] >>
Induct >> rpt gen_tac >- fs [] >>
rewrite_tac [AND_IMP_INTRO] >>
strip_tac >> fs [] >>
cases_on ‘index’ >> fs []
>- (
fs [comp_field_def] >> rveq >>
fs [MAP_TAKE, flatten_def] >>
fs [panLangTheory.size_of_shape_def] >>
fs [GSYM length_flatten_eq_size_of_shape] >>
metis_tac [LENGTH_MAP, TAKE_LENGTH_APPEND]) >>
fs [comp_field_def] >>
last_x_assum drule >>
ntac 4 (disch_then drule) >>
fs [panLangTheory.size_of_shape_def, flatten_def] >>
drule map_append_eq_drop >>
fs [LENGTH_MAP, length_flatten_eq_size_of_shape])
>- (
rename [‘eval s (Load sh e)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab"] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq >>
last_x_assum drule_all >>
strip_tac >>
fs [shape_of_def, panLangTheory.size_of_shape_def,flatten_def] >>
rveq >> fs [] >> rveq >>
fs [length_load_shape_eq_shape] >>
drule mem_load_some_shape_eq >>
strip_tac >> fs [] >>
fs [MAP_EQ_EVERY2] >> fs [length_load_shape_eq_shape] >>
rveq >> fs [GSYM length_flatten_eq_size_of_shape] >>
fs [LIST_REL_EL_EQN] >> fs [length_load_shape_eq_shape] >>
rw [] >> fs [state_rel_def] >>
drule mem_load_flat_rel >>
disch_then drule >>
strip_tac >> fs [] >>
drule eval_load_shape_el_rel >>
disch_then (qspecl_then [‘0w’, ‘t’,‘x0’] mp_tac) >> fs [] >>
strip_tac >>
fs [eval_def, OPT_MMAP_def] >>
every_case_tac >> fs [] >> rveq >>
fs[EVERY_DEF] >> cases_on ‘h’ >> fs [] >>
fs [wordLangTheory.word_op_def] >> rveq >>
qpat_x_assum ‘mem_load _ _ = _’ (mp_tac o GSYM) >>
strip_tac >> fs [])
>- (
rename [‘eval s (LoadByte e)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab", option_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq >>
first_x_assum drule_all >> fs [shape_of_def] >>
strip_tac >> fs [] >> rveq >>
cases_on ‘cexp’ >> fs [panLangTheory.size_of_shape_def, flatten_def] >> rveq >>
fs [panLangTheory.size_of_shape_def] >>
fs [eval_def, state_rel_def])
>- (
rename [‘eval s (Op op es)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab", option_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [cexp_heads_eq] >>
fs [cexp_heads_simp_def] >>
‘~MEM [] (MAP FST (MAP (λa. compile_exp ct a) es))’ by (
CCONTR_TAC >> fs [] >> rveq >>
fs [MEM_MAP] >> rveq >>
drule opt_mmap_mem_func >>
disch_then drule >>
strip_tac >> fs [] >>
rename1 ‘MEM e es’ >>
cases_on ‘compile_exp ct e’ >> fs [] >>
‘shape_of m = One’ by (
‘MEM m ws’ by (
drule opt_mmap_mem_defined >>
strip_tac >> res_tac >> fs []) >>
qpat_x_assum ‘EVERY _ ws’ mp_tac >>
fs [EVERY_MEM] >>
disch_then (qspec_then ‘m’ mp_tac) >>
fs [] >> TOP_CASE_TAC >> fs [] >>
TOP_CASE_TAC >> fs [shape_of_def]) >>
last_x_assum drule_all >>
strip_tac >> rveq >> rfs [panLangTheory.size_of_shape_def]) >>
fs [] >> rveq >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
fs [flatten_def, eval_def, MAP_MAP_o] >>
‘OPT_MMAP (λa. eval t a)
(MAP (HD ∘ FST ∘ (λa. compile_exp ct a)) es) =
OPT_MMAP (λa. OPTION_MAP v2word (eval s a)) es’ by (
ho_match_mp_tac IMP_OPT_MMAP_EQ >>
fs [MAP_EQ_EVERY2, LIST_REL_EL_EQN] >>
rw [] >>
drule opt_mmap_length_eq >>
strip_tac >> fs [] >>
first_x_assum (qspec_then ‘EL n es’ mp_tac) >>
impl_tac >- metis_tac [EL_MEM] >>
drule opt_mmap_el >> fs [] >>
disch_then drule >>
strip_tac >> fs [] >>
disch_then drule >>
disch_then drule >>
disch_then (qspecl_then [‘FST (compile_exp ct (EL n es))’,
‘SND(compile_exp ct (EL n es))’] mp_tac) >>
fs [] >>
strip_tac >>
fs [EVERY_EL] >>
last_x_assum (qspec_then ‘n’ mp_tac) >>
fs [] >> TOP_CASE_TAC >> fs [] >>
TOP_CASE_TAC >> fs [] >>
qpat_x_assum ‘LENGTH es = LENGTH _’ (mp_tac o GSYM) >>
strip_tac >> fs [] >>
drule (INST_TYPE [``:'a``|->``:'a panLang$exp``,
``:'b``|->``:'a crepLang$exp``] EL_MAP) >>
disch_then (qspec_then ‘(HD ∘ FST ∘ (λa. compile_exp ct a))’ mp_tac) >>
strip_tac >> fs [] >>
fs [flatten_def, v2word_def] >> rveq) >>
fs [] >>
‘OPT_MMAP (λa. OPTION_MAP v2word (eval s a)) es =
SOME (MAP v2word ws)’ by (
ho_match_mp_tac opt_mmap_opt_map >> fs []) >>
fs [EVERY_MAP, MAP_MAP_o] >>
‘∀x. (λw. case w of ValWord v6 => T | ValLabel v7 => F | Struct v3 => F) x ==>
(λx. case v2word x of Word v2 => T | Label v3 => F) x’ by (
rw [] >> every_case_tac >> fs [v2word_def]) >>
drule MONO_EVERY >>
disch_then (qspec_then ‘ws’ mp_tac) >> fs [] >>
strip_tac >> fs [flatten_def] >>
fs [GSYM MAP_MAP_o] >>
qmatch_goalsub_abbrev_tac ‘word_op op ins’ >>
qmatch_asmsub_abbrev_tac ‘word_op op ins'’ >>
‘ins = ins'’ by (
unabbrev_all_tac >> fs [MAP_EQ_EVERY2] >>
fs [LIST_REL_EL_EQN] >>
rw [] >>
fs [EVERY_EL] >> (* for some reason, drule EL_MAP is not being inst. properly*)
‘EL n (MAP v2word ws) = v2word (EL n ws)’ by (
match_mp_tac EL_MAP >> fs []) >>
fs [] >>
last_x_assum (qspec_then ‘n’ mp_tac) >>
fs [] >> TOP_CASE_TAC >> fs [] >>
TOP_CASE_TAC >> fs [v2word_def]) >>
unabbrev_all_tac >> fs [])
>- (
rename1 ‘Panop’ >>
rpt gen_tac >> strip_tac >>
gvs[compile_exp_def,AllCaseEqs(),eval_def,panLangTheory.size_of_shape_def,
panSemTheory.eval_def,crepSemTheory.eval_def,flatten_def,shape_of_def,
DefnBase.one_line_ify NONE pan_op_def,MAP_EQ_CONS,opt_mmap_eq_some,
cexp_heads_def,PULL_EXISTS, SF DNF_ss
] >>
rpt $ qpat_x_assum ‘SOME _ = _’ $ assume_tac o GSYM >>
rpt $ first_x_assum $ drule_then $ drule_then $ drule_then drule >>
rpt $ disch_then $ resolve_then Any assume_tac $ GSYM PAIR >>
gvs[flatten_def,shape_of_def,DefnBase.one_line_ify NONE compile_panop_def,crep_op_def])
>- (
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def] >>
fs [option_case_eq, v_case_eq, word_lab_case_eq] >> rveq >>
(* open compile_exp *)
fs [compile_exp_def] >>
cases_on ‘compile_exp ct e’ >>
cases_on ‘compile_exp ct e'’ >>
first_x_assum drule_all >>
first_x_assum drule_all >>
strip_tac >> strip_tac >>
fs [panLangTheory.size_of_shape_def, shape_of_def, flatten_def] >>
rveq >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
rveq >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
fs [eval_def] >>
every_case_tac >> fs [] >> EVAL_TAC)
>- (
rpt gen_tac >> rpt strip_tac >>
fs [panSemTheory.eval_def] >>
fs [option_case_eq, v_case_eq, word_lab_case_eq] >> rveq >>
fs [compile_exp_def] >>
cases_on ‘compile_exp ct e’ >>
first_x_assum drule_all >>
rpt strip_tac >> fs [] >>
fs [panLangTheory.size_of_shape_def, shape_of_def, flatten_def] >>
rveq >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >> rveq >>
fs [eval_def] >> every_case_tac >>
fs [panLangTheory.size_of_shape_def, shape_of_def])>>
rpt strip_tac >>
fs [panSemTheory.eval_def] >>
fs [option_case_eq, v_case_eq, word_lab_case_eq] >> rveq >>
fs [compile_exp_def] >>
fs [panLangTheory.size_of_shape_def, shape_of_def, flatten_def] >>
fs [eval_def] >>
fs[state_component_equality, state_rel_def]
QED
Theorem mem_comp_field_lem:
∀i l es x.
MEM x (FST(comp_field i l es)) ⇒
MEM x es ∨ x = (Const 0w)
Proof
Induct_on ‘l’ >> rw[comp_field_def] >>
imp_res_tac MEM_TAKE >>
rw[] >>
res_tac >>
imp_res_tac MEM_DROP_IMP >>
gvs[]
QED
Theorem MEM_compile_exp_vmax:
∀ctxt exp n e.
ctxt_max ctxt.vmax ctxt.vars ∧ MEM n (var_cexp e) ∧
MEM e (FST(compile_exp ctxt exp)) ⇒
n ≤ ctxt.vmax
Proof
recInduct compile_exp_ind >>
rw[compile_exp_def] >>
gvs[var_cexp_def,MEM_FLAT,MEM_MAP,PULL_EXISTS,UNCURRY_eq_pair,ELIM_UNCURRY, SF DNF_ss] >>
rpt(PURE_FULL_CASE_TAC >> gvs[var_cexp_def,MEM_FLAT,MEM_MAP,PULL_EXISTS,UNCURRY_eq_pair,ELIM_UNCURRY]) >>
res_tac
>- (gvs[ctxt_max_def] >> res_tac >> gvs[])
>- (imp_res_tac mem_comp_field_lem >> res_tac >> gvs[var_cexp_def])
>- (imp_res_tac var_exp_load_shape >> gvs[]
) >>
gvs[cexp_heads_eq,cexp_heads_simp_def,MEM_MAP,FORALL_PROD] >>
first_x_assum drule >>
disch_then drule >>
disch_then irule >>
Cases_on ‘(FST (compile_exp ctxt a'))’ >>
gvs[] >>
metis_tac[FST,PAIR,SND]
QED
Definition globals_lookup_def:
globals_lookup t v =
OPT_MMAP (FLOOKUP t.globals)
(GENLIST (λx. n2w x) (size_of_shape (shape_of v)))
End
val gen_goal =
``λ comp (prog, s). ∀res s1 t ctxt.
evaluate (prog,s) = (res,s1) ∧ res ≠ SOME Error ∧
state_rel s t ∧ code_rel ctxt s.code t.code /\
excp_rel ctxt.eids s.eshapes /\
locals_rel ctxt s.locals t.locals ⇒
∃res1 t1. evaluate (comp ctxt prog,t) = (res1,t1) /\
state_rel s1 t1 ∧ code_rel ctxt s1.code t1.code /\
excp_rel ctxt.eids s1.eshapes /\
case res of
| NONE => res1 = NONE /\ locals_rel ctxt s1.locals t1.locals
| SOME Break => res1 = SOME Break /\
locals_rel ctxt s1.locals t1.locals
| SOME Continue => res1 = SOME Continue /\
locals_rel ctxt s1.locals t1.locals
| SOME (Return v) =>
(size_of_shape (shape_of v) = 0 ==> res1 = SOME (Return (Word 0w))) ∧
(size_of_shape (shape_of v) = 1 ==> res1 = SOME (Return (HD(flatten v)))) ∧
(1 < size_of_shape (shape_of v) ==>
res1 = SOME (Return (Word 0w)) /\ globals_lookup t1 v = SOME (flatten v) ∧
size_of_shape (shape_of v) <= 32)
| SOME (Exception eid v) =>
(case FLOOKUP ctxt.eids eid of
| SOME n => res1 = SOME (Exception n) ∧
(1 <= size_of_shape (shape_of v) ==>
globals_lookup t1 v = SOME (flatten v) ∧
size_of_shape (shape_of v) <= 32)
| NONE => F)
| SOME TimeOut => res1 = SOME TimeOut
| SOME (FinalFFI f) => res1 = SOME (FinalFFI f)
| _ => F``
local
val goal = beta_conv ``^gen_goal pan_to_crep$compile``
val ind_thm = panSemTheory.evaluate_ind
|> ISPEC goal
|> CONV_RULE (DEPTH_CONV PairRules.PBETA_CONV) |> REWRITE_RULE [];
fun list_dest_conj tm = if not (is_conj tm) then [tm] else let
val (c1,c2) = dest_conj tm in list_dest_conj c1 @ list_dest_conj c2 end
val ind_goals = ind_thm |> concl |> dest_imp |> fst |> list_dest_conj
in
fun get_goal s = first (can (find_term (can (match_term (Term [QUOTE s]))))) ind_goals
fun compile_tm () = ind_thm |> concl |> rand
fun the_ind_thm () = ind_thm
val fgoal = beta_conv ``^gen_goal pan_to_crep$compile``
end
Theorem compile_Skip_Break_Continue_Annot:
^(get_goal "compile _ panLang$Skip") /\
^(get_goal "compile _ panLang$Break") /\
^(get_goal "compile _ panLang$Continue") /\
^(get_goal "compile _ (panLang$Annot _ _)")
Proof
rpt strip_tac >>
fs [panSemTheory.evaluate_def, evaluate_def,
compile_def] >> rveq >> fs []
QED
Theorem compile_Tick:
^(get_goal "compile _ panLang$Tick")
Proof
rpt strip_tac >>
fs [panSemTheory.evaluate_def, evaluate_def,
compile_def] >> rveq >> fs [] >>
every_case_tac >> fs [panSemTheory.empty_locals_def, empty_locals_def,
panSemTheory.dec_clock_def, dec_clock_def] >>
rveq >> fs [state_rel_def]
QED
Theorem locals_rel_lookup_ctxt:
locals_rel ctxt lcl lcl' /\
FLOOKUP lcl vr = SOME v ==>
?ns. FLOOKUP ctxt.vars vr = SOME (shape_of v,ns) /\
LENGTH ns = LENGTH (flatten v) /\
OPT_MMAP (FLOOKUP lcl') ns = SOME (flatten v)
Proof
rw [locals_rel_def] >>
metis_tac [opt_mmap_length_eq]
QED
Theorem eval_nested_assign_distinct_eq:
!es ns t ev vs.
MAP (eval t) es = MAP SOME ev /\
OPT_MMAP (FLOOKUP t.locals) ns = SOME vs /\
distinct_lists ns (FLAT (MAP var_cexp es)) /\
ALL_DISTINCT ns /\
LENGTH ns = LENGTH es ==>
evaluate (nested_seq (MAP2 Assign ns es),t) =
(NONE, t with locals := t.locals |++ ZIP (ns, ev))
Proof
Induct
>- (
rpt gen_tac >> strip_tac >>
cases_on ‘ns’ >> fs [] >>
fs [nested_seq_def, evaluate_def,
FUPDATE_LIST_THM,
state_component_equality]) >>
rpt gen_tac >>
strip_tac >>
cases_on ‘ns’ >>
fs [nested_seq_def] >>
fs [evaluate_def] >>
pairarg_tac >> fs [] >>
fs [MAP_EQ_CONS] >>
rveq >> rfs [] >>
fs [OPT_MMAP_def] >>
rveq >> rfs [] >>
rveq >>
rename [‘eval t e = SOME v’] >>
rename [‘MAP (eval t) es = MAP SOME ev’] >>
rename [‘FLOOKUP t.locals n = SOME nv’] >>
qpat_x_assum ‘distinct_lists _ _’
(assume_tac o REWRITE_RULE [Once CONS_APPEND]) >>
drule distinct_lists_cons >>
strip_tac >>
drule opt_mmap_flookup_update >>
disch_then drule >>
disch_then (qspec_then ‘v’ assume_tac) >>
‘MAP (eval (t with locals := t.locals |+ (n,v))) es = MAP SOME ev’ by (
fs [MAP_EQ_EVERY2, LIST_REL_EL_EQN] >>
rw [] >>
first_x_assum (qspec_then ‘n'’ assume_tac) >>
rfs [] >>
ho_match_mp_tac update_locals_not_vars_eval_eq >>
fs [distinct_lists_def] >>
CCONTR_TAC >>
metis_tac [MEM_FLAT, EL_MEM, MEM_MAP]) >>
qpat_x_assum ‘MAP (eval t) es = MAP SOME ev’ kall_tac >>
first_x_assum drule >>
fs [state_accfupds] >>
disch_then drule >>
strip_tac >> fs [] >>
fs [FUPDATE_LIST_THM]
QED
Theorem eval_nested_decs_seq_res_var_eq:
!es ns t ev p.
MAP (eval t) es = MAP SOME ev /\
LENGTH ns = LENGTH es /\
distinct_lists ns (FLAT (MAP var_cexp es)) /\
ALL_DISTINCT ns ==>
let (q,r) = evaluate (p, t with locals := t.locals |++ ZIP (ns, ev)) in
evaluate (nested_decs ns es p, t) =
(q, r with locals :=
FOLDL res_var r.locals (ZIP (ns, MAP (FLOOKUP t.locals) ns)))
Proof
Induct
>- (
rpt gen_tac >> strip_tac >>
cases_on ‘ns’ >> fs [] >>
pairarg_tac >> fs [] >>
fs [nested_decs_def, FUPDATE_LIST_THM] >>
cases_on ‘t’ >> cases_on ‘r’ >>
fs [state_component_equality, recordtype_state_seldef_locals_fupd_def]) >>
rpt gen_tac >>
strip_tac >>
cases_on ‘ns’ >>
fs [nested_decs_def] >>
fs [evaluate_def] >>
fs [MAP_EQ_CONS] >>
pairarg_tac >> fs [] >>
rveq >> rfs [] >>
pairarg_tac >> fs [] >>
rename [‘eval t e = SOME v’] >>
rename [‘MAP (eval t) es = MAP SOME ev’] >>
rename [‘~MEM n t'’] >>
qpat_x_assum ‘distinct_lists _ _’
(assume_tac o REWRITE_RULE [Once CONS_APPEND]) >>
drule distinct_lists_cons >>
strip_tac >>
‘MAP (eval (t with locals := t.locals |+ (n,v))) es = MAP SOME ev’ by (
fs [MAP_EQ_EVERY2, LIST_REL_EL_EQN] >>
rw [] >>
first_x_assum (qspec_then ‘n'’ assume_tac) >>
rfs [] >>
ho_match_mp_tac update_locals_not_vars_eval_eq >>
fs [distinct_lists_def] >>
CCONTR_TAC >>
metis_tac [MEM_FLAT, EL_MEM, MEM_MAP]) >>
qpat_x_assum ‘MAP (eval t) es = MAP SOME ev’ kall_tac >>
first_x_assum drule_all >>
disch_then (qspec_then ‘p’ assume_tac) >>
pairarg_tac >> fs [] >>
rveq >>
fs [FUPDATE_LIST_THM] >>
fs [state_component_equality] >>
‘MAP (FLOOKUP (t.locals |+ (n,v))) t' =
MAP (FLOOKUP t.locals) t'’ by
metis_tac [MAP_EQ_f, FLOOKUP_UPDATE] >>
fs [] >>
pop_assum kall_tac >>
qpat_x_assum ‘~MEM n t'’ mp_tac >>
rpt (pop_assum kall_tac) >>
MAP_EVERY qid_spec_tac [‘r’, ‘n’,‘t’, ‘t'’] >>
Induct >> rw [] >>
first_x_assum (qspec_then ‘t’ mp_tac) >>
disch_then (qspec_then ‘n’ mp_tac) >>
fs [] >>
disch_then (qspec_then ‘r with locals :=
res_var r.locals (h,FLOOKUP t.locals h)’ mp_tac) >>
fs [] >>
metis_tac [res_var_commutes]
QED
Theorem mem_comp_field:
!sh i e shp ce es vs.
i < LENGTH vs /\
LENGTH e = size_of_shape (shape_of (Struct vs)) /\
comp_field i sh e = (es,shp) /\
Comb sh = shape_of (Struct vs) /\
MEM ce es ==> MEM ce e
Proof
Induct >> rw [comp_field_def] >>
fs [] >> rveq
>- fs [shape_of_def]
>- (
cases_on ‘vs’ >> fs [] >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
rveq >> fs [] >>
‘size_of_shape (shape_of h') <= LENGTH e’ by DECIDE_TAC >>
metis_tac [MEM_TAKE]) >>
cases_on ‘vs’ >> fs [] >>
fs [panLangTheory.size_of_shape_def, shape_of_def] >>
rveq >> fs [] >>
first_x_assum (qspecl_then [‘i-1’, ‘(DROP (size_of_shape (shape_of h')) e)’,
‘shp’, ‘ce’, ‘es’, ‘t’] mp_tac) >>
fs [] >>
metis_tac [MEM_DROP_IMP]
QED
Theorem eval_var_cexp_present_ctxt:
∀(s :('a, 'b) panSem$state) e v (t :('a, 'b) state) ct es sh.
state_rel s t /\
eval s e = SOME v /\
code_rel ct s.code t.code /\
locals_rel ct s.locals t.locals /\
compile_exp ct e = (es,sh) ==>
(∀n. MEM n (FLAT (MAP var_cexp es)) ==>
?v shp ns. FLOOKUP ct.vars v = SOME (shp,ns) /\
MEM n ns)
Proof
ho_match_mp_tac panSemTheory.eval_ind >>
rpt conj_tac >> rpt gen_tac >> strip_tac
>- (
rename [‘Const w’] >>
fs [panSemTheory.eval_def] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [var_cexp_def])
>- (
rename [‘eval s (Var vname)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [var_cexp_def] >>
fs [CaseEq "option"] >> rveq
>- fs [var_cexp_def] >>
cases_on ‘v'’ >> fs [] >>
rveq >>
fs [MEM_MAP, MEM_FLAT] >>
rveq >>
fs [var_cexp_def] >>
metis_tac [])
>- (
fs [panSemTheory.eval_def] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [var_cexp_def])
>- (
rename [‘eval s (Struct es)’] >>
rpt gen_tac >> strip_tac >> fs [] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [MAP_MAP_o, MAP_FLAT] >>
fs [o_DEF] >>
rpt (pop_assum mp_tac) >>
MAP_EVERY qid_spec_tac [‘vs’, ‘es’] >>
Induct >> fs [] >>
rpt gen_tac >> strip_tac >>
fs [OPT_MMAP_def] >>
strip_tac >>
strip_tac >>
rveq >>
last_x_assum mp_tac >>
impl_tac >- metis_tac [] >>
strip_tac >> fs [] >>
last_x_assum (qspec_then ‘h’ mp_tac) >> fs [] >>
disch_then drule >>
cases_on ‘compile_exp ct h’ >> fs [] >>
strip_tac >>
strip_tac >>
metis_tac [])
>- (
rename [‘eval s (Field index e)’] >>
rpt gen_tac >> strip_tac >> fs [] >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq
>- rw [var_cexp_def] >>
rpt gen_tac >> strip_tac >>
fs [MEM_FLAT, MEM_MAP] >> rveq >>
first_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e’ >> fs [] >>
disch_then (qspec_then ‘n’ mp_tac) >>
fs [] >> rveq >>
impl_tac
>- (
qexists_tac ‘var_cexp y’ >>
fs [] >>
qexists_tac ‘y’ >> fs [] >>
drule compile_exp_val_rel >>
disch_then drule_all >>
strip_tac >> fs [] >> rveq >>
metis_tac [mem_comp_field]) >>
fs [])
>- (
rename [‘eval s (Load sh e)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab"] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq >>
cases_on ‘cexp’ >> fs [] >> rveq
>- (rw [] >> fs [MEM_FLAT, MEM_MAP, var_cexp_def]) >>
rpt gen_tac >>
strip_tac >>
fs [MEM_FLAT, MEM_MAP] >> rveq >>
last_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e’ >> fs [] >>
rveq >>
disch_then (qspec_then ‘n’ mp_tac) >>
rveq >> fs [] >>
impl_tac
>- (
qexists_tac ‘var_cexp y’ >>
fs [] >>
qexists_tac ‘h’ >> fs [] >>
metis_tac [var_exp_load_shape]) >>
fs [])
>- (
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab"] >> rveq >>
fs [compile_exp_def] >> rveq >>
pairarg_tac >> fs [CaseEq "shape"] >> rveq >>
cases_on ‘cexp’ >> fs [] >> rveq
>- (rw [] >> fs [MEM_FLAT, MEM_MAP, var_cexp_def]) >>
reverse (cases_on ‘shape’) >> fs [] >> rveq
>- (rw [] >> fs [MEM_FLAT, MEM_MAP, var_cexp_def]) >>
rw [] >>
fs [var_cexp_def] >>
last_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e’ >> fs [])
>- (
rename [‘eval s (Op op es)’] >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab", option_case_eq] >> rveq >>
fs [compile_exp_def] >> rveq >>
FULL_CASE_TAC >>
fs [] >> rveq
>- (rw [] >> fs [MEM_FLAT, MEM_MAP, var_cexp_def]) >>
fs [var_cexp_def, ETA_AX] >>
rveq >>
rw [] >>
ntac 4 (pop_assum mp_tac) >>
pop_assum kall_tac >>
pop_assum kall_tac >>
ntac 3 (pop_assum mp_tac) >>
MAP_EVERY qid_spec_tac [‘n’,‘ws’, ‘x’, ‘es’] >>
Induct
>- (
rw [] >> fs [cexp_heads_def, var_cexp_def] >>
rveq >> fs [MAP, FLAT]) >>
rpt gen_tac >> strip_tac >>
fs [OPT_MMAP_def] >>
rpt strip_tac >>
rveq >>
fs [cexp_heads_def] >>
fs [CaseEq "list", CaseEq "option"] >>
rveq >>
fs [MAP, MEM_FLAT, MEM_MAP] >> rveq
>- (
first_x_assum (qspec_then ‘h’ mp_tac) >>
fs [] >>
disch_then drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct h’ >> fs []) >>
last_x_assum mp_tac >>
impl_tac >- metis_tac [] >>
disch_then (qspec_then ‘n’ mp_tac) >>
impl_tac
>- (
qexists_tac ‘var_cexp y’ >>
fs [] >> metis_tac []) >>
fs [])
>- (rpt strip_tac >>
gvs[panSemTheory.eval_def,AllCaseEqs(),
DefnBase.one_line_ify NONE pan_op_def,
MAP_EQ_CONS,MEM_MAP,MEM_FLAT,compile_exp_def,
opt_mmap_eq_some,cexp_heads_def,PULL_EXISTS,
SF DNF_ss,var_cexp_def
] >>
rpt $ first_x_assum $ resolve_then (Pat ‘_ = (_,_)’) assume_tac $ GSYM PAIR >>
rpt $ qpat_x_assum ‘SOME _ = _’ $ assume_tac o GSYM >>
rpt $ first_x_assum $ drule_then $ drule_then $ drule_then $ drule >>
rpt strip_tac >>
metis_tac[FST,MEM]
)
>- (
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab"] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [CaseEq "list", CaseEq "option"] >>
rveq >> fs [MEM_FLAT, MEM_MAP, var_cexp_def] >>
rw []
>- (
last_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e’ >> fs []) >>
first_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e'’ >> fs []) >>
rpt gen_tac >> strip_tac >>
fs [panSemTheory.eval_def, option_case_eq, v_case_eq,
CaseEq "word_lab"] >> rveq >>
fs [compile_exp_def] >> rveq >>
fs [CaseEq "list", CaseEq "option"] >>
rveq >> fs [MEM_FLAT, MEM_MAP, var_cexp_def] >>
rw [] >> last_x_assum drule >>
disch_then (qspec_then ‘ct’ mp_tac) >>
cases_on ‘compile_exp ct e’ >> fs []
QED
Theorem compile_Assign:
^(get_goal "compile _ (panLang$Assign _ _)")
Proof
rpt gen_tac >>
rpt strip_tac >>
rename [‘Assign vr e’] >>
fs [panSemTheory.evaluate_def, is_valid_value_def] >>
fs [CaseEq "option", CaseEq "bool"] >> rveq >> fs [] >>
rename [‘eval _ e = SOME ev’] >>
rename [‘FLOOKUP _ vr = SOME v’] >>
(* open compiler def *)
fs [compile_def] >>
pairarg_tac >> fs [] >>
drule locals_rel_lookup_ctxt >>
disch_then drule_all >>
strip_tac >> fs [] >>
drule compile_exp_val_rel >>
disch_then drule_all >>
strip_tac >> fs [] >> rveq >>
fs [length_flatten_eq_size_of_shape] >>
TOP_CASE_TAC >> fs [] >> rveq
>- (
‘ALL_DISTINCT ns’
by metis_tac [locals_rel_def, no_overlap_def] >>
drule eval_nested_assign_distinct_eq >>
disch_then drule >>
strip_tac >> fs [] >>
conj_tac
>- fs [state_rel_def] >>
fs [locals_rel_def] >>
rpt gen_tac >> strip_tac >> fs [] >>
cases_on ‘vr = vname’ >> fs [] >> rveq
>- (
pop_assum (assume_tac o REWRITE_RULE [FLOOKUP_DEF]) >>
fs [] >> rveq >>
match_mp_tac opt_mmap_some_eq_zip_flookup >>
fs [] >>
metis_tac [all_distinct_flookup_all_distinct,
length_flatten_eq_size_of_shape]) >>
fs [FLOOKUP_UPDATE] >>
last_x_assum drule >>
strip_tac >> fs [] >>
rfs [] >>
drule no_overlap_flookup_distinct >>
disch_then drule_all >>
strip_tac >>
drule (INST_TYPE [``:'a``|->``:num``,
``:'b``|->``:'a word_lab``]
opt_mmap_disj_zip_flookup) >>
disch_then (qspecl_then [‘t.locals’, ‘flatten ev’] mp_tac) >>
fs [length_flatten_eq_size_of_shape]) >>
(* non-distinct Assign *)
qmatch_goalsub_abbrev_tac ‘nested_decs temps es _’ >>
‘distinct_lists temps (FLAT (MAP var_cexp es))’ by (
unabbrev_all_tac >>
ho_match_mp_tac genlist_distinct_max >>
rw [] >>
drule eval_var_cexp_present_ctxt >>
disch_then drule_all >>
rw [] >> fs [] >>
rfs [] >>
fs [locals_rel_def, ctxt_max_def] >>
first_x_assum drule >>
fs [] >>
first_x_assum drule >>
fs [EVERY_MEM] >>
res_tac >> fs []) >>
‘ALL_DISTINCT temps ∧ LENGTH es = LENGTH temps’ by (
unabbrev_all_tac >>
fs [LENGTH_GENLIST, ALL_DISTINCT_GENLIST]) >>
fs [] >>
‘ALL_DISTINCT ns’ by metis_tac [locals_rel_def, no_overlap_def] >>
‘distinct_lists ns temps’ by (
unabbrev_all_tac >>
once_rewrite_tac [distinct_lists_commutes] >>
ho_match_mp_tac genlist_distinct_max >>
metis_tac [locals_rel_def, ctxt_max_def]) >>
assume_tac eval_nested_decs_seq_res_var_eq >>
pop_assum (qspecl_then [‘es’, ‘temps’, ‘t’, ‘flatten ev’,
‘nested_seq (MAP2 Assign ns (MAP Var temps))’] mp_tac) >>
impl_tac >- fs [] >>
fs [] >>
pairarg_tac >> fs [] >> rveq >>
strip_tac >>
pop_assum kall_tac >>
‘MAP (eval (t with locals := t.locals |++ ZIP (temps,flatten ev)))
(MAP Var temps) = MAP SOME (flatten ev)’ by (
fs [MAP_MAP_o, MAP_EQ_EVERY2] >>
fs [LIST_REL_EL_EQN] >>
rw [] >> rfs [] >>
‘n < LENGTH temps’ by (
unabbrev_all_tac >> fs [MAP_MAP_o, MAP_EQ_EVERY2]>>
metis_tac []) >>
drule (INST_TYPE [``:'a``|->``:num``,
``:'b``|->``:'a crepLang$exp``] EL_MAP) >>
disch_then (qspec_then ‘Var’ assume_tac) >> fs [] >>
fs [eval_def] >>
metis_tac [update_eq_zip_flookup]) >>
drule eval_nested_assign_distinct_eq >>
disch_then (qspec_then ‘ns’ mp_tac) >>
disch_then (qspec_then ‘flatten v’ mp_tac) >>
impl_tac
>- (
fs [map_var_cexp_eq_var] >>
fs [Once distinct_lists_commutes] >>
drule (INST_TYPE [``:'a``|->``:num``,
``:'b``|->``:'a word_lab``]
opt_mmap_disj_zip_flookup) >>
disch_then (qspecl_then [‘t.locals’, ‘flatten ev’] mp_tac) >>
fs [length_flatten_eq_size_of_shape]) >>
strip_tac >> fs [] >>
rveq >>
fs [state_rel_def] >>
fs [locals_rel_def] >>
rw [] >> fs [] >>
(* writing in this style for druling below *)
‘DISJOINT (set (MAP FST (ZIP (temps,flatten ev))))
(set (MAP FST (ZIP (ns,flatten ev))))’ by (
‘LENGTH ns = LENGTH (flatten ev)’ by
fs [length_flatten_eq_size_of_shape] >>
fs [GSYM length_flatten_eq_size_of_shape, MAP_ZIP] >>
fs [distinct_lists_def, IN_DISJOINT, EVERY_DEF, EVERY_MEM] >>
metis_tac []) >>
drule FUPDATE_LIST_APPEND_COMMUTES >>
disch_then (qspec_then ‘t.locals’ assume_tac) >>
fs [] >>
pop_assum kall_tac >>
pop_assum kall_tac >>
cases_on ‘vr = vname’ >> fs [] >> rveq
>- (
pop_assum (assume_tac o REWRITE_RULE [FLOOKUP_DEF]) >>
fs [] >> rveq >>
fs [opt_mmap_eq_some] >>
fs [Once distinct_lists_commutes] >>
drule (INST_TYPE [``:'a``|->``:num``,
``:'b``|->``:'a word_lab``]
flookup_res_var_zip_distinct) >>
disch_then (qspecl_then [‘flatten ev’,
‘MAP (FLOOKUP t.locals) temps’,