Finding multiple feasible solutions using MiniZinc/HiGHS fails

[hdavid16]

I'm trying to find multiple feasible solutions in the attached problem. However, I am running into the following road blocks:

1. If I use MiniZinc/HiGHS, adding SolutionLimit results in an error.
2. If I use MiniZinc/HiGHS and don't add the SolutionLimit line, 1 solution is successfully found.

Can HiGHS be used with MiniZinc to find multiple solutions?

feasibility.mof.json

using JuMP, MiniZinc
model = read_from_file("feasibility.mof.json")
set_optimizer(model, () -> MiniZinc.Optimizer{Float64}("highs"))
set_optimizer_attribute(model, MOI.SolutionLimit(), 5)
optimize!(model)
Dict(v => value(v) for v in all_variables(model))

ERROR: Result index of attribute MathOptInterface.VariablePrimal(1) out of bounds. There are currently 0 solution(s) in the model.

[odow]

You must always check the statuses before querying a value.

raw_status(model) will show you:

=====ERROR=====
minizinc: Unrecognized option or bad format `--num-solutions'
minizinc: MiniZinc driver.
Usage: minizinc  [<options>] [-I <include path>] <model>.mzn [<data>.dzn ...] or just <flat>.fzn
More info with "/Users/oscar/.julia/artifacts/4c78c50512c620cc7df12173a8532f3730440298/bin/minizinc --help"

HiGHS does not support passing a solution limit, and it does not support returning multiple solutions.

[odow]

Closing as won't fix.

[hdavid16]

Thanks @odow for pointing me to raw_status

[chriscoey]

@odow thank you. just wondering if you have heard anything off-hand about HiGHS exposing a solution pool for MIPs in future? In this HiGHS discussion from 2022 ERGO-Code/HiGHS#949 Julian mentions “The accumulation of a solution pool is WIP”

[odow]

Do you want a solution pool that force enumerates a set of optimal solutions? Or are you okay with just getting whatever primal feasible solutions were found during the search? The former is unlikely to happen any time soon. The latter can be setup using a callback. I can demo the code if you're interested.

[odow]

But the callback would need HiGHS.jl directly. You couldn't use MiniZinc.jl

[hdavid16]

Both applications are of interest. A demo of the callbacks with HiGHS would be nice to have. If you can provide a demo, it would be much appreciated.

Along the lines of the former (enumerating a set of solutions), I've run HiGHS in a loop adding no-good-cuts at each iteration to create a solution pool. For our current applications, we still have significant latency in building the model before sending it to MOI, which is why getting a solution pool like Gurobi does is of interest.

[odow]

julia> using JuMP, HiGHS

julia> function main(N)
           model = direct_model(HiGHS.Optimizer())
           set_silent(model)
           @variable(model, 0 <= x[1:N] <= 3, Int)
           @constraint(model, rand(N)' * x <= 0.1 * N)
           @objective(model, Max, rand(N)' * x)
           solutions = Vector{Float64}[]
           function callback_fn(
               callback_type::Cint,
               message::Ptr{Cchar},
               data_out::HiGHS.HighsCallbackDataOut,
           )::Cint
               if callback_type == kHighsCallbackMipSolution
                   ret = HiGHS.Highs_getCallbackDataOutItem(Ref(data_out), "mip_solution")
                   ret = convert(Ptr{Float64}, ret)
                   push!(solutions, copy(unsafe_wrap(Array, ret, N)))            
               end
               return 0
           end
           set_attribute(model, HiGHS.CallbackFunction(), callback_fn)
           optimize!(model)
           return unique(solutions)
       end
main (generic function with 1 method)

julia> main(100)
5-element Vector{Vector{Float64}}:
 [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0  …  0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0]
 [0.0, 0.0, 0.0, 0.0, 0.0, 3.0, 3.0, 3.0, 0.0, 3.0  …  0.0, 0.0, 0.0, 0.0, 3.0, 0.0, 0.0, 0.0, 0.0, 0.0]
 [0.0, 0.0, 0.0, 0.0, 0.0, 3.0, 3.0, 3.0, 0.0, 3.0  …  0.0, 0.0, 0.0, 0.0, 3.0, 0.0, 0.0, 0.0, 0.0, 0.0]
 [0.0, 0.0, 0.0, 0.0, 0.0, 3.0, 3.0, 3.0, 0.0, 3.0  …  0.0, 0.0, 0.0, 0.0, 3.0, 0.0, 0.0, 0.0, 0.0, 0.0]
 [0.0, 0.0, 0.0, 0.0, 0.0, 3.0, 3.0, 3.0, 0.0, 3.0  …  0.0, 0.0, 0.0, 0.0, 3.0, 0.0, 0.0, 0.0, 0.0, 0.0]