meson.build.1

if get_option('with_test')

    test_exe = executable(meson.project_name() + '-test',
        sources,
        include_directories: directories,
        d_unittest: true,
        d_module_versions: test_versions,
        link_args: '-main',
        dependencies: required_deps,
    )

    test(meson.project_name() + '-test', test_exe)

    foreach dir : test_subdirs
        subdir(dir)
    endforeach
endif

if get_option('with_doc')

    tags = run_command('python3', 'docgen/stable_and_latest_tags.py').stdout().split()
    stable_tag = tags[0]
    latest_tag = tags[1]

    docs_config =  latest_tag + '.ddoc'
    latest_file = custom_target('latest_target',
                build_by_default: true,
                input : [],
                output : docs_config,
                capture: true,
                command: ['echo',
                    '\nLATEST=' + latest_tag +
                    '\nLATEST_STABLE=' + stable_tag +
                    '\nPROJECT=' + meson.project_name() +
                    '\nCOMPANY=' + get_option('company') +
                    '\nMETA_DESCRIPTION=' + description
                ])

    d_compiler = meson.get_compiler('d').get_id()
    if d_compiler == 'gcc'
        d_compiler = 'gdmd'
    elif d_compiler == 'llvm'
        d_compiler = 'ldmd2'
    else
        d_compiler = 'dmd'
    endif

    root = meson.source_root()

    menu = custom_target('menu_target',
                build_by_default: true,
                input : files('docgen/gen_modlist.d'),
                output : 'mir.ddoc',
                capture: true,
                command: [d_compiler, '-run', '@INPUT0@', join_paths(root, 'source')])

    includes = ['-I' + join_paths(root, 'source')]
    foreach sub_name : subprojects
        includes += '-I' + join_paths(root, 'subprojects', sub_name, 'source')
    endforeach

    extra_args = [d_compiler, '-w', '-c', '-o-', '-preview=dip1008',
            docs_config,
            join_paths(root, 'docgen/macros.ddoc'),
            join_paths(root, 'docgen/html.ddoc'),
            join_paths(root, 'docgen/dlang.org.ddoc'),
            join_paths(root, 'docgen/std.ddoc'),
            join_paths(root, 'docgen/custom.ddoc'),
            'mir.ddoc',
            includes,
            '-Dfweb/@OUTPUT@', '@INPUT@']

    i = 0
    foreach source : sources_list

        test_name = 'documented_unittests_' + source.underscorify()
        test_source_name = test_name + '.d'

        test_source = custom_target(test_name,
            output: test_source_name,
            input: sources[i],
            capture: true,
            command: [
                'dtools_tests_extractor',
                # '--betterC',
                '-i',
                '@INPUT@',
            ]
        )

        test_exe = executable(test_name + '_exe',
            test_source,
            include_directories: directories,
            d_unittest: true,
            d_module_versions: test_versions,
            link_args: '-main',
            dependencies: this_dep,
        )

        test(source + ' documented unittest', test_exe)

        i += 1
    endforeach

    htmls = []

    foreach f : sources_list
        s = []
        foreach e : f.split('/')
            if e != 'package'
                s += e
            endif
        endforeach
        htmls += '_'.join(s) + '.html'
    endforeach

    htmls = ['index.html'] + htmls
    sources = ['index.d'] + sources

    i = 0
    foreach source : sources
        custom_target('doc_target_' + i.to_string(),
                build_by_default: true,
                input : source,
                output : htmls[i],
                depends: [menu, latest_file],
                command: extra_args,
            )
        i += 1
    endforeach

endif