kotlinx-rpc/settings.gradle.kts at main · Kotlin/kotlinx-rpc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
/*
 * Copyright 2023-2025 JetBrains s.r.o and contributors. Use of this source code is governed by the Apache 2.0 license.
 */

rootProject.name = "kotlinx-rpc"

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

pluginManagement {
    includeBuild("gradle-conventions-settings")
    includeBuild("gradle-conventions")

    includeBuild("gradle-plugin")

    apply(from = "gradle-conventions-settings/src/main/kotlin/conventions-repositories.settings.gradle.kts")
}

plugins {
    id("conventions-repositories")
    id("conventions-version-resolution")
    id("conventions-develocity")
    id("krpc-compat-tests")
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
}

dependencyResolutionManagement {
    includeBuild("compiler-plugin")
    includeBuild("dokka-plugin")
    includeBuild("protoc-gen")
    includeBuild("gradle-plugin")
}

include(":protobuf")
includePublic(":protobuf:protobuf-lite")
includePublic(":protobuf:protobuf-wkt")
includePublic(":protobuf:protobuf")

include(":grpc")
includePublic(":grpc:grpc-core")
includePublic(":grpc:grpc-client")
includePublic(":grpc:grpc-server")
includePublic(":grpc:grpc-ktor-server")
includePublic(":grpc:grpc-marshaller")
includePublic(":grpc:grpc-marshaller-kotlinx-serialization")

includePublic(":bom")

includePublic(":utils")

includePublic(":core")

include(":krpc")
includePublic(":krpc:krpc-core")
includePublic(":krpc:krpc-client")
includePublic(":krpc:krpc-server")
includePublic(":krpc:krpc-logging")
include(":krpc:krpc-test")

include(":krpc:krpc-serialization")
includePublic(":krpc:krpc-serialization:krpc-serialization-core")
includePublic(":krpc:krpc-serialization:krpc-serialization-json")
includePublic(":krpc:krpc-serialization:krpc-serialization-cbor")
includePublic(":krpc:krpc-serialization:krpc-serialization-protobuf")

include(":krpc:krpc-ktor")
includePublic(":krpc:krpc-ktor:krpc-ktor-core")
includePublic(":krpc:krpc-ktor:krpc-ktor-server")
includePublic(":krpc:krpc-ktor:krpc-ktor-client")

include(":tests")
include(":tests:test-utils")
include(":tests:krpc-compatibility-tests")
include(":tests:krpc-protocol-compatibility-tests")
include(":tests:krpc-protocol-compatibility-tests:test-api")
include(":tests:test-protos")
include(":tests:grpc-test-server")
val onWindows = providers.systemProperty("os.name").get().contains("Windows", ignoreCase = true)
if (!onWindows) {
    // The protobuf-conformance configuration doesn't support windows, so we exclude it on Windows.
    include(":tests:protobuf-conformance")
}

include(":tests:protobuf-unittest")
include(":tests:protobuf-playground")

val kotlinMasterBuild = providers.gradleProperty("kotlinx.rpc.kotlinMasterBuild").orNull == "true"

if (!kotlinMasterBuild) {
    include(":tests:compiler-plugin-tests")
    include(":tests:compiler-plugin-tests:compiler-plugin-protos")
}

include(":jpms-check")