build.gradle

apply plugin: 'com.android.library'
apply plugin: 'maven-publish'
apply plugin: 'jacoco'

version '0.10.8-SNAPSHOT'
project.version = this.version


jacoco {
    toolVersion = jacocoVersion
}

android {

    namespace "io.ona.kujaku.utils"

    compileSdk rootProject.ext.compileSdkVersion

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    defaultConfig {
        minSdkVersion 21
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode 1
        versionName this.version
        testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        debug {
            // See bug https://github.com/vanniktech/gradle-android-junit-jacoco-plugin/issues/183
            testCoverageEnabled true
        }
    }

    lintOptions {
        abortOnError false
    }
}

dependencies {
    androidTestImplementation ('androidx.test.espresso:espresso-core:3.6.1', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    implementation 'androidx.appcompat:appcompat:1.7.0'
    implementation 'com.cocoahero.android:geojson:1.0.1@jar'
    implementation (mapboxSDK) {
        transitive = true
        exclude group: 'com.android.support', module: 'support-annotations'
        exclude group: 'com.android.support', module: 'support-fragment'
    }

    // The local build has an issue fetching this library for some reason which
    // is a dependency of the mapbox-android-sdk. The mapbox-sdk-turf is declared as
    // a runtime dependency
    implementation mapboxSDKTurf
    implementation mapboxStyleEx
    implementation mapboxLocation
    implementation mapboxGestures
    //implementation mapboxAnnotationPlugin

    testImplementation junit
    testImplementation robolectric
    testImplementation 'org.skyscreamer:jsonassert:1.5.3'
}

tasks.withType(Test) {
    jacoco.includeNoLocationClasses = true
    jacoco.excludes = ['jdk.internal.*']
}

task printTasks {
    System.out.println("Jacoco version ${jacoco.toolVersion}")
}

// Add github packages, maven-central and sonatype publishing
apply from: '../publish.gradle'
apply from: '../jacoco-report.gradle'