build.gradle

plugins {
    id 'java'
    id 'distribution'
    id 'org.springframework.boot' version '3.4.1'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'org.graalvm.buildtools.native' version '0.10.4'
    id 'org.cyclonedx.bom' version '1.10.0'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(23)
    }
}

repositories {
    mavenCentral()
}

ext {
    set('springShellVersion', "3.4.0")
}

dependencies {
    implementation platform("org.springframework.shell:spring-shell-dependencies:${springShellVersion}")

    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.shell:spring-shell-starter'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.shell:spring-shell-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

springBoot {
    buildInfo()
}

graalvmNative {
    binaries {
        main {
            imageName = "arconia"
        }
    }
}

tasks.named('test') {
    useJUnitPlatform()
}

tasks.named('cyclonedxBom') {
    includeConfigs = ["runtimeClasspath"]
    outputFormat = "json"
    projectType = "application"
    schemaVersion = "1.6"
}

distributions {
    main {
        contents {
            from("$buildDir/native/nativeCompile") {
                into 'bin'
                include 'arconia', 'arconia.exe'
            }
            from("$buildDir/reports") {
                include 'application.cdx.json'
                rename { 'sbom.cdx.json' }
            }
            from(rootDir) {
                include 'LICENSE', 'README.md'
            }
        }
    }
}

tasks.named('distZip') {
    def archiveName = gradle.startParameter.projectProperties['archiveName'] ?: "arconia-${project.version}.zip"
    onlyIf {
        gradle.startParameter.taskNames.contains("distZip")
    }
    archiveFileName = "${archiveName}"
}

tasks.named('distTar') {
    enabled = false
}