build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
  id "org.ajoberstar.grgit" version '4.0.2'
}

apply plugin: "base"
apply plugin: 'java'
apply plugin: 'java-library'

defaultTasks "clean", "createPluginZip"

sourceCompatibility = 1.8
targetCompatibility = 1.8

def gitVersion = "none"
try {
	gitVersion = "v${grgit.head().abbreviatedId}"
} catch(Exception e) {
	// Ignore it
}

def getDate() {
    def date = new Date()
    def formattedDate = date.format('yyyy.MMdd.HHmmss')
    return formattedDate
}

repositories {
    mavenCentral()
}

sourceSets {
    main {
        java {
            srcDirs = ['src']
        }
        resources {
            srcDirs = ['src']
        }
    }
}

def spLibs = fileTree(dir: 'lib')
spLibs.include "identityiq*.jar"
spLibs.include "connector*.jar"

dependencies {
    implementation spLibs
	implementation group: 'commons-logging', name: 'commons-logging', version: '1.1.3'
    implementation group: 'javax.servlet', name: 'javax.servlet-api', version: '4.0.1'
    implementation(group: 'org.glassfish.jersey.bundles', name: 'jaxrs-ri', version: '2.22.2') {
        transitive = false
    }
}

task createPluginZip(type: Zip) {	
	archiveName = archivesBaseName + ".${gitVersion}.zip"
	
    into('jars') {
        from jar
    }
    into('import/install') {
    	from("config") {
    		include "**"
    		exclude "*Example*"
    	}
    }
    into('import/upgrade') {
        from("config") {
            include "AuditConfig.xml"
            include "ServiceDefinition-*"
        }
    }
    from('.') {
        include 'manifest.xml'
        include 'db/**'        
		filter { it.replace("%%BUILD_VERSION%%", getDate() + "." + gitVersion) }
    }
}

createPluginZip {
	dependsOn 'jar'
}