Lesson 08 has been added

Author: XOMAv2

api-example/README.md

@@ -0,0 +1,11 @@
+# Minimal API example with some tests
+
+## Run
+
+```
+docker compose up -d
+```
+
+```
+lein run local
+```

api-example/config.edn

@@ -0,0 +1,28 @@
+{:core/db
+ {:config #profile {:local {:dbtype "postgres"
+                            :dbname "api_example_db"
+                            :host "localhost"
+                            :port 5432
+                            :user "postgres"
+                            :password "123"}
+                    :test {:dbtype "postgres"
+                           :dbname "api_example_db_test"
+                           :host "localhost"
+                           :port 5433
+                           :user "postgres"
+                           :password "123"}}}
+
+ :core/migrator
+ {:db #ig/ref :core/db}
+
+ :core/app
+ {:ds #ig/ref :core/migrator}
+
+ :core/server
+ {:app #ig/ref :core/app
+  :config #profile {:local {:host "127.0.0.1"
+                            :port 5555
+                            :join? false}
+                    :test {:host "127.0.0.1"
+                           :port 5556
+                           :join? false}}}}

api-example/docker-compose.yml

@@ -0,0 +1,27 @@
+version: "3.8"
+
+services:
+  db:
+    image: postgres
+    container_name: api_example_db
+    environment:
+      POSTGRES_DB: api_example_db
+      POSTGRES_USER: postgres
+      POSTGRES_PASSWORD: "123"
+    ports:
+      - 5432:5432
+    volumes:
+      - api_example_db_volume:/var/lib/postgresql/data
+
+  db_test:
+    image: postgres
+    container_name: api_example_db_test
+    environment:
+      POSTGRES_DB: api_example_db_test
+      POSTGRES_USER: postgres
+      POSTGRES_PASSWORD: "123"
+    ports:
+      - 5433:5432
+
+volumes:
+  api_example_db_volume:

api-example/project.clj

@@ -0,0 +1,30 @@
+(defproject api-example "0.1.0-SNAPSHOT"
+  :description "FIXME: write description"
+  :url "http://example.com/FIXME"
+  :license {:name "EPL-2.0 OR GPL-2.0-or-later WITH Classpath-exception-2.0"
+            :url "https://www.eclipse.org/legal/epl-2.0/"}
+  :dependencies [[aero "1.1.6"]
+                 [camel-snake-kebab "0.4.3"]
+                 [com.github.seancorfield/honeysql "2.4.1033"]
+                 [com.github.seancorfield/next.jdbc "1.3.874"]
+                 [compojure "1.7.0"]
+                 [integrant "0.8.0"]
+                 [migratus "1.4.9"]
+                 [nubank/matcher-combinators "3.8.5"]
+                 [org.clojure/clojure "1.11.1"]
+                 [org.postgresql/postgresql "42.6.0"]
+                 [org.slf4j/slf4j-log4j12 "2.0.7"] ; Required by migratus.
+                 [ring "1.10.0"]
+                 [ring/ring-json "0.5.1"]
+                 [ring/ring-mock "0.4.0"]]
+  :main ^:skip-aot api-example.core
+  :target-path "target/%s"
+  :profiles {:uberjar {:aot :all
+                       :jvm-opts ["-Dclojure.compiler.direct-linking=true"]}}
+  
+  :test-selectors {:integration :integration
+                   :unit (complement :integration)
+                   :crud (fn [m]
+                           (->> (:name m)
+                                (name)
+                                (re-find #"get|create|delete|update|replace")))})

api-example/resources/migrations/20230526133616-create-account.up.sql

@@ -0,0 +1,26 @@
+CREATE TABLE "account" (
+    "id" INT GENERATED ALWAYS AS IDENTITY PRIMARY KEY,
+    "username" VARCHAR (255) UNIQUE NOT NULL,
+    "password" VARCHAR (255) NOT NULL,
+    "email" VARCHAR (255) UNIQUE NOT NULL,
+    "created_on" TIMESTAMP NOT NULL
+);
+--;;
+INSERT INTO "account"(
+        "username",
+        "password",
+        "email",
+        "created_on"
+    )
+VALUES (
+        'admin',
+        'password123',
+        '[email protected]',
+        NOW()
+    ),
+    (
+        'nikita',
+        'password',
+        '[email protected]',
+        NOW()
+    );

api-example/resources/migrations/20230526142225-create-role.up.sql

@@ -0,0 +1,8 @@
+CREATE TABLE "role"(
+    "id" INT GENERATED ALWAYS AS IDENTITY PRIMARY KEY,
+    "name" VARCHAR (255) UNIQUE NOT NULL
+);
+--;;
+INSERT INTO "role"("name")
+VALUES ('admin'),
+    ('user');

api-example/resources/migrations/20230526142305-create-account-role.up.sql

@@ -0,0 +1,36 @@
+CREATE TABLE "account_role" (
+    "account_id" INT NOT NULL,
+    "role_id" INT NOT NULL,
+    "grant_date" TIMESTAMP,
+    PRIMARY KEY ("account_id", "role_id"),
+    FOREIGN KEY ("role_id") REFERENCES "role" ("id"),
+    FOREIGN KEY ("account_id") REFERENCES "account" ("id")
+);
+--;;
+INSERT INTO "account_role"("account_id", "role_id", "grant_date")
+VALUES (
+        (
+            SELECT "id"
+            FROM "account"
+            WHERE "username" = 'admin'
+        ),
+        (
+            SELECT "id"
+            FROM "role"
+            WHERE "name" = 'admin'
+        ),
+        NOW()
+    ),
+    (
+        (
+            SELECT "id"
+            FROM "account"
+            WHERE "username" = 'nikita'
+        ),
+        (
+            SELECT "id"
+            FROM "role"
+            WHERE "name" = 'user'
+        ),
+        NOW()
+    );

api-example/src/api_example/api/account.clj

@@ -0,0 +1,11 @@
+(ns api-example.api.account
+  (:require [compojure.core :as c]
+            [compojure.coercions :refer [as-int]]
+            [api-example.service.account :as service.account]))
+
+(def routes
+  (c/context "/accounts" {:keys [ctx]}
+    (c/GET "/" [] (service.account/get-all ctx))
+    (c/POST "/" {:keys [body]} (service.account/create ctx body))
+    (c/context "/:id" [id :<< as-int]
+      (c/GET "/" [] (service.account/get-by-id ctx id)))))

api-example/src/api_example/core.clj

@@ -0,0 +1,88 @@
+(ns api-example.core
+  (:require [camel-snake-kebab.core :as csk]
+            [clojure.spec.alpha :as s]
+            [integrant.core :as ig]
+            [api-example.middleware]
+            [api-example.router :refer [router]]
+            [api-example.spec :as spec]
+            [api-example.util :as u]
+            [migratus.core :as migratus]
+            [next.jdbc :as jdbc]
+            [ring.adapter.jetty :refer [run-jetty]]
+            [ring.middleware.json])
+  (:gen-class))
+
+;; DB
+
+(defmethod ig/pre-init-spec :core/db [_]
+  (s/keys :req-un [::spec/config]))
+
+(defmethod ig/init-key :core/db
+  [_ {:keys [config]}]
+  config)
+
+;; Migrator
+
+(defmethod ig/init-key :core/migrator
+  [_ {:keys [db]}]
+  (let [ds (jdbc/get-datasource db)
+        config {:store :database
+                :migration-dir "migrations"
+                :db {:datasource ds}}]
+    (migratus/migrate config)
+    ds))
+
+(comment
+  (migratus/create {:migration-dir "migrations"} "create-account-role")
+  (migratus/create {:migration-dir "migrations"} "create-account" :edn)
+  )
+
+;; App
+
+(def ^:dynamic *ctx*
+  nil)
+
+(defmethod ig/init-key :core/app
+  [_ {:keys [ds]}]
+  (binding [*ctx* {:ds ds}]
+    (-> router
+        
+        (ring.middleware.json/wrap-json-body {:key-fn csk/->kebab-case-keyword})
+        
+        (api-example.middleware/wrap-request-ctx *ctx*)
+
+        (api-example.middleware/wrap-postgres-exception)
+        (api-example.middleware/wrap-fallback-exception)
+        
+        (ring.middleware.json/wrap-json-response {:key-fn csk/->camelCaseString}))))
+
+;; Server
+
+(defmethod ig/init-key :core/server
+  [_ {:keys [app config]}]
+  (run-jetty app config))
+
+(defmethod ig/halt-key! :core/server
+  [_ server]
+  (.stop server))
+
+;; Whole system
+
+(defonce system
+  (atom nil))
+
+(defn start-system
+  [config]
+  (when @system
+    (ig/halt! @system))
+  (reset! system (ig/init config)))
+
+(defn -main
+  [profile & _args]
+  (let [profile-kw (keyword profile)
+        config (u/load-config "config.edn" {:profile profile-kw})]
+    (println config)
+    (start-system config)))
+
+#_(-main "local")
+#_(ig/halt! @system)

api-example/src/api_example/dao/account.clj

@@ -0,0 +1,24 @@
+(ns api-example.dao.account
+  (:require [api-example.dao.util :refer [sql-format execute! execute-one!]]))
+
+(def table
+  :account)
+
+(defn get-all
+  [ds]
+  (let [query (sql-format {:select [:*]
+                           :from table})]
+    (execute! ds query)))
+
+(defn get-by-id
+  [ds id]
+  (let [query (sql-format {:select [:*]
+                           :from table
+                           :where [:= :id id]})]
+    (execute-one! ds query)))
+
+(defn create
+  [ds entity]
+  (let [query (sql-format {:insert-into table
+                           :values [entity]})]
+    (execute-one! ds query)))