build.gradle

plugins {
    id 'java'
    id 'maven-publish'
}

group = 'com.nicat.asgarzada'
version = '1.0.0'
sourceCompatibility = '11'

repositories {
    mavenCentral()
}

dependencies {
    // for template rendering
    implementation('org.codehaus.groovy:groovy-templates:3.0.8')

    // for sending smtp messages
    implementation('jakarta.activation:jakarta.activation-api:2.0.1')
    implementation('jakarta.mail:jakarta.mail-api:2.0.1')
    implementation('com.sun.mail:jakarta.mail:2.0.1')

    testImplementation('org.junit.jupiter:junit-jupiter')
    testImplementation(platform('org.junit:junit-bom:5.7.2'))
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/nasgarzada/mail-util")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
            }
        }
    }
    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}