BinaryPatcher/build.gradle at master · MinecraftForge/BinaryPatcher · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    id 'java-library'
    id 'eclipse'
    id 'maven-publish'
    alias libs.plugins.licenser
    alias libs.plugins.gradleutils
    alias libs.plugins.gitversion
    alias libs.plugins.versions
    alias libs.plugins.shadow
    alias libs.plugins.jarsigner
    alias libs.plugins.changelog
}

final projectDisplayName = 'Binary Patcher'
final projectArtifactId = base.archivesName = 'binarypatcher'
final projectVendor = 'Forge Development LLC'
description = 'Creates and applies binary patches for jar files at the class level.'
group = 'net.minecraftforge'
version = gitversion.tagOffset

println "Version: $version"

jarSigner.autoDetect('forge')

java {
    toolchain.languageVersion = JavaLanguageVersion.of(8)
    withSourcesJar()
}

changelog {
    fromBase()
}

dependencies {
    implementation libs.srgutils
    implementation libs.jopt.simple
    implementation libs.lzma
    implementation libs.xdelta

    testImplementation libs.junit.api
    testRuntimeOnly libs.bundles.junit.runtime
}

license {
    header rootProject.file('LICENSE-header.txt')
    newLine false
}

tasks.named('jar', Jar) {
    manifest {
        attributes([
            'Main-Class'            : 'net.minecraftforge.binarypatcher.ConsoleTool',
            'Specification-Title'   : projectDisplayName,
            'Specification-Vendor'  : projectVendor,
            'Specification-Version' : gitversion.info.tag,
            'Implementation-Title'  : "$project.group:$project.name",
            'Implementation-Vendor' : projectVendor,
            'Implementation-Version': project.version
        ] as LinkedHashMap)
    }

    jarSigner.sign(it)
}

tasks.named('shadowJar', ShadowJar) {
    archiveClassifier = 'fatjar'
    jarSigner.sign(it)

    // Meta stuff we don't need
    exclude('com/google/errorprone/**')
    exclude('META-INF/maven/**')
    exclude('META-INF/proguard/**')

    // We shouldn't ever need to care about conflicts as this is an executable jar, but just be safe
    relocate('net.minecraftforge.srgutils', 'net.minecraftforge.binarypatcher.shadow.srgutils')
    relocate('joptsimple',                  'net.minecraftforge.binarypatcher.shadow.joptsimple')
    relocate('at.spardat.xma.xdelta',       'net.minecraftforge.binarypatcher.shadow.xdelta')
    relocate('com.nothome.delta',           'net.minecraftforge.binarypatcher.shadow.delta')
    relocate('gnu.trove',                   'net.minecraftforge.binarypatcher.shadow.trove')
    relocate('lzma',                        'net.minecraftforge.binarypatcher.shadow.lzma')
    relocate('org.cservenak.streams',       'net.minecraftforge.binarypatcher.shadow.streams')

    // Rewrite JOpt's message files, so that help text is displayed nicely.
    transform(com.github.jengelman.gradle.plugins.shadow.transformers.PropertiesFileTransformer) {
        paths = [ 'Messages.properties$' ]
        keyTransformer = { key -> 'net.minecraftforge.binarypatcher.shadow.' + key }
    }
}

artifacts {
    archives shadowJar
}

test {
    useJUnitPlatform()
}

publishing {
    publications.register('mavenJava', MavenPublication) {
        changelog.publish(it)
        gradleutils.promote(it)

        from components.java

        artifactId = projectArtifactId

        pom { pom ->
            name = projectDisplayName
            description = project.description

            gradleutils.pom.addRemoteDetails(pom)

            licenses {
                license gradleutils.pom.licenses.LGPLv2_1
            }

            developers {
                developer gradleutils.pom.developers.LexManos
            }
        }
    }

    repositories {
        maven gradleutils.publishingForgeMaven
    }
}