I am trying to set up a save system

[MrCherry09]

I don't think I am doing this correctly. Can someone explain how i can do this and does anyone have code for it?

[Raptorq1]

Just check this discussion #206

[r6915ee]

I'm not sure if you mean something like a save select screen as with discussion #206 or just the system, but for now I will cover the latter due to the usage of the word "system."

One basic way to add saving itself is to use Godot's ConfigFile. It is used for making configuration files, which include save files on some occasions. I believe Worlds Next already applies this with how it handles configuration. The Godot documentation for the class describes how to use ConfigFile, so for now I will not be covering that, but I will explain some methods.

While I haven't checked if Worlds Next does this as well, one way I do this is to use dictionaries and iterate over them. I'd recommend doing this in an autoload script.

First I declare a string that I can reuse for the save path:

var save_path : String = "user://.data"

Then, I create the save data variable. This variable is actually a dictionary, so manipulating it is the same as how you manipulate any regular dictionary. Each key in the dictionary is another dictionary, which contains certain variables and their values. In the context of this saving system, these top-level keys can be referred to as tables or sections.

var data : Dictionary = {
	"gameplay": {
		"some_var": "super awesome"
	},
	"settings": {
		"video_scale": 3,
		"max_fps": 60
	}
}

ConfigFiles provide an interface to write and read from the disk in an INI file-styled fashion. An INI file is a type of configuration file, much like JSON or YAML, using key-value pairs. Dictionaries ALSO use key-value pairs, making it easily translatable. INI files contain segments aptly known as sections or tables, hence why I call the top-level keys in the data dictionary such: those top-level dictionaries are translated into INI tables. Now back on to the saving system.

I first construct a ConfigFile somewhere at the top level scope and check if loading the data file was successful somewhere else:

var config_data : ConfigFile = ConfigFile.new()

# . . .

if config_data.load(save_path) != OK:
	print("Creating save file")
	save_data()
else:
	print("Loading save file")
	load_data()

Two methods are defined. One is for saving the data, and the other is for loading the data. Both methods use iteration on data in both instances and its respective child dictionaries. In the case of loading, it makes sure that only keys that exist in data are loaded in. Checking for keys existing in the save file is done while loading, and loading saves immediately afterwards just in case.

func load_data():
	for key in data:
		for subkey in data[key]:
			if config_data.has_section_key(key, subkey) == true:
				data[key][subkey] = config_data.get_value(key, subkey)
	save_data()

func save_data():
	for key in data:
		for subkey in data[key]:
			config_data.set_value(key, subkey, data[key][subkey])
	config_data.save(save_path)

From this point, you can load and save data using load_data() and save_data() respectively from the script all of this code is in. This is best to implement in an autoload script because it will be accessible everywhere. If you need multiple save files, you may be able to use multiple dictionaries or put it all in one dictionary to save a few lines of code, but for now I will not be covering that as well.

If you need a screen to launch save files, then on that end I'm not exactly sure how to help. In my experience in using Godot, I've never implemented a save select screen, so I apologize on that end.

[Raptorq1]

Okay but if you checked it there would be a link to a reddit post on the godot reddit talking about the topic and it will allow you how to make a save system similar to sonic 3

https://www.reddit.com/r/godot/comments/16fhfbx/how_would_i_do_this_effect/?rdt=45881

[r6915ee]

I have seen this post before, that is for the save screen and not the actual system. Besides, searching through the Godot subreddit just for that post is not a very good thing. Along with this, I am describing the method I personally use when making games in Godot. OP also already checked that discussion as well because they commented in there before you commented, Raptor.

[MrCherry09]

Thank you for all this help but i still can't figure out how to make it so unlocked stages are saved so that the player can only access the unlocked ones

[r6915ee]

One such example in the case of having a specific order to the levels like much of the original classic Sonic games is to make a variable in the gameplay table that notes how many levels have been completed as an integer. With this, a key for how many levels completed (and, effectively, what level to start at) must exist in the table so that it can be used by any script:

"levels_complete": 0

You may also need to add an exported variable to Level.gd, however, as I am not sure if Worlds Next identifies zones using something like integers. So add the line of code below to Level.gd just in case, which is used for identifying a level by number. If Worlds Next already provides this, use its method instead.

@export var level_num : int = 0

Anywhere in the code for completing a level, such as as soon as a goal post has been spun or when the HUD goal sequence occurs, a check should occur for whether or not the level's level_num is greater than the current levels_complete variable, and only change the variable if such is the case.

# Global is an example autoload script name I used here, change this according to where your data dictionary is stored
if SceneTree.current_scene.level_num > Global.data.gameplay.levels_complete:
	Global.data.gameplay.levels_complete = SceneTree.current_scene.level_num

Afterwards, in your script where it handles choosing stages, you will need to iterate through each level and check if its associated number is at most the current level_num. This does vary depending on how the levels are accessed, however.

[MrCherry09]

Thanks for all the help i'll try to implement all this