Better support for inline attachments. Fixes #137

Co-authored-by: Jarrod Moldrich <[email protected]>

Author: andrewtimberlake

CHANGELOG.md

@@ -1,12 +1,18 @@
 # Changelog
 
+## 0.4.5
+
+* Update RFC2822 Renderer to correctly render multipart combinations of `multipart/alternative`, `multipart/related`, and `multipart/mixed` https://github.com/DockYard/elixir-mail/pull/137
+* Update `Mail.get_attachments/2` to handle inline attachments
+* Update `Mail.Message.is_attachment?/2` to handle inline attachments
+
 ## 0.4.4 2025-03-24
 
-* Quote address name when needed #190
-* Encode address name when needed #189
-* Fix infinite loop with invalid parameters #187
-* Fix parsing of multiple recipients #
-* Fix get_html/1 to correctly handle multiple parameters in the content-type header #186
+* Quote address name when needed https://github.com/DockYard/elixir-mail/pull/190
+* Encode address name when needed https://github.com/DockYard/elixir-mail/pull/189
+* Fix infinite loop with invalid parameters https://github.com/DockYard/elixir-mail/pull/187
+* Fix parsing of multiple recipients
+* Fix get_html/1 to correctly handle multiple parameters in the content-type header https://github.com/DockYard/elixir-mail/pull/186
 
 ## 0.4.3 2024-11-15
 

lib/mail.ex

@@ -54,13 +54,11 @@ defmodule Mail do
   def put_text(message, body, opts \\ [])
 
   def put_text(%Mail.Message{multipart: true} = message, body, opts) do
-    message =
-      case Enum.find(message.parts, &Mail.Message.match_body_text/1) do
-        %Mail.Message{} = part -> Mail.Message.delete_part(message, part)
-        _ -> message
-      end
-
-    Mail.Message.put_part(message, Mail.Message.build_text(body, opts))
+    Mail.Message.replace_part(
+      message,
+      &Mail.Message.match_body_text/1,
+      Mail.Message.build_text(body, opts)
+    )
   end
 
   def put_text(%Mail.Message{} = message, body, opts) do
@@ -115,13 +113,11 @@ defmodule Mail do
   def put_html(message, body, opts \\ [])
 
   def put_html(%Mail.Message{multipart: true} = message, body, opts) do
-    message =
-      case Enum.find(message.parts, &Mail.Message.match_content_type?(&1, "text/html")) do
-        %Mail.Message{} = part -> Mail.Message.delete_part(message, part)
-        _ -> message
-      end
-
-    Mail.Message.put_part(message, Mail.Message.build_html(body, opts))
+    Mail.Message.replace_part(
+      message,
+      &Mail.Message.match_content_type?(&1, "text/html"),
+      Mail.Message.build_html(body, opts)
+    )
   end
 
   def put_html(%Mail.Message{} = message, body, opts) do
@@ -223,24 +219,30 @@ defmodule Mail do
   @doc """
   Walks the message parts and collects all attachments
 
+  Types:
+  - `:all` - all attachments
+  - `:attachment` - only attachments (default)
+  - `:inline` - only inline attachments
+
   Each member in the list is `{filename, content}`
   """
-  def get_attachments(%Mail.Message{} = message) do
+  @spec get_attachments(Mail.Message.t(), :all | :attachment | :inline) :: [
+          {String.t(), binary()}
+        ]
+  def get_attachments(%Mail.Message{} = message, type \\ :attachment) do
     walk_parts([message], {:cont, []}, fn message, acc ->
-      case Mail.Message.is_attachment?(message) do
-        true ->
-          filename =
-            case List.wrap(Mail.Message.get_header(message, :content_disposition)) do
-              ["attachment" | properties] ->
-                Enum.find_value(properties, "Unknown", fn {key, value} ->
-                  key == "filename" && value
-                end)
-            end
-
-          {:cont, List.insert_at(acc, -1, {filename, message.body})}
-
-        false ->
-          {:cont, acc}
+      if Mail.Message.is_attachment?(message, type) do
+        filename =
+          case List.wrap(Mail.Message.get_header(message, :content_disposition)) do
+            [_ | properties] ->
+              Enum.find_value(properties, "Unknown", fn {key, value} ->
+                key == "filename" && value
+              end)
+          end
+
+        {:cont, List.insert_at(acc, -1, {filename, message.body})}
+      else
+        {:cont, acc}
       end
     end)
     |> elem(1)

lib/mail/message.ex

@@ -18,6 +18,19 @@ defmodule Mail.Message do
     put_in(message.parts, message.parts ++ [part])
   end
 
+  def put_parts(message, parts) when is_list(parts) do
+    put_in(message.parts, message.parts ++ parts)
+  end
+
+  def replace_part(message, match_fun, %Mail.Message{} = part) when is_function(match_fun, 1) do
+    parts =
+      message.parts
+      |> Enum.reject(match_fun)
+      |> Kernel.++([part])
+
+    %{message | parts: parts}
+  end
+
   @doc """
   Delete a matching part
 
@@ -375,21 +388,40 @@ defmodule Mail.Message do
   @doc """
   Is the part an attachment or not
 
+  Types:
+  - `:all` - all attachments
+  - `:attachment` - only attachments (default)
+  - `:inline` - only inline attachments
+
   Returns `Boolean`
   """
-  def is_attachment?(message),
-    do: Enum.member?(List.wrap(get_header(message, :content_disposition)), "attachment")
+  @spec is_attachment?(Mail.Message.t(), :all | :attachment | :inline) :: boolean()
+  def is_attachment?(message, type \\ :attachment) do
+    types =
+      case type do
+        :all -> ["attachment", "inline"]
+        :attachment -> ["attachment"]
+        :inline -> ["inline"]
+      end
+
+    case List.wrap(get_header(message, :content_disposition)) do
+      [disposition | _] -> disposition in types
+      _ -> false
+    end
+  end
 
   @doc """
   Determines the message has any attachment parts
 
   Returns a `Boolean`
   """
-  def has_attachment?(parts) when is_list(parts),
-    do: has_part?(parts, &is_attachment?/1)
+  def has_attachment?(parts, type \\ :attachment)
+
+  def has_attachment?(parts, type) when is_list(parts),
+    do: has_part?(parts, &is_attachment?(&1, type))
 
-  def has_attachment?(message),
-    do: has_attachment?(message.parts)
+  def has_attachment?(message, type),
+    do: has_attachment?(message.parts, type)
 
   @doc """
   Is the message text based or not

lib/mail/renderers/rfc_2822.ex

@@ -138,7 +138,9 @@ defmodule Mail.Renderers.RFC2822 do
     end
   end
 
-  defp render_address({name, email}), do: "#{encode_header_value(~s("#{name}"), :quoted_printable)} <#{validate_address(email)}>"
+  defp render_address({name, email}),
+    do: "#{encode_header_value(~s("#{name}"), :quoted_printable)} <#{validate_address(email)}>"
+
   defp render_address(email), do: validate_address(email)
 
   defp render_subtypes([]), do: []
@@ -261,31 +263,45 @@ defmodule Mail.Renderers.RFC2822 do
   end
 
   defp reorganize(%Mail.Message{multipart: true} = message) do
-    content_type = Mail.Message.get_content_type(message)
-
-    if Mail.Message.has_attachment?(message) do
-      text_parts =
-        Enum.filter(message.parts, &match_content_type?(&1, ~r/text\/(plain|html)/))
-        |> Enum.sort(&(&1 > &2))
-
-      content_type = List.replace_at(content_type, 0, "multipart/mixed")
-      message = Mail.Message.put_content_type(message, content_type)
+    {text_parts, attachments} =
+      message.parts
+      |> Enum.split_with(&match_content_type?(&1, ~r/text\/(plain|html)/))
 
-      if Enum.any?(text_parts) do
-        message = Enum.reduce(text_parts, message, &Mail.Message.delete_part(&2, &1))
+    {inline_attachments, other_attachments} =
+      Enum.split_with(attachments, &Mail.Message.is_attachment?(&1, :inline))
 
-        mixed_part =
+    if Enum.empty?(text_parts) do
+      Mail.Message.put_content_type(message, "multipart/mixed")
+    else
+      alternative =
+        case text_parts do
+          [part] ->
+            part
+
+          text_parts ->
+            Mail.build_multipart()
+            |> Mail.Message.put_content_type("multipart/alternative")
+            |> Mail.Message.put_parts(text_parts)
+        end
+
+      related =
+        if Enum.empty?(inline_attachments) do
+          alternative
+        else
           Mail.build_multipart()
-          |> Mail.Message.put_content_type("multipart/alternative")
+          |> Mail.Message.put_content_type("multipart/related")
+          |> Mail.Message.put_part(alternative)
+          |> Mail.Message.put_parts(inline_attachments)
+        end
 
-        mixed_part = Enum.reduce(text_parts, mixed_part, &Mail.Message.put_part(&2, &1))
-        put_in(message.parts, List.insert_at(message.parts, 0, mixed_part))
+      if Enum.empty?(other_attachments) do
+        related
       else
-        message
+        Mail.build_multipart()
+        |> Mail.Message.put_content_type("multipart/mixed")
+        |> Mail.Message.put_part(related)
+        |> Mail.Message.put_parts(other_attachments)
       end
-    else
-      content_type = List.replace_at(content_type, 0, "multipart/alternative")
-      Mail.Message.put_content_type(message, content_type)
     end
   end
 

test/mail/message_test.exs

@@ -244,8 +244,11 @@ defmodule Mail.MessageTest do
       |> Mail.put_to(to)
       |> Mail.render()
 
-    encoded_from = ~s(From: =?UTF-8?Q?"#{Mail.Encoders.QuotedPrintable.encode(elem(from, 0))}"?= <#{elem(from, 1)}>)
-    encoded_to = ~s(To: =?UTF-8?Q?"#{Mail.Encoders.QuotedPrintable.encode(elem(to, 0))}"?= <#{elem(to, 1)}>)
+    encoded_from =
+      ~s(From: =?UTF-8?Q?"#{Mail.Encoders.QuotedPrintable.encode(elem(from, 0))}"?= <#{elem(from, 1)}>)
+
+    encoded_to =
+      ~s(To: =?UTF-8?Q?"#{Mail.Encoders.QuotedPrintable.encode(elem(to, 0))}"?= <#{elem(to, 1)}>)
 
     assert txt =~ encoded_from
     assert txt =~ encoded_to