build.gradle

repositories {
    jcenter()
}

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.cinnober.gradle:semver-git:2.2.0'
        classpath 'ch.raffael.markdown-doclet:markdown-doclet:1.4'
    }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'com.cinnober.gradle.semver-git'
apply plugin: 'ch.raffael.markdown-doclet'

group = "com.namehillsoftware"
archivesBaseName = "lazy-j"
version = project.version

sourceCompatibility = JavaVersion.VERSION_1_6
targetCompatibility = JavaVersion.VERSION_1_6

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { !version.endsWith("SNAPSHOT") && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

if (!hasProperty("sonatypeUsername")) {
    sonatypeUsername = ""
}

if (!hasProperty("sonatypePassword")) {
    sonatypePassword = ""
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            pom.project {
                name 'lazy-j'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'Embarassingly Simple Lazy Instantiation Library'
                url 'http://www.namehillsoftware.com/'

                scm {
                    connection 'https://github.com/danrien/lazy-j.git'
                    developerConnection 'https://github.com/danrien/lazy-j.git'
                    url 'https://github.com/danrien/lazy-j'
                }

                licenses {
                    license {
//                        name 'GNU Lesser General Public License v3.0'
                        url 'https://www.gnu.org/copyleft/lesser.html'
                    }
                }

                developers {
                    developer {
                        id 'david'
//                        name 'David Vedvick'
                        email 'dvedvick@gmail.com'
                    }
                }
            }
        }
    }
}

uploadArchives.setEnabled(!version.endsWith("SNAPSHOT"))