DelayedSelectorBasedAccessManager.sol

// SPDX-License-Identifier: Apache-2.0
// Copyright 2017 Loopring Technology Limited.
pragma solidity ^0.7.0;

import "../../lib/Claimable.sol";
import "../../thirdparty/BytesUtil.sol";
import "./DelayedTransaction.sol";

/// @title  DelayedSelectorBasedAccessManager
/// @author Break Xiong - <kl456123@outlook.com>
contract DelayedSelectorBasedAccessManager is DelayedTransaction, Claimable {
    using BytesUtil for bytes;

    address public immutable target;
    mapping(address => mapping(bytes4 => bool)) public permissions;

    event PermissionUpdate(
        address indexed user,
        bytes4 indexed selector,
        bool allowed
    );

    modifier withAccess(bytes4 selector) {
        require(hasAccessTo(msg.sender, selector), "PERMISSION_DENIED");
        _;
    }

    constructor(
        address _target,
        uint _timeToLive
    ) DelayedTransaction(_timeToLive) {
        require(_target != address(0), "ZERO_ADDRESS");
        target = _target;
    }

    receive() external payable {}

    fallback() external payable {
        transact(msg.data);
    }

    function grantAccess(
        address user,
        bytes4 selector,
        bool granted
    ) external onlyOwner {
        require(permissions[user][selector] != granted, "INVALID_VALUE");
        permissions[user][selector] = granted;
        emit PermissionUpdate(user, selector, granted);
    }

    function transact(
        bytes calldata data
    ) public payable withAccess(data.toBytes4(0)) {
        transactInternal(target, msg.value, data);
    }

    function transact(
        address,
        bytes calldata
    ) external payable override nonReentrant onlyAuthorized {
        revert("Deprecated");
    }

    function hasAccessTo(
        address user,
        bytes4 selector
    ) public view returns (bool) {
        return user == owner || permissions[user][selector];
    }

    function isAuthorizedForTransactions(
        address sender
    ) internal view override returns (bool) {
        return hasAccessTo(sender, msg.data.toBytes4(0));
    }

    function setFunctionDelay(bytes4 functionSelector, uint delay) internal {
        setFunctionDelay(target, functionSelector, delay);
    }
}