|
| 1 | +load("//:build/wd_test.bzl", "wd_test") |
| 2 | + |
| 3 | +# The public entry point is a macro named wpt_test. It first invokes a private |
| 4 | +# rule named _wpt_test_gen to access the files in the wpt filegroup and |
| 5 | +# generate a corresponding wd-test file. It then invokes the wd_test macro |
| 6 | +# to set up the test. |
| 7 | + |
| 8 | +def wpt_test(name, wpt_directory, test_js): |
| 9 | + test_gen_rule = "{}@_wpt_test_gen".format(name) |
| 10 | + _wpt_test_gen( |
| 11 | + name = test_gen_rule, |
| 12 | + test_name = name, |
| 13 | + wpt_directory = wpt_directory, |
| 14 | + test_js = test_js, |
| 15 | + ) |
| 16 | + |
| 17 | + wd_test( |
| 18 | + name = "{}".format(name), |
| 19 | + src = test_gen_rule, |
| 20 | + args = ["--experimental"], |
| 21 | + data = [ |
| 22 | + "//src/wpt:wpt-test-harness", |
| 23 | + test_js, |
| 24 | + wpt_directory, |
| 25 | + "//src/workerd/io:trimmed-supported-compatibility-date.txt", |
| 26 | + ], |
| 27 | + ) |
| 28 | + |
| 29 | +def _wpt_test_gen_impl(ctx): |
| 30 | + src = ctx.actions.declare_file("{}.wd-test".format(ctx.attr.test_name)) |
| 31 | + ctx.actions.write( |
| 32 | + output = src, |
| 33 | + content = WPT_TEST_TEMPLATE.format( |
| 34 | + test_name = ctx.attr.test_name, |
| 35 | + test_js = wd_relative_path(ctx.file.test_js), |
| 36 | + modules = generate_external_modules(ctx.attr.wpt_directory.files), |
| 37 | + ), |
| 38 | + ) |
| 39 | + |
| 40 | + return DefaultInfo( |
| 41 | + files = depset([src]), |
| 42 | + ) |
| 43 | + |
| 44 | +WPT_TEST_TEMPLATE = """ |
| 45 | +using Workerd = import "/workerd/workerd.capnp"; |
| 46 | +const unitTests :Workerd.Config = ( |
| 47 | + services = [ |
| 48 | + ( name = "{test_name}", |
| 49 | + worker = ( |
| 50 | + modules = [ |
| 51 | + (name = "worker", esModule = embed "{test_js}"), |
| 52 | + (name = "harness", esModule = embed "../../../../../workerd/src/wpt/harness.js"), |
| 53 | + {modules} |
| 54 | + ], |
| 55 | + bindings = [ |
| 56 | + (name = "wpt", service = "wpt"), |
| 57 | + ], |
| 58 | + compatibilityDate = embed "../../../../../workerd/src/workerd/io/trimmed-supported-compatibility-date.txt", |
| 59 | + compatibilityFlags = ["nodejs_compat_v2", "experimental"], |
| 60 | + ) |
| 61 | + ), |
| 62 | + ( |
| 63 | + name = "wpt", |
| 64 | + disk = ".", |
| 65 | + ) |
| 66 | + ], |
| 67 | +);""" |
| 68 | + |
| 69 | +def wd_relative_path(file): |
| 70 | + """ |
| 71 | + Returns a relative path which can be referenced in the .wd-test file. |
| 72 | + This is four directories up from the bazel short_path |
| 73 | + """ |
| 74 | + return "../" * 4 + file.short_path |
| 75 | + |
| 76 | +def generate_external_modules(files): |
| 77 | + """ |
| 78 | + Generates a string for all files in the given directory in the specified format. |
| 79 | + Example for a JS file: |
| 80 | + (name = "url-origin.any.js", esModule = embed "../../../../../wpt/url/url-origin.any.js"), |
| 81 | + Example for a JSON file: |
| 82 | + (name = "resources/urltestdata.json", json = embed "../../../../../wpt/url/resources/urltestdata.json"), |
| 83 | + """ |
| 84 | + result = [] |
| 85 | + |
| 86 | + for file in files.to_list(): |
| 87 | + file_path = wd_relative_path(file) |
| 88 | + if file.basename.endswith(".js"): |
| 89 | + entry = """(name = "{}", esModule = embed "{}")""".format(file.basename, file_path) |
| 90 | + elif file.basename.endswith(".json"): |
| 91 | + entry = """(name = "{}", json = embed "{}")""".format(file.basename, file_path) |
| 92 | + else: |
| 93 | + # For other file types, you can add more conditions or skip them |
| 94 | + continue |
| 95 | + |
| 96 | + result.append(entry) |
| 97 | + |
| 98 | + return ",\n".join(result) |
| 99 | + |
| 100 | +_wpt_test_gen = rule( |
| 101 | + implementation = _wpt_test_gen_impl, |
| 102 | + attrs = { |
| 103 | + # A string to use as the test name. Used in the wd-test filename and the worker's name |
| 104 | + "test_name": attr.string(), |
| 105 | + # A file group representing a directory of wpt tests. All files in the group will be embedded. |
| 106 | + "wpt_directory": attr.label(), |
| 107 | + # A JS file containing the actual test logic. |
| 108 | + "test_js": attr.label(allow_single_file = True), |
| 109 | + }, |
| 110 | +) |
0 commit comments