Create generate and watch scripts for 2021 in Raku

`./generate.raku dayX` creates a dayX directory, dayX.raku program, and
a DayX class with template solve methods.  It also creates empty
input.example.txt and input.actual.txt files for AoC input.
`./watch dayX` runs the dayX program on the input files when started
and whenever the program or its inputs are changed.  Watch saves stdout
and stderr to a file in the out/ directory so it's easy to see what
debug output changed between two runs.

Author: flwyd

2021/.gitignore

@@ -0,0 +1 @@
+out/

2021/generate.raku

@@ -0,0 +1,64 @@
+#!/usr/bin/env raku
+# Copyright 2021 Google LLC
+#
+# Use of this source code is governed by an MIT-style
+# license that can be found in the LICENSE file or at
+# https://opensource.org/licenses/MIT.
+
+# Generator script for a day's Advent of Code files.  Usage:
+# ./generate day1
+
+sub MAIN(Str:D $day-dir-name) {
+  my $day-dir = $day-dir-name.IO;
+  my $class-name = $day-dir.basename.tc;
+  my $day-num = $class-name.match(/\d+$/).Str;
+  my $script = $day-dir.add($day-dir.basename ~ '.raku');
+  $day-dir.mkdir;
+  for <input.example.txt input.actual.txt>.map({ $day-dir.add($_) }) {
+    $_.spurt('') unless $_.f;
+  }
+  $script.spurt(qq:to/END/) unless $script.f;
+    #!/usr/bin/env raku
+    # Copyright 2021 Google LLC
+    #
+    # Use of this source code is governed by an MIT-style
+    # license that can be found in the LICENSE file or at
+    # https://opensource.org/licenses/MIT.
+    #
+    # https://adventofcode.com/2021/day/$day-num
+
+    class $class-name \{
+      has \$.input;
+
+      method solve-part1(--> Cool:D) \{
+        return "TODO";
+      }
+
+      method solve-part2(--> Cool:D) \{
+        return "TODO";
+      }
+    }
+
+    sub MAIN(*@input-files) \{
+      for @input-files -> \$input-file \{
+        if (my \$input = \$input-file.IO.slurp) \{
+          say "Running $class-name part 1 on \$input-file";
+          my \$start1 = now;
+          my \$solver = {$class-name}.new(:input(\$input));
+          say \$solver.solve-part1();
+          "Part 1 took %.3fms\\n".printf((now - \$start1)*1000);
+          say '';
+          say "Running $class-name part 2 on \$input-file";
+          my \$start2 = now;
+          \$solver = {$class-name}.new(:input(\$input));
+          say \$solver.solve-part2();
+          "Part 2 took %.3fms\\n".printf((now - \$start2)*1000);
+        } else \{
+          say "EMPTY INPUT FILE: \$input-file";
+        }
+        say '=' x 40;
+      }
+    }
+    END
+  $script.chmod(0o755);
+}

2021/watch

@@ -0,0 +1,34 @@
+#!/bin/zsh
+# Copyright 2021 Google LLC
+#
+# Use of this source code is governed by an MIT-style
+# license that can be found in the LICENSE file or at
+# https://opensource.org/licenses/MIT.
+
+# Watch an AoC directory; rerun the solver when program or input files change.
+# Uses https://github.com/emcrisostomo/fswatch
+
+if [ $# -eq 0 ]; then
+  echo "Usage: watch day1"
+  exit 1
+fi
+DIR=$1
+PROGRAM="${DIR:a:t}.raku"
+DATEFMT='%Y%m%d-%H%M%S'
+cd $DIR
+mkdir -p out
+
+function runscript {
+  outfile="out/$(date +$DATEFMT).log"
+  cmd=(raku "$PROGRAM" input.example* input.actual.txt)
+  echo "$cmd > $outfile"
+  echo
+  $cmd 2>&1 | tee "$outfile"
+  echo
+}
+
+runscript
+
+fswatch -0 -o *.raku input.* | while read -d "" event ; do
+  runscript
+done