build.gradle

buildscript {
  repositories {
    mavenCentral()
    // Needed for ml-gradle 6.2-SNAPSHOT
    maven {
      url = "https://bed-artifactory.bedford.progress.com:443/artifactory/ml-maven-snapshots/"
    }
  }
  dependencies {
    classpath "com.marklogic:ml-gradle:6.2-SNAPSHOT"
  }
}

plugins {
  id "net.saliman.properties" version "1.6.0"
}

apply plugin: "com.marklogic.ml-gradle"

// Using longer values as MarkLogic seems to take much longer to initialize with the Jenkins nodeclientpool.
mlWaitTillReady {
  waitInterval = 3000
  maxAttempts = 40
}

tasks.register("addMarkLogic12SchemasIfNecessary", com.marklogic.gradle.task.MarkLogicTask) {
  description = "If testing against MarkLogic 12, include schemas that will not work on MarkLogic 11 or earlier."
  doLast {
    def version = new com.marklogic.mgmt.resource.clusters.ClusterManager(getManageClient()).getVersion()
    if (version.startsWith("12.")) {
      mlAppConfig.getSchemaPaths().add(new File(getProjectDir(), "src/main/ml-schemas-12").getAbsolutePath())
    }
  }
}
mlDeploy.dependsOn addMarkLogic12SchemasIfNecessary
mlLoadSchemas.dependsOn addMarkLogic12SchemasIfNecessary

/*
 * Required for forcing MarkLogic to generate a temporary certificate for the app server
 * that requires SSL.
 */
ext {
  def command = new com.marklogic.appdeployer.command.security.GenerateTemporaryCertificateCommand()
  command.setTemplateIdOrName("node-client-ssl-template")
  command.setCommonName("localhost")
  command.setValidFor(365)
  mlAppDeployer.commands.add(command)
}

tasks.register("curlPeople", Exec) {
  commandLine = [
    'curl',
    '--fail',
    '--anyauth', '--user', 'admin:admin',
    '-i',
    '-X', 'POST',
    '--data-binary', '@./src/main/turtle/people/people.ttl',
    '-H', 'Content-type: text/turtle',
    "http://${mlHost}:8079/v1/graphs?graph=/people"
  ]
}

tasks.register("curlCompanies", Exec) {
  commandLine = [
    'curl',
    '--fail',
    '--anyauth', '--user', 'admin:admin',
    '-i',
    '-X', 'POST',
    '--data-binary', '@./src/main/turtle/companies/companies_100.ttl',
    '-H', 'Content-type: text/turtle',
    "http://${mlHost}:8079/v1/graphs?graph=/optic/sparql/test/companies.ttl"
  ]
}

mlDeploy.finalizedBy curlPeople
mlDeploy.finalizedBy curlCompanies