build.gradle

plugins {
  id 'pl.allegro.tech.build.axion-release' version '1.17.2'
  id 'org.springframework.boot' version '3.3.0'
  id "org.sonarqube" version "5.0.0.4638"
  id 'com.google.cloud.tools.jib' version '3.4.3'
}

//apply plugin: 'java-library'
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'jacoco'
apply plugin: 'org.sonarqube'

scmVersion {
  tag {
    prefix = ''
  }
}

group = 'de.gessnerfl.rabbitmq'
description = """RabbitMQ :: Queue Management :: List/Move/Delete dead messages from queues"""
project.version = scmVersion.version

ext.scmUrl = 'git@github.com:gessnerfl/rabbitmq-queue-management.git'
ext.projectUrl = 'https://github.com/gessnerfl/rabbitmq-queue-management'

sourceCompatibility = 17
targetCompatibility = 17

repositories { mavenCentral() }

dependencies {
  implementation 'org.springframework.boot:spring-boot-starter-actuator'
  implementation 'org.springframework.boot:spring-boot-starter-web'
  implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
  implementation 'org.springframework.boot:spring-boot-devtools'
  implementation('org.springframework.boot:spring-boot-starter-validation')

  implementation 'io.github.openfeign:feign-core:13.2.1'
  implementation 'io.github.openfeign:feign-gson:13.2.1'
  implementation 'io.github.openfeign:feign-slf4j:13.2.1'

  implementation 'com.google.code.gson:gson:2.11.0'
  implementation 'commons-codec:commons-codec:1.17.0'

  implementation 'org.webjars.bowergithub.caldwell:renderjson:1.4.0'
  implementation 'org.webjars.bower:bootstrap:5.3.3'
  implementation 'org.webjars.bower:open-iconic:1.1.1'

  implementation 'com.rabbitmq:amqp-client:5.21.0'

  testImplementation 'org.springframework.boot:spring-boot-starter-test'
  testImplementation 'org.hamcrest:hamcrest:2.2'
  testImplementation 'org.awaitility:awaitility:4.2.1'
  testImplementation 'org.testcontainers:testcontainers:1.19.8'
  testImplementation 'org.testcontainers:junit-jupiter:1.19.8'
  testImplementation 'org.apache.commons:commons-lang3:3.14.0'
}

java {
  withSourcesJar()
}

bootJar {
    manifest {
        attributes 'Main-Class': 'org.springframework.boot.loader.launch.PropertiesLauncher'
    }
}

test {
  finalizedBy jacocoTestReport
  useJUnitPlatform()
}

jacocoTestReport {
  dependsOn test
  reports {
    xml.required = true
    csv.required = false
    html.required = true
  }
}

sonar {
  properties {
    property 'sonar.host.url', 'https://sonarcloud.io'
    property 'sonar.organization', 'gessnerfl-github'
    property "sonar.projectName", "RabbitMQ Queue Management"
    property "sonar.projectKey", "de.gessnerfl.rabbitmq-queue-management"
  }
}

jib{
  from {
    image = 'amazoncorretto:17.0.11-al2023-headless'
    container {
      ports = ["8780", "8781"]
      creationTime='USE_CURRENT_TIMESTAMP'
      jvmFlags = ['-Djava.security.egd=file:/dev/./urandom','-Dfile.encoding=utf-8']
    }
    platforms {
      platform {
        architecture = 'amd64'
        os = 'linux'
      }
      platform {
        architecture = 'arm64'
        os = 'linux'
      }
    }
  }
  to {
    image = 'gessnerfl/rabbitmq-queue-management'
    tags = [scmVersion.version, 'latest']
    auth {
      username = DOCKERHUB_USERNAME
      password = DOCKERHUB_TOKEN
    }
  }
}