tests(rds-scheduler): implement stop operation

This commit adds end-to-end testing to validate the
AWS Lambda rds scheduler actually works expected.
They key changes include:
* Created a new test-execution module that:
  * Triggers the aws stop lambda
  * Waits appropriate time intervals before and after function execution
  * Retrieves the rds power states to verify function effectiveness

Author: diodonfrost

examples/rds-scheduler/main.tf

@@ -21,12 +21,12 @@ resource "aws_subnet" "secondary" {
 }
 
 resource "aws_db_subnet_group" "aurora" {
-  name       = "aurora-subnet"
+  name       = "aurora-subnet-${random_pet.suffix.id}"
   subnet_ids = [aws_subnet.primary.id, aws_subnet.secondary.id]
 }
 
 resource "aws_rds_cluster" "aurora_scheduled" {
-  cluster_identifier   = "test-to-stop-${random_pet.suffix.id}"
+  cluster_identifier   = "test-to-stop-aurora-cluster-${random_pet.suffix.id}"
   engine               = "aurora-mysql"
   db_subnet_group_name = aws_db_subnet_group.aurora.id
   database_name        = "aurorawithtag"
@@ -40,7 +40,7 @@ resource "aws_rds_cluster" "aurora_scheduled" {
 }
 
 resource "aws_rds_cluster_instance" "aurora_scheduled" {
-  identifier           = "test-to-stop-instance-${random_pet.suffix.id}"
+  identifier           = "test-to-stop-aurora-instance-${random_pet.suffix.id}"
   engine               = aws_rds_cluster.aurora_scheduled.engine
   engine_version       = aws_rds_cluster.aurora_scheduled.engine_version
   db_subnet_group_name = aws_db_subnet_group.aurora.id
@@ -52,9 +52,8 @@ resource "aws_rds_cluster_instance" "aurora_scheduled" {
   }
 }
 
-# Create rds mariadb instance with tag
 resource "aws_db_instance" "mariadb_scheduled" {
-  identifier           = "test-to-stop-${random_pet.suffix.id}"
+  identifier           = "test-to-stop-mariadb-instance-${random_pet.suffix.id}"
   db_name              = "mariadbwithtag"
   db_subnet_group_name = aws_db_subnet_group.aurora.id
   allocated_storage    = 10
@@ -71,9 +70,8 @@ resource "aws_db_instance" "mariadb_scheduled" {
   }
 }
 
-# Create rds mysql instance with tag
 resource "aws_db_instance" "mysql_not_scheduled" {
-  identifier           = "test-not-to-stop-${random_pet.suffix.id}"
+  identifier           = "test-not-to-stop-mysql-instance-${random_pet.suffix.id}"
   db_name              = "mysqlwithouttag"
   db_subnet_group_name = aws_db_subnet_group.aurora.id
   allocated_storage    = 10
@@ -124,3 +122,17 @@ module "rds-start-monday" {
     value = "true"
   }
 }
+
+module "test-execution" {
+  count  = var.test_mode ? 1 : 0
+  source = "./test-execution"
+
+  lambda_stop_name                         = module.rds-stop-friday.scheduler_lambda_name
+  rds_aurora_cluster_to_scheduled_name     = aws_rds_cluster.aurora_scheduled.cluster_identifier
+  rds_mariadb_instance_to_scheduled_name   = aws_db_instance.mariadb_scheduled.identifier
+  rds_mysql_instance_to_not_scheduled_name = aws_db_instance.mysql_not_scheduled.identifier
+
+  depends_on = [
+    aws_rds_cluster_instance.aurora_scheduled
+  ]
+}

examples/rds-scheduler/outputs.tf

@@ -15,3 +15,11 @@ output "lambda_start_name" {
 output "lambda_start_arn" {
   value = module.rds-start-monday.scheduler_lambda_arn
 }
+
+output "rds_aurora_cluster_name" {
+  value = aws_rds_cluster.aurora_scheduled.cluster_identifier
+}
+
+output "rds_aurora_instance_name" {
+  value = aws_rds_cluster_instance.aurora_scheduled.identifier
+}

examples/rds-scheduler/terraform.tftest.hcl

@@ -1,6 +1,10 @@
 run "create_test_infrastructure" {
   command = apply
 
+  variables {
+    test_mode = true
+  }
+
   assert {
     condition     = module.rds-stop-friday.scheduler_lambda_name == "stop-rds-${random_pet.suffix.id}"
     error_message = "Invalid Stop lambda name"
@@ -10,4 +14,34 @@ run "create_test_infrastructure" {
     condition     = module.rds-start-monday.scheduler_lambda_name == "start-rds-${random_pet.suffix.id}"
     error_message = "Invalid Start lambda name"
   }
+
+  assert {
+    condition     = module.test-execution[0].rds_aurora_cluster_to_scheduled == "stopping\n"
+    error_message = "Invalid RDS cluster instance state"
+  }
+
+  assert {
+    condition     = module.test-execution[0].rds_mariadb_instance_to_scheduled == "stopping\n"
+    error_message = "Invalid RDS instance state"
+  }
+
+  assert {
+    condition     = module.test-execution[0].rds_mysql_instance_to_not_scheduled == "available\n"
+    error_message = "Invalid RDS instance state"
+  }
+}
+
+# Add this cleanup step to restore the cluster to 'available' state before destruction
+run "cleanup_test_resources" {
+  command = apply
+
+  variables {
+    rds_aurora_cluster_name  = run.create_test_infrastructure.rds_aurora_cluster_name
+    rds_aurora_instance_name = run.create_test_infrastructure.rds_aurora_instance_name
+  }
+
+  # This will start the stopped cluster to ensure proper deletion
+  module {
+    source = "./test-cleanup"
+  }
 }

examples/rds-scheduler/test-cleanup/main.tf

@@ -0,0 +1,72 @@
+resource "null_resource" "start_rds_aurora_cluster" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      TIMEOUT=600
+      START_TIME=$(date +%s)
+      
+      echo "Waiting for rds aurora cluster ${var.rds_aurora_cluster_name} to reach 'stopped' state (timeout: $TIMEOUT seconds)..."
+      
+      while true; do
+        # Check the current state of the rds aurora cluster
+        CURRENT_STATE=$(aws rds describe-db-clusters --db-cluster-identifier ${var.rds_aurora_cluster_name} --query 'DBClusters[0].Status' --output text)
+        
+        # Get current elapsed time
+        CURRENT_TIME=$(date +%s)
+        ELAPSED=$((CURRENT_TIME - START_TIME))
+        
+        # Check if cluster is stopped
+        if [ "$CURRENT_STATE" = "stopped" ]; then
+          aws rds start-db-cluster --db-cluster-identifier ${var.rds_aurora_cluster_name}
+          exit 0
+        fi
+        
+        # Check if we've exceeded the timeout
+        if [ $ELAPSED -ge $TIMEOUT ]; then
+          echo "Timeout reached. rds aurora cluster did not reach 'stopped' state within $TIMEOUT seconds."
+          exit 1
+        fi
+        
+        # Wait 10 seconds before checking again
+        echo "Current state: $CURRENT_STATE (elapsed: $ELAPSED seconds/ $TIMEOUT seconds)..."
+        sleep 10
+      done
+    EOT
+  }
+}
+
+resource "null_resource" "waiting_for_rds_aurora_cluster_to_start" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      TIMEOUT=600
+      START_TIME=$(date +%s)
+      
+      echo "Waiting for rds aurora cluster ${var.rds_aurora_cluster_name} to reach 'available' state (timeout: $TIMEOUT seconds)..."
+      
+      while true; do
+        # Check the current state of the rds aurora cluster
+        CURRENT_STATE=$(aws rds describe-db-clusters --db-cluster-identifier ${var.rds_aurora_cluster_name} --query 'DBClusters[0].Status' --output text)
+        
+        # Get current elapsed time
+        CURRENT_TIME=$(date +%s)
+        ELAPSED=$((CURRENT_TIME - START_TIME))
+        
+        # Check if cluster is available
+        if [ "$CURRENT_STATE" = "available" ]; then
+          exit 0
+        fi
+        
+        # Check if we've exceeded the timeout
+        if [ $ELAPSED -ge $TIMEOUT ]; then
+          echo "Timeout reached. rds aurora cluster did not reach 'available' state within $TIMEOUT seconds."
+          exit 1
+        fi
+        
+        # Wait 10 seconds before checking again
+        echo "Current state: $CURRENT_STATE (elapsed: $ELAPSED seconds/ $TIMEOUT seconds)..."
+        sleep 10
+      done
+    EOT
+  }
+
+  depends_on = [null_resource.start_rds_aurora_cluster]
+}

examples/rds-scheduler/test-cleanup/variables.tf

@@ -0,0 +1,9 @@
+variable "rds_aurora_cluster_name" {
+  description = "Name of the rds aurora cluster to start before deletion"
+  type        = string
+}
+
+variable "rds_aurora_instance_name" {
+  description = "Name of the rds aurora instance to start before deletion"
+  type        = string
+}

examples/rds-scheduler/test-execution/main.tf

@@ -0,0 +1,77 @@
+resource "time_sleep" "before_stop_wait_60_seconds" {
+  create_duration = "60s"
+}
+
+resource "aws_lambda_invocation" "this" {
+  function_name = var.lambda_stop_name
+
+  input = jsonencode({
+    key1 = "value1"
+    key2 = "value2"
+  })
+
+  depends_on = [time_sleep.before_stop_wait_60_seconds]
+}
+
+resource "time_sleep" "after_stop_wait_60_seconds" {
+  create_duration = "60s"
+
+  depends_on = [aws_lambda_invocation.this]
+}
+
+resource "null_resource" "rds_aurora_cluster_to_scheduled" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      aws rds describe-db-clusters \
+        --db-cluster-identifier ${var.rds_aurora_cluster_to_scheduled_name} \
+        --query 'DBClusters[0].Status' \
+        --output text > ${path.module}/rds_aurora_cluster_to_scheduled.state
+    EOT
+  }
+
+  depends_on = [time_sleep.after_stop_wait_60_seconds]
+}
+
+data "local_file" "rds_aurora_cluster_to_scheduled" {
+  filename = "${path.module}/rds_aurora_cluster_to_scheduled.state"
+
+  depends_on = [null_resource.rds_aurora_cluster_to_scheduled]
+}
+
+resource "null_resource" "rds_mariadb_instance_to_scheduled" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      aws rds describe-db-instances \
+        --db-instance-identifier ${var.rds_mariadb_instance_to_scheduled_name} \
+        --query 'DBInstances[0].DBInstanceStatus' \
+        --output text > ${path.module}/rds_mariadb_instance_to_scheduled.state
+    EOT
+  }
+
+  depends_on = [time_sleep.after_stop_wait_60_seconds]
+}
+
+data "local_file" "rds_mariadb_instance_to_scheduled" {
+  filename = "${path.module}/rds_mariadb_instance_to_scheduled.state"
+
+  depends_on = [null_resource.rds_mariadb_instance_to_scheduled]
+}
+
+resource "null_resource" "rds_mysql_instance_to_not_scheduled" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      aws rds describe-db-instances \
+        --db-instance-identifier ${var.rds_mysql_instance_to_not_scheduled_name} \
+        --query 'DBInstances[0].DBInstanceStatus' \
+        --output text > ${path.module}/rds_mysql_instance_to_not_scheduled.state
+    EOT
+  }
+
+  depends_on = [time_sleep.after_stop_wait_60_seconds]
+}
+
+data "local_file" "rds_mysql_instance_to_not_scheduled" {
+  filename = "${path.module}/rds_mysql_instance_to_not_scheduled.state"
+
+  depends_on = [null_resource.rds_mysql_instance_to_not_scheduled]
+}

examples/rds-scheduler/test-execution/outputs.tf

@@ -0,0 +1,14 @@
+output "rds_aurora_cluster_to_scheduled" {
+  description = "The status of the RDS cluster"
+  value       = data.local_file.rds_aurora_cluster_to_scheduled.content
+}
+
+output "rds_mariadb_instance_to_scheduled" {
+  description = "The status of the RDS instance"
+  value       = data.local_file.rds_mariadb_instance_to_scheduled.content
+}
+
+output "rds_mysql_instance_to_not_scheduled" {
+  description = "The status of the RDS instance"
+  value       = data.local_file.rds_mysql_instance_to_not_scheduled.content
+}

examples/rds-scheduler/test-execution/variables.tf

@@ -0,0 +1,19 @@
+variable "lambda_stop_name" {
+  description = "Name of the Lambda function used for stopping instances"
+  type        = string
+}
+
+variable "rds_aurora_cluster_to_scheduled_name" {
+  description = "rds cluster name to be scheduled"
+  type        = string
+}
+
+variable "rds_mariadb_instance_to_scheduled_name" {
+  description = "rds instance name to be scheduled"
+  type        = string
+}
+
+variable "rds_mysql_instance_to_not_scheduled_name" {
+  description = "rds instance name to not be scheduled"
+  type        = string
+}

examples/rds-scheduler/test-execution/versions.tf

@@ -0,0 +1,21 @@
+terraform {
+  required_version = ">= 1.3.0"
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 5.94.1"
+    }
+    null = {
+      source  = "hashicorp/null"
+      version = ">= 3.0.0, < 4.0"
+    }
+    local = {
+      source  = "hashicorp/local"
+      version = ">= 2.0.0, < 3.0"
+    }
+    time = {
+      source  = "hashicorp/time"
+      version = "0.13.0"
+    }
+  }
+}

examples/rds-scheduler/variables.tf

@@ -0,0 +1,5 @@
+variable "test_mode" {
+  description = "Whether to run in test mode"
+  type        = bool
+  default     = false
+}