fix package generation (#775)

* fix package generation

* rename package to zenohc;
prefix add lib prefix to deb packages;

* fix package version

* fix version for X.Y.Z.1

Author: DenisBiryukov91

CMakeLists.txt

@@ -43,7 +43,7 @@ if(NOT DEFINED PROJECT_VERSION_TWEAK)
 	set(project_version "${project_version}")
 elseif(PROJECT_VERSION_TWEAK EQUAL 0)
 	set(project_version "${project_version}-dev")
-elseif(PROJECT_VERSION_TWEAK GREATER 1)
+elseif(PROJECT_VERSION_TWEAK GREATER 0)
 	set(project_version "${project_version}-pre.${PROJECT_VERSION_TWEAK}")
 endif()
 status_print(project_version)

install/CMakeLists.txt

@@ -22,9 +22,9 @@ function(install_zenohc_lib configurations property_postfix package_name)
         else()
             set(ZENOHC_INSTALL_DYLIBDIR ${CMAKE_INSTALL_LIBDIR})
         endif()
-        install(FILES ${dylib_path} DESTINATION ${ZENOHC_INSTALL_DYLIBDIR} CONFIGURATIONS ${configurations})
+        install(FILES ${dylib_path} DESTINATION ${ZENOHC_INSTALL_DYLIBDIR} CONFIGURATIONS ${configurations} COMPONENT lib)
         if(DEFINED implib_path)
-            install(FILES ${implib_path} DESTINATION ${CMAKE_INSTALL_LIBDIR} CONFIGURATIONS ${configurations})
+            install(FILES ${implib_path} DESTINATION ${CMAKE_INSTALL_LIBDIR} CONFIGURATIONS ${configurations} COMPONENT lib)
         endif()
         if((APPLE OR UNIX))
             get_filename_component(LIBNAME ${DYLIB} NAME_WE)
@@ -33,13 +33,14 @@ function(install_zenohc_lib configurations property_postfix package_name)
                 DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig" 
                 CONFIGURATIONS ${configurations}
                 RENAME ${package_name}.pc
-                OPTIONAL)
+                OPTIONAL
+                COMPONENT dev)
         endif()
     else()
         get_target_property(staticlib_path zenohc::static IMPORTED_LOCATION_${property_postfix})
         get_target_property(NATIVE_STATIC_LIBS zenohc::static INTERFACE_LINK_LIBRARIES)
         get_filename_component(STATICLIB ${staticlib_path} NAME)
-        install(FILES ${staticlib_path} DESTINATION ${CMAKE_INSTALL_LIBDIR} CONFIGURATIONS ${configurations})
+        install(FILES ${staticlib_path} DESTINATION ${CMAKE_INSTALL_LIBDIR} CONFIGURATIONS ${configurations} COMPONENT lib)
     endif()
 
     set(CMAKE_INSTALL_CMAKEDIR "${CMAKE_INSTALL_LIBDIR}/cmake/${package_name}")
@@ -79,11 +80,50 @@ endfunction()
 #
 get_target_property(include_dirs zenohc::lib INTERFACE_INCLUDE_DIRECTORIES)
 foreach(dir ${include_dirs})
-    install(DIRECTORY "${dir}/" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+    install(DIRECTORY "${dir}/" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} COMPONENT headers)
 endforeach()
 
 #
 # Install lib files 
 #
 install_zenohc_lib("Release;RelWithDebInfo;MinSizeRel;None" "RELEASE" zenohc)
 install_zenohc_lib("Debug" "DEBUG" zenohc)
+
+#
+# Configure CPack
+#
+set(CPACK_PACKAGE_DIRECTORY "${CMAKE_BINARY_DIR}/packages")
+set(CPACK_PACKAGE_CHECKSUM MD5)
+set(CPACK_PACKAGE_VENDOR "The Eclipse Foundation")
+set(CPACK_PACKAGE_VERSION_MAJOR ${PROJECT_VERSION_MAJOR})
+set(CPACK_PACKAGE_VERSION_MINOR ${PROJECT_VERSION_MINOR})
+set(CPACK_PACKAGE_VERSION_PATCH ${PROJECT_VERSION_PATCH})
+set(CPACK_COMPONENT_LIB_DESCRIPTION "The C client library for Eclipse zenoh")
+set(CPACK_COMPONENT_DEV_DESCRIPTION "${CPACK_COMPONENT_LIB_DESCRIPTION} - cmake files")
+set(CPACK_COMPONENT_HEADERS_DESCRIPTION "${CPACK_COMPONENT_LIB_DESCRIPTION} - header files")
+set(CPACK_COMPONENT_LIB_GROUP "lib")
+set(CPACK_COMPONENT_HEADERS_GROUP "dev")
+set(CPACK_COMPONENT_DEV_GROUP "dev")
+set(CPACK_COMPONENT_HEADERS_DEPENDS lib)
+set(CPACK_COMPONENT_DEV_DEPENDS lib)
+
+set(CPACK_GENERATOR ZIP)
+# set package name to format <name>-<version>.<extension>
+# platform name doesn't matter for header-only library
+set(CPACK_PACKAGE_NAME zenohc)
+
+if(NOT CPACK_PACKAGE_VERSION)
+    set(SEM_VER "${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}")
+    if(NOT DEFINED PROJECT_VERSION_TWEAK)
+        set(CPACK_PACKAGE_VERSION ${SEM_VER})
+    elseif(PROJECT_VERSION_TWEAK EQUAL 0)
+        set(CPACK_PACKAGE_VERSION "${SEM_VER}~dev-1")
+    elseif(PROJECT_VERSION_TWEAK GREATER 0)
+        set(CPACK_PACKAGE_VERSION "${SEM_VER}~pre.${PROJECT_VERSION_TWEAK}-1")
+    endif()
+endif()
+
+set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
+set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_CURRENT_SOURCE_DIR}/cpack_project_config.cmake")
+
+include(CPack)

install/cpack_project_config.cmake

@@ -0,0 +1,34 @@
+if(CPACK_GENERATOR MATCHES "DEB")
+    # DEB package
+    if(NOT DEBARCH)
+        execute_process(
+        COMMAND dpkg --print-architecture
+        OUTPUT_VARIABLE DEBARCH
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+        )
+    endif()
+    message(STATUS "Configure DEB packaging for Linux ${DEBARCH}")
+    set(CPACK_DEBIAN_PACKAGE_MAINTAINER "ZettaScale Zenoh Team, <[email protected]>")
+    set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE ${DEBARCH})
+    set(CPACK_DEB_COMPONENT_INSTALL ON)
+    set(CPACK_DEBIAN_FILE_NAME DEB-DEFAULT)
+    set(CPACK_DEBIAN_LIB_PACKAGE_NAME lib${CPACK_PACKAGE_NAME})
+    set(CPACK_DEBIAN_LIB_PACKAGE_DEPENDS "libc6 (>=2.12)")
+    set(CPACK_DEBIAN_DEV_PACKAGE_NAME lib${CPACK_PACKAGE_NAME}-dev)
+    set(CPACK_DEBIAN_DEV_PACKAGE_DEPENDS "${CPACK_DEBIAN_LIB_PACKAGE_NAME} (=${CPACK_PACKAGE_VERSION})")
+endif()
+
+if(CPACK_GENERATOR MATCHES "RPM")
+  # RPM package
+  # rpmbuild should be installed
+  # apt install rpm
+  if(NOT RPMARCH)
+    set(RPMARCH ${CMAKE_SYSTEM_PROCESSOR})
+  endif()
+  message(STATUS "Configure RPM packaging for Linux ${RPMARCH}")
+  set(CPACK_RPM_PACKAGE_ARCHITECTURE ${RPMARCH})
+  set(CPACK_RPM_COMPONENT_INSTALL ON)
+  set(CPACK_RPM_FILE_NAME RPM-DEFAULT)
+  set(CPACK_RPM_LIB_PACKAGE_NAME ${CPACK_PACKAGE_NAME}) # avoid "-lib" suffix for "lib" package
+  set(CPACK_RPM_DEV_PACKAGE_REQUIRES "${CPACK_RPM_LIB_PACKAGE_NAME} = ${CPACK_PACKAGE_VERSION}")
+endif()