|
| 1 | +# ------------------------------------------------------------------------- # |
| 2 | +# CTests for Global Workflow |
| 3 | +# ------------------------------------------------------------------------- # |
| 4 | +# These ctests correspond to JJOBs (individual Rocoto jobs) that can be |
| 5 | +# run independently, each requiring its own YAML definition of inputs |
| 6 | +# and configurations. By integrating with Rocoto, these jobs can be |
| 7 | +# validated, staged, and executed as self-contained tests using |
| 8 | +# their own data and test parameters. |
| 9 | +# ------------------------------------------------------------------------- # |
| 10 | + |
| 11 | +# Function to set a variable from an environment variable or default value |
| 12 | +function(set_from_env_or_default VAR_NAME ENV_VAR DEFAULT_VALUE) |
| 13 | + if (DEFINED ENV{${ENV_VAR}} AND NOT DEFINED ${VAR_NAME}) |
| 14 | + set(${VAR_NAME} $ENV{${ENV_VAR}} CACHE STRING "Set from environment variable ${ENV_VAR}") |
| 15 | + elseif(NOT DEFINED ${VAR_NAME} AND NOT ${DEFAULT_VALUE} STREQUAL "") |
| 16 | + set(${VAR_NAME} ${DEFAULT_VALUE} CACHE STRING "Default value for ${VAR_NAME}") |
| 17 | + endif() |
| 18 | +endfunction() |
| 19 | + |
| 20 | +# Set HOMEgfs |
| 21 | +if (NOT DEFINED HOMEgfs) |
| 22 | + set(HOMEgfs ${PROJECT_SOURCE_DIR}) |
| 23 | +endif() |
| 24 | + |
| 25 | +# Set RUNTESTS |
| 26 | +set_from_env_or_default(RUNTESTS RUNTESTS "${CMAKE_CURRENT_BINARY_DIR}/RUNTESTS") |
| 27 | + |
| 28 | +# Set HPC_ACCOUNT |
| 29 | +set_from_env_or_default(HPC_ACCOUNT HPC_ACCOUNT " ") |
| 30 | +if (NOT DEFINED HPC_ACCOUNT) |
| 31 | + message(WARNING "HPC_ACCOUNT must be set. CTests will not be created.") |
| 32 | + return() |
| 33 | +endif() |
| 34 | + |
| 35 | +# Set ICSDIR_ROOT |
| 36 | +set_from_env_or_default(ICSDIR_ROOT ICSDIR_ROOT "") |
| 37 | +if (NOT DEFINED ICSDIR_ROOT) |
| 38 | + message(WARNING "ICSDIR_ROOT must be set. CTests will not be created.") |
| 39 | + return() |
| 40 | +endif() |
| 41 | + |
| 42 | +# Set STAGED_TESTS_DIR |
| 43 | +set_from_env_or_default(STAGED_TESTS_DIR STAGED_TESTS_DIR "") |
| 44 | +if (NOT DEFINED STAGED_TESTS_DIR) |
| 45 | + message(WARNING "STAGED_TESTS_DIR must be set. CTests will not be created.") |
| 46 | + return() |
| 47 | +endif() |
| 48 | + |
| 49 | +message(STATUS "gw: global-workflow baselines will be used from: '${HOMEgfs}'") |
| 50 | +message(STATUS "gw: global-workflow tests will be run at: '${RUNTESTS}'") |
| 51 | +message(STATUS "gw: global-workflow tests will use the allocation: '${HPC_ACCOUNT}'") |
| 52 | +message(STATUS "gw: global-workflow tests will use ICSDIR_ROOT: '${ICSDIR_ROOT}'") |
| 53 | +message(STATUS "gw: global-workflow tests will use staged data from: '${STAGED_TESTS_DIR}'") |
| 54 | + |
| 55 | +# Prepare test scripts |
| 56 | +configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scripts/setup.sh.in |
| 57 | + ${CMAKE_CURRENT_BINARY_DIR}/scripts/setup.sh @ONLY) |
| 58 | +configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scripts/stage.sh.in |
| 59 | + ${CMAKE_CURRENT_BINARY_DIR}/scripts/stage.sh @ONLY) |
| 60 | +configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scripts/execute.sh.in |
| 61 | + ${CMAKE_CURRENT_BINARY_DIR}/scripts/execute.sh @ONLY) |
| 62 | +configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scripts/validate.sh.in |
| 63 | + ${CMAKE_CURRENT_BINARY_DIR}/scripts/validate.sh @ONLY) |
| 64 | + |
| 65 | +function(AddJJOBTest) |
| 66 | + |
| 67 | + set(prefix ARG) |
| 68 | + set(novals NOTRAPFPE NOVALGRIND) |
| 69 | + set(singlevals CASE JOB TEST_DATE) |
| 70 | + set(multivals TEST_DEPENDS) |
| 71 | + |
| 72 | + cmake_parse_arguments(${prefix} |
| 73 | + "${novals}" "${singlevals}" "${multivals}" |
| 74 | + ${ARGN}) |
| 75 | + |
| 76 | + set(TEST_NAME ${ARG_CASE}_${ARG_JOB}) |
| 77 | + set(CASE_PATH ${HOMEgfs}/ci/cases/pr) |
| 78 | + set(CASE_YAML ${CASE_PATH}/${ARG_CASE}.yaml) |
| 79 | + |
| 80 | + add_test(NAME test_${TEST_NAME}_setup |
| 81 | + COMMAND ./setup.sh ${TEST_NAME} ${CASE_YAML} ${ARG_TEST_DATE} |
| 82 | + WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/scripts) |
| 83 | + set_tests_properties(test_${TEST_NAME}_setup PROPERTIES LABELS "${ARG_CASE};${ARG_JOB}") |
| 84 | + |
| 85 | + add_test(NAME test_${TEST_NAME}_stage |
| 86 | + COMMAND ./stage.sh ${TEST_NAME} ${ARG_TEST_DATE} |
| 87 | + WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/scripts) |
| 88 | + set_tests_properties(test_${TEST_NAME}_stage PROPERTIES DEPENDS test_${TEST_NAME}_setup LABELS "${ARG_CASE};${ARG_JOB}") |
| 89 | + |
| 90 | + add_test(NAME test_${TEST_NAME}_execute |
| 91 | + COMMAND ./execute.sh ${TEST_NAME} ${ARG_JOB} ${ARG_TEST_DATE} |
| 92 | + WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/scripts) |
| 93 | + set_tests_properties(test_${TEST_NAME}_execute PROPERTIES DEPENDS test_${TEST_NAME}_stage LABELS "${ARG_CASE};${ARG_JOB}") |
| 94 | + |
| 95 | + # TODO - This is a stub for the validation step |
| 96 | + add_test(NAME test_${TEST_NAME}_validate |
| 97 | + COMMAND ./validate.sh ${TEST_NAME} ${CASE_YAML} |
| 98 | + WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/scripts) |
| 99 | + set_tests_properties(test_${TEST_NAME}_validate PROPERTIES DEPENDS test_${TEST_NAME}_execute LABELS "${ARG_CASE};${ARG_JOB}") |
| 100 | +endfunction() |
| 101 | + |
| 102 | +AddJJOBTest( |
| 103 | + CASE "C48_ATM" |
| 104 | + JOB "gfs_fcst_seg0" |
| 105 | + TEST_DATE "2021032312" |
| 106 | +) |
0 commit comments