MODULE.bazel

# Copyright 2026 The OpenGrm Authors.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

# Module file for Bazel build system for OpenGrm.
#
# See https://registry.bazel.build/ for central Bazel package registry.

module(
    name = "opengrm",
    bazel_compatibility = [">=8.0.0"],
)

# Bazel core modules providing rules.
bazel_dep(
    name = "bazel_skylib",
    version = "1.9.0",
)
# NOTE: GCC toolchains are broken with Bazel 9.
# TODO: Update to 0.9.0.bcr.1 when
# https://github.com/bazelbuild/bazel-central-registry/pull/7391
# is merged.
bazel_dep(
    name = "gcc_toolchain",
    version = "0.9.0",
)
bazel_dep(
    name = "rules_cc",
    version = "0.2.22",
)
bazel_dep(
    name = "rules_python",
    version = "2.2.0",
)
bazel_dep(
    name = "rules_bison",
    version = "0.4.bcr.1"
)
bazel_dep(
    name = "rules_m4",
    version = "0.3.bcr.1"
)
bazel_dep(
    name = "rules_shell",
    version = "0.8.0",
)
bazel_dep(
    name = "platforms",
    version = "1.1.0",
)
bazel_dep(
    name = "rules_license",
    version = "1.0.0",
)
bazel_dep(
    name = "toolchains_llvm",
    version = "1.6.0",
)
bazel_dep(
    name = "cython",
    version = "3.2.8",
)

# Module extensions.
# GCC
gcc = use_extension("@gcc_toolchain//toolchain:module_extensions.bzl", "gcc_toolchains")

# We would like to support 7.5.0, but the lowest version available via
# bzlmod is 12.5.0.
# https://github.com/google/oss-policies-info/blob/main/foundational-cxx-support-matrix.md#compilers-tools-build-systems
gcc.toolchain(
    name = "gcc_toolchain_old",
    gcc_version = "12.5.0",
    target_arch = "x86_64",
    extra_ldflags = ["-lstdc++"],
)
use_repo(gcc, "gcc_toolchain_old")

# Current version.
# https://gcc.gnu.org/releases.html
gcc.toolchain(
    name = "gcc_toolchain_cur",
    gcc_version = "15.2.0",
    target_arch = "x86_64",
    extra_ldflags = ["-lstdc++"],
)
use_repo(gcc, "gcc_toolchain_cur")

# LLVM
llvm = use_extension("@toolchains_llvm//toolchain/extensions:llvm.bzl", "llvm")

# Lowest supported clang version.
llvm.toolchain(
    name = "llvm_toolchain_old",
    llvm_version = "14.0.0",
)
use_repo(llvm, "llvm_toolchain_old")

# Latest downloadable release.
# https://releases.llvm.org/
llvm.toolchain(
    name = "llvm_toolchain_cur",
    llvm_version = "20.1.0",
)
use_repo(llvm, "llvm_toolchain_cur")
# Note we're not using `register_toolchain()`; `--extra_toolchains` is
# configured in `.bazelrc`.

# Prod dependencies.
bazel_dep(
    name = "abseil-cpp",
    version = "20260526.0",
    repo_name = "com_google_absl",
)
bazel_dep(  # For Thrax `rewrite-tester`.
    name = "readline",
    version = "8.3.bcr.1"
)
bazel_dep(
    name = "abseil-py",
    version = "2.4.0",
    repo_name = "com_google_absl_py",
)
bazel_dep(
    name = "protobuf",
    version = "35.1",
    repo_name = "com_google_protobuf"
)

# Some modules are not yet available in the bazel central registry. We define
# a dummy module and then use `git_override` to point it at the specific commit
# in the respective github repo.
OPENFST_COMMIT = "a676239535d308e7351d130ced3fdf6c2faec497"  # 07/08/26.
bazel_dep(name = "openfst", version = "0.0.0", repo_name = "com_google_openfst")
git_override(
    module_name = "openfst",
    remote = "https://github.com/google-research/openfst.git",
    commit = OPENFST_COMMIT,
)

# Dev dependencies.
bazel_dep(
    name = "googletest",
    version = "1.17.0.bcr.2",
    dev_dependency = True,
    repo_name = "com_google_googletest",
)