updated insert routine to account for list of elements being inserted.

Author: jacobwilliams

src/json_value_module.F90

@@ -2510,8 +2510,27 @@ end subroutine json_value_add_member
 !  end program test
 !````
 !
-!@note This routine can be used to insert a new element
-!      into an array or object at a specific index.
+!### Details
+!
+!  * This routine can be used to insert a new element (or set of elements)
+!    into an array or object at a specific index.
+!    See [[json_value_insert_after_child_by_index]]
+!  * Children and subsequent elements of `element` are carried along.
+!  * If the inserted elements are part of an existing list, then
+!    they are removed from that list.
+!
+!````
+!              p
+!       [1] - [2] - [3] - [4]
+!                 |
+!                [5] - [6] - [7]        n=3 elements inserted
+!              element       last
+!
+!  Result is:
+!
+!       [1] - [2] - [5] - [6] - [7] - [3] - [4]
+!
+!````
 
     subroutine json_value_insert_after(json,p,element)
 
@@ -2524,30 +2543,66 @@ subroutine json_value_insert_after(json,p,element)
     type(json_value),pointer       :: element !! the element to insert after `p`
 
     type(json_value),pointer :: parent  !! the parent of `p`
+    type(json_value),pointer :: next  !! temp pointer for traversing structure
+    type(json_value),pointer :: last  !! the last of the items being inserted
+    integer :: n  !! number of items being inserted
 
     if (.not. json%exception_thrown) then
 
         parent => p%parent
 
+        ! set first parent of inserted list:
+        element%parent => parent
+
+        ! Count the number of inserted elements.
+        ! and set their parents.
+        n = 1 ! initialize counter
+        next => element%next
+        last => element
+        do
+            if (.not. associated(next)) exit
+            n = n + 1
+            next%parent => parent
+            last => next
+            next => next%next
+        end do
+
         if (associated(parent)) then
-            element%parent => parent
-            parent%n_children = parent%n_children + 1
-            ! if p is last in list have to update parent tail:
-            if (associated(parent%tail,p)) parent%tail => element
-        else
-            element%parent => null()
+            ! update parent's child counter:
+            parent%n_children = parent%n_children + n
+            ! if p is last of parents children then
+            ! also have to update parent tail pointer:
+            if (associated(parent%tail,p)) then
+                parent%tail => last
+            end if
+        end if
+
+        if (associated(element%previous)) then
+            ! element is apparently part of an existing list,
+            ! so have to update that as well.
+            if (associated(element%previous%parent)) then
+                element%previous%parent%n_children = &
+                    element%previous%parent%n_children - n
+                element%previous%parent%tail => &
+                    element%previous ! now the last one in the list
+            else
+                ! this would be a memory leak if the previous entries
+                ! are not otherwise being pointed too
+                ! [throw an error in this case???]
+            end if
+            !remove element from the other list:
+            element%previous%next => null()
         end if
+        element%previous => p
 
-        !if there are any in the list after p:
         if (associated(p%next)) then
-            element%next => p%next
-            element%next%previous => element
+            ! if there are any in the list after p:
+            last%next => p%next
+            last%next%previous => element
         else
-            element%next => null()
+            last%next => null()
         end if
-
         p%next => element
-        element%previous => p
 
     end if
 
@@ -2557,7 +2612,7 @@ end subroutine json_value_insert_after
 !*****************************************************************************************
 !>
 !  Inserts `element` after the `idx`-th child of `p`,
-!  and updates the JSON structure accordingly. It is just
+!  and updates the JSON structure accordingly. This is just
 !  a wrapper for [[json_value_insert_after]].
 
     subroutine json_value_insert_after_child_by_index(json,p,idx,element)

src/tests/jf_test_20.f90

@@ -21,7 +21,7 @@ subroutine test_20(error_cnt)
     integer,intent(out) :: error_cnt !! report number of errors to caller
 
     type(json_core) :: json
-    type(json_value),pointer :: p,new,element
+    type(json_value),pointer :: p,new,element,elements,root
     logical(lk) :: found,is_valid
     integer(IK),dimension(:),allocatable :: iarray
     character(kind=CK,len=:),allocatable :: error_msg
@@ -111,6 +111,59 @@ subroutine test_20(error_cnt)
             end if
         end if
 
+        ! extract a set of elements from one array
+        ! and insert them into another:
+        nullify(new)
+        call json%create_object(root,'')
+        call json%create_array(new,'array')
+        call json%add(root,new)
+        call json%add(new,'',100)
+        call json%add(new,'',101)
+        call json%add(new,'',102)
+
+        call json%get(root,'array',iarray)
+        if (json%failed()) then
+            call json%print_error_message(error_unit)
+            error_cnt = error_cnt + 1
+        end if
+
+        call json%get_child(new,2,elements)
+        if (json%failed()) then
+            call json%print_error_message(error_unit)
+            error_cnt = error_cnt + 1
+        else
+            call json%insert_after(element,7,elements) ! insert new element after x(7)
+            call json%get(p,'x',iarray)
+            if (.not. all(iarray==[1,2,22,3,33,4,44,101,102])) then
+                write(error_unit,'(A,1x,*(I3,1X))') 'Error: unexpected output:',iarray
+                error_cnt = error_cnt + 1
+            else
+                write(error_unit,'(A,1x,*(I3,1X))') 'Success:',iarray
+            end if
+
+            !also check original list, which should now have only 100
+            call json%validate(new,is_valid,error_msg)
+            if (.not. is_valid) then
+                write(error_unit,'(A)') trim(error_msg)
+                error_cnt = error_cnt + 1
+            else
+                !check contents:
+                call json%get(root,'array',iarray)
+                if (json%failed()) then
+                    call json%print_error_message(error_unit)
+                    error_cnt = error_cnt + 1
+                else
+                    if (.not. all(iarray==[100])) then
+                        write(error_unit,'(A,1x,*(I3,1X))') 'Error: unexpected output:',iarray
+                        error_cnt = error_cnt + 1
+                    else
+                        write(error_unit,'(A,1x,*(I3,1X))') 'Success:',iarray
+                    end if
+                end if
+            end if
+
+        end if
+
         call json%validate(p,is_valid,error_msg)
         if (.not. is_valid) then
             write(error_unit,'(A)') trim(error_msg)