libtslitex/version.cmake at main · NateMeyer/libtslitex · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
#
# This cmake module sets the project version and partial version
# variables by analysing the git tag and commit history. It expects git
# tags defined with semantic versioning 2.0.0 (http://semver.org/).
#
# The module expects the PROJECT_NAME variable to be set, and recognizes
# the GIT_FOUND, GIT_EXECUTABLE and VERSION_UPDATE_FROM_GIT variables.
# If Git is found and VERSION_UPDATE_FROM_GIT is set to boolean TRUE,
# the project version will be updated using information fetched from the
# most recent git tag and commit. Otherwise, the module will try to read
# a VERSION file containing the full and partial versions. The module
# will update this file each time the project version is updated.
#
# Once done, this module will define the following variables:
#
# ${PROJECT_NAME}_VERSION_STRING - Version string without metadata
# such as "v2.0.0" or "v1.2.41-beta.1". This should correspond to the
# most recent git tag.
# ${PROJECT_NAME}_VERSION_STRING_FULL - Version string with metadata
# such as "v2.0.0+3.a23fbc" or "v1.3.1-alpha.2+4.9c4fd1"
# ${PROJECT_NAME}_VERSION - Same as ${PROJECT_NAME}_VERSION_STRING,
# without the preceding 'v', e.g. "2.0.0" or "1.2.41-beta.1"
# ${PROJECT_NAME}_VERSION_MAJOR - Major version integer (e.g. 2 in v2.3.1-RC.2+21.ef12c8)
# ${PROJECT_NAME}_VERSION_MINOR - Minor version integer (e.g. 3 in v2.3.1-RC.2+21.ef12c8)
# ${PROJECT_NAME}_VERSION_PATCH - Patch version integer (e.g. 1 in v2.3.1-RC.2+21.ef12c8)
# ${PROJECT_NAME}_VERSION_TWEAK - Tweak version string (e.g. "RC.2" in v2.3.1-RC.2+21.ef12c8)
# ${PROJECT_NAME}_VERSION_AHEAD - How many commits ahead of last tag (e.g. 21 in v2.3.1-RC.2+21.ef12c8)
# ${PROJECT_NAME}_VERSION_GIT_SHA - The git sha1 of the most recent commit (e.g. the "ef12c8" in v2.3.1-RC.2+21.ef12c8)
#
# This module is public domain, use it as it fits you best.
#
# Author: Nuno Fachada

find_package(Git)

# Check if git is found...
if (GIT_FOUND)

	# Get last tag from git
	execute_process(COMMAND ${GIT_EXECUTABLE} describe --abbrev=0 --tags
		WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
		OUTPUT_VARIABLE ${PROJECT_NAME}_VERSION_STRING
		OUTPUT_STRIP_TRAILING_WHITESPACE
		RESULT_VARIABLE GIT_DESCRIBE_RESULT)

	if (NOT GIT_DESCRIBE_RESULT EQUAL 0)
		set(${PROJECT_NAME}_VERSION_STRING "v0.0.0")
        set(${PROJECT_NAME}_VERSION_MAJOR 0)
        set(${PROJECT_NAME}_VERSION_MINOR 0)
        set(${PROJECT_NAME}_VERSION_PATCH 0)
        set(${PROJECT_NAME}_VERSION_TWEAK "")
        set(${PROJECT_NAME}_VERSION_AHEAD 0)
        set(${PROJECT_NAME}_VERSION_GIT_SHA "unknown")
    else()
		#How many commits since last tag
		execute_process(COMMAND ${GIT_EXECUTABLE} rev-list main ${${PROJECT_NAME}_VERSION_STRING}^..HEAD --count
			WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
			OUTPUT_VARIABLE ${PROJECT_NAME}_VERSION_AHEAD
			OUTPUT_STRIP_TRAILING_WHITESPACE
			ERROR_QUIET
			RESULT_VARIABLE GIT_REVLIST_RESULT)

		if (NOT GIT_REVLIST_RESULT EQUAL 0)
			set(${PROJECT_NAME}_VERSION_AHEAD 0)
		endif()

		# Get current commit SHA from git
		execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
			WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
			OUTPUT_VARIABLE ${PROJECT_NAME}_VERSION_GIT_SHA
			OUTPUT_STRIP_TRAILING_WHITESPACE)

		# Get partial versions into a list
		string(REGEX MATCHALL "-.*$|[0-9]+" ${PROJECT_NAME}_PARTIAL_VERSION_LIST
			${${PROJECT_NAME}_VERSION_STRING})

		# Set the version numbers
		list(GET ${PROJECT_NAME}_PARTIAL_VERSION_LIST
			0 ${PROJECT_NAME}_VERSION_MAJOR)
		list(GET ${PROJECT_NAME}_PARTIAL_VERSION_LIST
			1 ${PROJECT_NAME}_VERSION_MINOR)
		list(GET ${PROJECT_NAME}_PARTIAL_VERSION_LIST
			2 ${PROJECT_NAME}_VERSION_PATCH)

		# The tweak part is optional, so check if the list contains it
		list(LENGTH ${PROJECT_NAME}_PARTIAL_VERSION_LIST
			${PROJECT_NAME}_PARTIAL_VERSION_LIST_LEN)
		if (${PROJECT_NAME}_PARTIAL_VERSION_LIST_LEN GREATER 3)
			list(GET ${PROJECT_NAME}_PARTIAL_VERSION_LIST 3 ${PROJECT_NAME}_VERSION_TWEAK)
			string(SUBSTRING ${${PROJECT_NAME}_VERSION_TWEAK} 1 -1 ${PROJECT_NAME}_VERSION_TWEAK)
		endif()

		# Unset the list
		unset(${PROJECT_NAME}_PARTIAL_VERSION_LIST)
	endif()

	# Set full project version string
	set(${PROJECT_NAME}_VERSION_STRING_FULL
		${${PROJECT_NAME}_VERSION_STRING}+${${PROJECT_NAME}_VERSION_AHEAD}.${${PROJECT_NAME}_VERSION_GIT_SHA})

else()

	# Git not available, get version from file
	set(${PROJECT_NAME}_VERSION_STRING_FULL "unknown-version")

endif()


# Set project version (without the preceding 'v')
message(STATUS "Setting ${PROJECT_NAME} version to: ${${PROJECT_NAME}_VERSION_STRING_FULL}")
set(${PROJECT_NAME}_VERSION ${${PROJECT_NAME}_VERSION_MAJOR}.${${PROJECT_NAME}_VERSION_MINOR}.${${PROJECT_NAME}_VERSION_PATCH})
if (${PROJECT_NAME}_VERSION_TWEAK)
	set(${PROJECT_NAME}_VERSION ${${PROJECT_NAME}_VERSION}-${${PROJECT_NAME}_VERSION_TWEAK})
endif()