Latest local changes for branching.

Author: BKcore

bkcore.coffee/controllers/OrientationController.coffee

@@ -0,0 +1,72 @@
+###
+  OrientationController (Orientation + buttons) for touch devices
+  
+  @class bkcore.OrientationController
+  @author Thibaut 'BKcore' Despoulain <http://bkcore.com>
+###
+class OrientationController
+
+  @isCompatible: ->
+    return ('DeviceOrientationEvent' of window)
+
+  ###
+    Creates a new OrientationController
+
+    @param dom DOMElement The element that will listen to touch events
+    @param registerTouch bool Enable touch detection
+    @param touchCallback function Callback for touches
+  ###
+  constructor: (@dom, @registerTouch=true, @touchCallback=null) ->
+    @active = true
+    @alpha = 0.0
+    @beta = 0.0
+    @gamma  = 0.0
+    @dalpha = null
+    @dbeta = null
+    @dgamma = null
+    @touches = null
+
+    window.addEventListener('deviceorientation', ((e)=> @orientationChange(e)), false)
+    if @registerTouch
+      @dom.addEventListener('touchstart', ((e)=> @touchStart(e)), false)
+      @dom.addEventListener('touchend', ((e)=> @touchEnd(e)), false)
+
+  ###
+    @private
+  ###
+  orientationChange: (event) ->
+    return if not @active
+    if(@dalpha == null)
+      console.log "calbrate", event.beta 
+      @dalpha = event.alpha
+      @dbeta = event.beta
+      @dgamma = event.gamma
+    @alpha = event.alpha - @dalpha
+    @beta = event.beta - @dbeta
+    @gamma = event.gamma - @dgamma
+    false
+
+  ###
+    @private
+  ###
+  touchStart: (event) ->
+    return if not @active
+    for touch in event.changedTouches
+        @touchCallback?(on, touch, event)
+    @touches = event.touches
+    false
+
+  ###
+    @private
+  ###
+  touchEnd: (event) ->
+    return if not @active
+    for touch in event.changedTouches
+        @touchCallback?(on, touch, event)
+    @touches = event.touches
+    false
+
+exports = exports ? @
+exports.bkcore ||= {}
+exports.bkcore.controllers ||= {}
+exports.bkcore.controllers.OrientationController = OrientationController

bkcore.coffee/controllers/OrientationController.js

@@ -0,0 +1,109 @@
+###
+  TouchController (stick + buttons) for touch devices
+  Based on the touch demo by Seb Lee-Delisle <http://seb.ly/>
+  
+  @class bkcore.controllers.TouchController
+  @author Thibaut 'BKcore' Despoulain <http://bkcore.com>
+###
+class TouchController
+
+  @isCompatible: ->
+    return ('ontouchstart' of document.documentElement);
+
+  ###
+    Creates a new TouchController
+
+    @param dom DOMElement The element that will listen to touch events
+    @param stickMargin int The left margin in px for stick detection
+    @param buttonCallback function Callback for non-stick touches
+  ###
+  constructor: (@dom, @stickMargin=200, @buttonCallback=null) ->
+    @active = true
+    @touches = null
+    @stickID = -1
+    @stickPos = new Vec2(0, 0)
+    @stickStartPos = new Vec2(0, 0)
+    @stickVector = new Vec2(0, 0)
+
+    @dom.addEventListener('touchstart', ((e)=> @touchStart(e)), false)
+    @dom.addEventListener('touchmove', ((e)=> @touchMove(e)), false)
+    @dom.addEventListener('touchend', ((e)=> @touchEnd(e)), false)
+
+  ###
+    @private
+  ###
+  touchStart: (event) ->
+    return if not @active
+    for touch in event.changedTouches
+      if @stickID < 0 and touch.clientX < @stickMargin
+        @stickID = touch.identifier
+        @stickStartPos.set(touch.clientX, touch.clientY)
+        @stickPos.copy(@stickStartPos)
+        @stickVector.set(0, 0)
+        continue
+      else
+        @buttonCallback?(on, touch, event)
+    @touches = event.touches
+    false
+
+  ###
+    @private
+  ###
+  touchMove: (event) ->
+    event.preventDefault()
+    return if not @active
+    for touch in event.changedTouches
+      if @stickID is touch.identifier
+        @stickPos.set(touch.clientX, touch.clientY)
+        @stickVector.copy(@stickPos).substract(@stickStartPos)
+        break
+    @touches = event.touches
+    false
+
+  ###
+    @private
+  ###
+  touchEnd: (event) ->
+    return if not @active
+    @touches = event.touches
+    for touch in event.changedTouches
+      if @stickID is touch.identifier
+        @stickID = -1
+        @stickVector.set(0, 0)
+        break
+      else
+        @buttonCallback?(off, touch, event)
+    false
+
+###
+  Internal class used for vector2
+  @class Vec2
+  @private
+###
+class Vec2
+
+  constructor: (@x = 0, @y = 0) ->
+
+  substract: (vec) ->
+    @x -= vec.x
+    @y -= vec.y
+    @
+
+  copy: (vec) ->
+    @x = vec.x
+    @y = vec.y
+    @
+
+  set: (x, y) ->
+    @x = x
+    @y = y
+    @
+	
+###
+  Exports
+  @package bkcore
+###
+exports = exports ? @
+exports.bkcore ||= {}
+exports.bkcore.controllers ||= {}
+exports.bkcore.controllers.TouchController = TouchController