build.gradle

plugins {
    id 'org.springframework.boot' version '1.5.22.RELEASE'
    id "org.jetbrains.kotlin.jvm" version "1.3.61"
    id "org.jetbrains.kotlin.plugin.spring" version "1.3.61"
    id "com.github.kt3k.coveralls" version "2.9.0"
    id 'jacoco'
}

version = '0.1'
sourceCompatibility = 11
targetCompatibility = 11

repositories {
    jcenter()
}

dependencies {
    // Kotlin
    compile('org.jetbrains.kotlin:kotlin-stdlib-jdk8')
    // Spring Boot
    compile('org.springframework.boot:spring-boot-starter-web')
    compile('org.springframework.boot:spring-boot-starter-data-jpa')
    compile('org.springframework.boot:spring-boot-starter-mail')
    runtime('javax.xml.bind:jaxb-api:2.3.0')
    // Spring Security
    compile('org.springframework.security:spring-security-web:4.2.14.RELEASE')
    // Spring Context Support
    compile('org.springframework:spring-context-support')
    // Vaadin
    compile('com.vaadin:vaadin-spring-boot-starter')
    // Utilities
    compile('com.sun.mail:javax.mail')
    compile('org.pegdown:pegdown:1.6.0')
    compile('org.checkerframework:checker-qual:2.5.0')
    // Database
    runtime('com.h2database:h2') // development and test
    runtime('org.postgresql:postgresql:42.2.10') // heroku
    // Tests
    testCompile('org.springframework.boot:spring-boot-starter-test')
}

dependencyManagement {
    imports {
        mavenBom 'com.vaadin:vaadin-bom:8.10.0'
    }
}

jar {
    baseName = 'obog-manager'
    archiveName = baseName + "." + extension
}

springBoot {
    executable = true
}

jacocoTestReport {
    reports {
        xml.enabled = true // coveralls plugin depends on xml format report
        html.enabled = true
    }
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "11"
    }
}
compileTestKotlin {
    kotlinOptions {
        jvmTarget = "11"
    }
}