First commit

Author: FabienHenon

.gitignore

@@ -2,3 +2,4 @@
 elm-stuff
 # elm-repl generated files
 repl-temp-*
+.DS_Store

README.md

@@ -1,2 +1,37 @@
 # jsonapi-http-retry
-Retry failed jsonapi requests with retry policies
+
+Retry failed jsonapi requests with retry policies.
+
+It uses the [`Retry` package](https://package.elm-lang.org/packages/choonkeat/elm-retry/latest/) and the [`jsonapi-http` package](https://package.elm-lang.org/packages/calions-app/jsonapi-http/latest/) under the hood.
+
+With this package you can add [`retry`](https://package.elm-lang.org/packages/choonkeat/elm-retry/latest/) policies to [`jsonapi-http`](https://package.elm-lang.org/packages/calions-app/jsonapi-http/latest/) requests errors.
+You can choose specific errors that will trigger a retry: unauthenticated error, network error, etc...
+
+## Getting Started
+
+Here is an example retrying requests 5 times maximum with a constant interval between retries, only for unauthenticated and unauthorized errors:
+
+```elm
+import Http.Request
+import Http.Retry
+import Json.Encode
+import JsonApi.Decode
+import Retry
+
+request : Cmd Msg
+request =
+    Request.request
+        { url = "http://endpoint"
+        , headers = []
+        , body = Json.Encode.object []
+        , documentDecoder = JsonApi.Decode.resources "resource-type" entityDecoder
+        }
+        |> Http.Retry.with
+            [ Retry.maxRetries 5
+            , Retry.exponentialBackoff { interval = 500, maxInterval = 3000 }
+            ]
+            [ Http.Retry.onUnauthenticatedStatus
+            , Http.Retry.onUnauthorizedStatus
+            ]
+        |> Task.perform OnTaskCompleted
+```

elm.json

@@ -0,0 +1,19 @@
+{
+    "type": "package",
+    "name": "calions-app/jsonapi-http-retry",
+    "summary": "Retry failed jsonapi requests with policies",
+    "license": "MIT",
+    "version": "1.0.0",
+    "exposed-modules": [
+        "Http.Retry"
+    ],
+    "elm-version": "0.19.0 <= v < 0.20.0",
+    "dependencies": {
+        "calions-app/jsonapi-http": "1.1.0 <= v < 2.0.0",
+        "choonkeat/elm-retry": "1.0.1 <= v < 2.0.0",
+        "elm/core": "1.0.5 <= v < 2.0.0",
+        "elm/http": "2.0.0 <= v < 3.0.0",
+        "krisajenkins/remotedata": "6.0.1 <= v < 7.0.0"
+    },
+    "test-dependencies": {}
+}

src/Http/Retry.elm

@@ -0,0 +1,160 @@
+module Http.Retry exposing
+    ( with
+    , FailureCondition, onStatus, onUnauthenticatedStatus, onUnauthorizedStatus, onNetworkError, onTimeout, onAllFailures
+    )
+
+{-| Add retries to a jsonapi http task, based on a list of retry policies, until any one of
+the policies fail too.
+
+@docs with
+
+
+# Failure conditions
+
+@docs FailureCondition, onStatus, onUnauthenticatedStatus, onUnauthorizedStatus, onNetworkError, onTimeout, onAllFailures
+
+-}
+
+import Http
+import Http.Error
+import RemoteData
+import Retry
+import Task exposing (Task)
+
+
+{-| FailureCondition contains a function that filter request errors
+-}
+type FailureCondition
+    = FailureCondition (Http.Error.RequestError -> Bool)
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying errors base on the 401 status code
+-}
+onUnauthenticatedStatus : FailureCondition
+onUnauthenticatedStatus =
+    let
+        conditionCheck err =
+            case err of
+                Http.Error.HttpError (Http.BadStatus 401) ->
+                    True
+
+                _ ->
+                    False
+    in
+    FailureCondition conditionCheck
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying errors base on the 403 status code
+-}
+onUnauthorizedStatus : FailureCondition
+onUnauthorizedStatus =
+    let
+        conditionCheck err =
+            case err of
+                Http.Error.HttpError (Http.BadStatus 403) ->
+                    True
+
+                _ ->
+                    False
+    in
+    FailureCondition conditionCheck
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying errors based on the status code
+-}
+onStatus : Int -> FailureCondition
+onStatus statusCode =
+    let
+        conditionCheck err =
+            case err of
+                Http.Error.HttpError (Http.BadStatus code) ->
+                    code == statusCode
+
+                _ ->
+                    False
+    in
+    FailureCondition conditionCheck
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying all network errors
+-}
+onNetworkError : FailureCondition
+onNetworkError =
+    let
+        conditionCheck err =
+            case err of
+                Http.Error.HttpError Http.NetworkError ->
+                    True
+
+                _ ->
+                    False
+    in
+    FailureCondition conditionCheck
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying all timeout errors
+-}
+onTimeout : FailureCondition
+onTimeout =
+    let
+        conditionCheck err =
+            case err of
+                Http.Error.HttpError Http.Timeout ->
+                    True
+
+                _ ->
+                    False
+    in
+    FailureCondition conditionCheck
+
+
+{-| To use with `with` function. Filters errors to be retried by retrying all errors
+-}
+onAllFailures : FailureCondition
+onAllFailures =
+    let
+        conditionCheck err =
+            True
+    in
+    FailureCondition conditionCheck
+
+
+{-| Given a list of error handling `Policy` from [`Retry` package](https://package.elm-lang.org/packages/choonkeat/elm-retry/latest/) we can make our `originalTask`
+retry on failure until any one of the `Policy` fails.
+
+    originalTask
+        |> Http.Retry.with
+            [ Retry.maxDuration 7000
+            , Retry.exponentialBackoff { interval = 500, maxInterval = 3000 }
+            ]
+            [ Http.Retry.onUnauthenticatedStatus ]
+        |> Task.perform DidOriginalTask
+
+-}
+with : List (Retry.Policy Http.Error.RequestError) -> List FailureCondition -> Task Never (RemoteData.RemoteData Http.Error.RequestError data) -> Task Never (RemoteData.RemoteData Http.Error.RequestError data)
+with errTasks failureConditions originalTask =
+    originalTask
+        |> Task.mapError (always (Http.Error.CustomError "no error"))
+        |> Task.andThen (convertToError failureConditions)
+        |> Retry.with errTasks
+        |> Task.onError (RemoteData.Failure >> Task.succeed)
+
+
+convertToError : List FailureCondition -> RemoteData.RemoteData Http.Error.RequestError data -> Task Http.Error.RequestError (RemoteData.RemoteData Http.Error.RequestError data)
+convertToError failureConditions result =
+    case result of
+        RemoteData.Loading ->
+            Task.succeed result
+
+        RemoteData.NotAsked ->
+            Task.succeed result
+
+        RemoteData.Success d ->
+            Task.succeed result
+
+        RemoteData.Failure err ->
+            if List.any (\(FailureCondition f) -> f err) failureConditions then
+                Task.fail err
+
+            else
+                Task.succeed result