Raise on unknown column opts (#752)

Author: itamm15

lib/ecto/migration.ex

@@ -1176,6 +1176,24 @@ defmodule Ecto.Migration do
     Runner.prefix()
   end
 
+  @add_remove_column_opts [
+    :primary_key,
+    :default,
+    :null,
+    :size,
+    :precision,
+    :scale,
+    :comment,
+    :collation,
+    :after,
+    :generated,
+    :start_value,
+    :increment,
+    :fields
+  ]
+
+  @modify_column_opts [:from | @add_remove_column_opts]
+
   @doc """
   Adds a column when creating or altering a table.
 
@@ -1250,6 +1268,7 @@ defmodule Ecto.Migration do
 
   """
   def add(column, type, opts \\ []) when is_atom(column) and is_list(opts) do
+    validate_column_opts!(opts, @add_remove_column_opts, "add/3")
     validate_precision_opts!(opts, column)
     validate_type!(type)
     Runner.subcommand({:add, column, type, opts})
@@ -1272,6 +1291,7 @@ defmodule Ecto.Migration do
 
   """
   def add_if_not_exists(column, type, opts \\ []) when is_atom(column) and is_list(opts) do
+    validate_column_opts!(opts, @add_remove_column_opts, "add_if_not_exists/3")
     validate_precision_opts!(opts, column)
     validate_type!(type)
     Runner.subcommand({:add_if_not_exists, column, type, opts})
@@ -1433,6 +1453,7 @@ defmodule Ecto.Migration do
     * `:collation` - the collation of the text type.
   """
   def modify(column, type, opts \\ []) when is_atom(column) and is_list(opts) do
+    validate_column_opts!(opts, @modify_column_opts, "modify/3")
     validate_precision_opts!(opts, column)
     validate_type!(type)
     Runner.subcommand({:modify, column, type, opts})
@@ -1471,6 +1492,7 @@ defmodule Ecto.Migration do
 
   """
   def remove(column, type, opts \\ []) when is_atom(column) do
+    validate_column_opts!(opts, @add_remove_column_opts, "remove/3")
     validate_type!(type)
     Runner.subcommand({:remove, column, type, opts})
   end
@@ -1747,6 +1769,16 @@ defmodule Ecto.Migration do
     end
   end
 
+  defp validate_column_opts!(opts, allowed, fun) when is_list(opts) do
+    case Enum.find(opts, fn {key, _} -> key not in allowed end) do
+      {key, _} ->
+        raise ArgumentError, "unknown option #{inspect(key)} given to #{fun}"
+
+      nil ->
+        :ok
+    end
+  end
+
   defp validate_precision_opts!(opts, column) when is_list(opts) do
     if opts[:scale] && !opts[:precision] do
       raise ArgumentError, "column #{Atom.to_string(column)} is missing precision option"

test/ecto/migration_test.exs

@@ -228,6 +228,24 @@ defmodule Ecto.MigrationTest do
     end
   end
 
+  test "raises on unknown column options" do
+    assert_raise ArgumentError, "unknown option :required given to add/3", fn ->
+      add(:hello, :string, required: true)
+    end
+
+    assert_raise ArgumentError, "unknown option :required given to add_if_not_exists/3", fn ->
+      add_if_not_exists(:hello, :string, required: true)
+    end
+
+    assert_raise ArgumentError, "unknown option :required given to modify/3", fn ->
+      modify(:hello, :string, required: true)
+    end
+
+    assert_raise ArgumentError, "unknown option :required given to remove/3", fn ->
+      remove(:hello, :string, required: true)
+    end
+  end
+
   test "flush clears out commands", %{runner: runner} do
     execute "TEST"
     commands = Agent.get(runner, & &1.commands)