publish-maven.gradle

//Version 3.0.1
if (project.hasProperty('publicationGradleFileUrl')) {
    apply from: publicationGradleFileUrl
} else {
    apply from: "$rootDir/publish-aar.gradle"
}

apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'de.marcphilipp.nexus-publish'

nexusStaging {
    // this package group has to be this one so that all yoti publication there are under the same group
    packageGroup = "com.yoti"

    username = sonatypeUsername
    password = sonatypePassword

    delayBetweenRetriesInMillis = 15000
}

import java.time.Duration

nexusPublishing {
    repositories {
        sonatype()
    }
    connectTimeout = Duration.ofMinutes(5)
    clientTimeout = Duration.ofMinutes(10)
}

project.afterEvaluate {
    signing {
        def performSigning = !(project.hasProperty('disableSigning') ?
                Boolean.valueOf(disableSigning) : false)

        if (performSigning) {
            required true

            if (project.hasProperty("inMemorySigningKey")) {
                useInMemoryPgpKeys(inMemorySigningKey, inMemoryKeyPassword)
            }

            for (pub in publishing.publications) {
                sign pub
            }
        }
    }
}