- Added !log command to allow moderators or admins to see the last 25 commands used globally, or use a color after it, to see the last 25 commands used by a player.

- Added Spawner to Restricted Units

Author: Motive

Chat/ChatHandler.galaxy

@@ -193,6 +193,7 @@ void libcrtx_chat_parsechat(int lp_player, string lp_message, int lp_recursionLi
 		libcrtx_variable_delete(lp_player, libcrtx_variable_name_return);
 
 		libcrtx_chat_set_parse_line( lp_player, lp_message );
+		libcrtx_log_event(lp_player, lp_message);
 		TriggerExecute(t, false, false);
 	} else {
 		// No such command for this iteration

Commands/AdminCommands.galaxy

@@ -868,4 +868,23 @@ bool libcrtx_command_trolls(bool testConds, bool runActions)
 	}
 
 	return true;
-}
+}
+
+bool libcrtx_command_log(bool checkConds, bool runActions)
+{
+	int plr = -1;
+	string val = StringWord( libcrtx_chat_get_parse_line(EventPlayer()), 2 );
+	plr = libcrtx_color_to_player( val );
+	
+	if( libcrtx_admin_getpermissions( EventPlayer() ) < libcrtx_admin_permissionlevel_moderator ) {
+		return true;
+	}
+	
+	if( plr != -1 )
+	{
+		libcrtx_write_text(PlayerGroupSingle(EventPlayer()), libcrtx_log_getlog(plr));
+	} else {
+		libcrtx_write_text(PlayerGroupSingle(EventPlayer()), libcrtx_log_getgloballog());
+	}
+	return true;
+}

Commands/Commands.galaxy

@@ -118,6 +118,7 @@ void libcrtx_commands_init()
 	libcrtx_command_create("!light", "libcrtx_command_light");
 	libcrtx_command_create("!creepspeed", "libcrtx_command_creepspeed");
 	libcrtx_command_create("!trolls", "libcrtx_command_trolls");
+	libcrtx_command_create("!log", "libcrtx_command_log");
 
 
 	// region commands

Common/Global.galaxy

@@ -78,3 +78,5 @@ include "Cortex/Common/SharedData.galaxy"
 include "Cortex/Common/CortexID.galaxy"
 include "Cortex/Common/Utility.galaxy"
 include "Cortex/Common/ComputerAI.galaxy"
+include "Cortex/Common/Log.galaxy"
+

Common/Log.galaxy

@@ -0,0 +1,103 @@
+// Cortex SC2 Roleplaying Engine
+// Copyright (C) 2009-2011 <http://www.cortexrp.com/>
+//
+// This program is free software; you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation; version 2 of the License.
+// 
+// This program is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+// GNU General Public License for more details.
+
+const int c_cortexMaxLoggedCommands = 25;
+
+string[libcrtx_max_players][c_cortexMaxLoggedCommands] libcrtx_log_perplayerlog;
+string[c_cortexMaxLoggedCommands] libcrtx_log_globallog;
+int[c_cortexMaxLoggedCommands] libcrtx_log_globallogplayers;
+
+static void libcrtx_log_event_individual(int player, string message)
+{
+	int currentLevel = 0;
+	
+	// Find free index and insert, if possible
+	while(currentLevel < c_cortexMaxLoggedCommands)
+	{
+		if( libcrtx_log_perplayerlog[player][currentLevel] == "" ) {
+			libcrtx_log_perplayerlog[player][currentLevel] = message;
+			return;
+		}
+		currentLevel += 1;
+	}
+	
+	// We're out of space! Discard one message and move the rest upward one level, and use last index.
+	currentLevel = 1;
+	while(currentLevel < c_cortexMaxLoggedCommands)
+	{
+		libcrtx_log_perplayerlog[player][currentLevel - 1] = libcrtx_log_perplayerlog[player][currentLevel]; 
+		currentLevel += 1;
+	}
+	libcrtx_log_perplayerlog[player][c_cortexMaxLoggedCommands - 1] = message;
+}
+
+static void libcrtx_log_event_global(int player, string message)
+{
+	int currentLevel = 0;
+	
+	// Find free index and insert, if possible
+	while(currentLevel < c_cortexMaxLoggedCommands)
+	{
+		if( libcrtx_log_globallog[currentLevel] == "" ) {
+			libcrtx_log_globallog[currentLevel] = message;
+			libcrtx_log_globallogplayers[currentLevel] = player;
+			return;
+		}
+		currentLevel += 1;
+	}
+	
+	// We're out of space! Discard one message and move the rest upward one level, and use last index.
+	currentLevel = 1;
+	while(currentLevel < c_cortexMaxLoggedCommands)
+	{
+		libcrtx_log_globallog[currentLevel - 1] = libcrtx_log_globallog[currentLevel]; 
+		currentLevel += 1;
+	}
+	libcrtx_log_globallog[c_cortexMaxLoggedCommands - 1] = message;
+	libcrtx_log_globallogplayers[c_cortexMaxLoggedCommands - 1] = player;
+}
+
+void libcrtx_log_event(int player, string message)
+{
+	libcrtx_log_event_individual(player, message);
+	libcrtx_log_event_global(player, message);
+}
+
+text libcrtx_log_getlog(int player)
+{
+	text ret = StringToText(libcrtx_log_perplayerlog[player][0]);
+	int i = 1;
+	while(i < c_cortexMaxLoggedCommands)
+	{
+		if( libcrtx_log_perplayerlog[player][i] != "" )
+		{
+			ret += StringToText("<n />") + libcrtx_colored_player_name(player) + StringToText(": " + libcrtx_log_perplayerlog[player][i]);
+		}
+		i += 1;
+	}
+	return ret;
+}
+
+text libcrtx_log_getgloballog()
+{
+	text ret = StringToText(libcrtx_log_globallog[0]);
+	int i = 1;
+	while(i < c_cortexMaxLoggedCommands)
+	{
+		if( libcrtx_log_globallog[i] != "" )
+		{
+			ret += StringToText("<n />") + libcrtx_colored_player_name(libcrtx_log_globallogplayers[i]) + StringToText(": " + libcrtx_log_globallog[i]);
+		}
+		i += 1;
+	}
+	return ret;
+}

Toolkit/DefaultToolkit/UnitToolkit.galaxy

@@ -57,6 +57,7 @@ void libcrtx_toolkit_default_initunittools()
 
 void libcrtx_toolkit_default_initrestrictedunits()
 {
+	libcrtx_toolkit_addrestrictedunit("Spawner");
 	libcrtx_toolkit_addrestrictedunit("nukenoodle");
 }