Add test for Japanese characters in table definition and errors

The test is taken from DBD::MariaDB and adopted to DBD::mysql.

There are two runs of all tests:
* one without mysql_enable_utf8 option
* one with enabled mysql_enable_utf8 option

There are XXX comments for situations which not follow mysql_enable_utf8
option.

Author: michal-josef-spacek

MANIFEST

@@ -53,6 +53,7 @@ t/51bind_type_guessing.t
 t/52comment.t
 t/53comment.t
 t/55utf8.t
+t/55utf8_jp.t
 t/55utf8mb4.t
 t/56connattr.t
 t/57trackgtid.t

t/55utf8_jp.t

@@ -0,0 +1,156 @@
+use strict;
+use warnings;
+
+use Test::More;
+use DBI;
+use Encode;
+
+use constant STRICT_DECODE => 1;
+
+use vars qw($test_dsn $test_user $test_password);
+use lib 't', '.';
+require "lib.pl";
+
+sub skip_rt_102404 {
+  skip "(Perl 5.13.1 and DBI 1.635) or DBI 1.639 is required due to bug RT 102404", $_[0] unless ($] >= 5.013001 and eval { DBI->VERSION(1.635) }) or eval { DBI->VERSION(1.639) };
+}
+
+sub for_db {
+  my ($mysql_enable_utf8, $value) = @_; # Value is in internal Perl Unicode.
+
+  my $ret;
+  if ($mysql_enable_utf8 == 1) {
+    $ret = $value;
+  } else {
+    $ret = Encode::encode('UTF-8', $value);
+  }
+
+  return $ret;
+}
+
+my $dbh;
+my $test_dsn = 'DBI:mysql:database=test';
+my $test_user = 'skim';
+my $test_password = 'IecohPh6';
+eval {$dbh= DBI->connect($test_dsn, $test_user, $test_password,
+                      { RaiseError => 1, PrintError => 1, AutoCommit => 0 });};
+if ($@) {
+    plan skip_all => "no database connection";
+}
+$dbh->disconnect();
+
+plan tests => 22 * 2;
+
+# All in internal Perl Unicode
+my $jpnTable = "\N{U+8868}"; # Japanese table
+my $jpnGender = "\N{U+6027}\N{U+5225}"; # Japanese word "gender"
+my $jpnYamadaTaro = "\N{U+5c71}\N{U+7530}\N{U+592a}\N{U+90ce}"; # a Japanese person name
+my $jpnMale = "\N{U+7537}"; # Japanese word "male"
+my $jpnErr = qr/\x{4ed8}\x{8fd1}.*\x{884c}\x{76ee}/; # Use \x{...} instead \N{U+...} due to Perl 5.12.0 bug
+
+foreach my $mysql_enable_utf8 (0, 1) {
+    $dbh = DBI->connect($test_dsn, $test_user, $test_password,
+                  { RaiseError => 1, PrintError => 1, AutoCommit => 0, $mysql_enable_utf8 ? (mysql_enable_utf8 => 1) : () });
+    if ($mysql_enable_utf8) {
+    	diag "Enabled mysql_enable_utf8.";
+    } else {
+    	diag "Disabled mysql_enable_utf8.";
+    }
+
+    eval {
+      $dbh->do("SET lc_messages = 'ja_JP'");
+    } or do {
+      $dbh->disconnect();
+      plan skip_all => "Server lc_messages ja_JP are needed for this test";
+    };
+    
+    my $jpnTable_db = for_db($mysql_enable_utf8, $jpnTable);
+    my $jpnGender_db = for_db($mysql_enable_utf8, $jpnGender);
+    my $jpnYamadaTaro_db = for_db($mysql_enable_utf8, $jpnYamadaTaro);
+    my $jpnMale_db = for_db($mysql_enable_utf8, $jpnMale);
+    
+    my $sth;
+    my $row;
+
+    ok($dbh->do("DROP TABLE IF EXISTS $jpnTable_db"), 'Drop table.');
+    
+    ok($dbh->do(<<"END"
+CREATE TEMPORARY TABLE $jpnTable_db (
+  name VARCHAR(20),
+  $jpnGender_db CHAR(1)
+) ENGINE=InnoDB DEFAULT CHARSET=utf8 COLLATE=utf8_bin
+END
+    ), 'Create temporay table with Japanese characters.');
+    
+    ok($sth = $dbh->prepare("INSERT INTO $jpnTable_db (name, $jpnGender_db) VALUES (?, ?)"), 'Prepare insert statement.');
+    ok($sth->execute($jpnYamadaTaro_db, $jpnMale_db), 'Execute insert statement with Japanese values.');
+    
+    ok($sth = $dbh->prepare("SELECT * FROM $jpnTable_db"), 'Prepare select statement.');
+    ok($sth->execute(), 'Execute select statement.');
+    ok($row = $sth->fetchrow_hashref(), 'Fetch hashref.');
+    
+    is($row->{name}, $jpnYamadaTaro_db, "Value of 'name'.");
+    ok(!exists $row->{$jpnGender}, 'Not exists key in internal Perl Unicode.'); # XXX
+    is($row->{Encode::encode('UTF-8', $jpnGender)}, $jpnMale_db, 'Exists key in octets and value.'); # XXX
+
+    is_deeply($sth->{NAME}, [ 'name', Encode::encode('UTF-8', $jpnGender) ], 'Statement column name is in octets.'); # XXX
+    is_deeply($sth->{mysql_table}, [ Encode::encode('UTF-8', $jpnTable), Encode::encode('UTF-8', $jpnTable) ], 'Statement table name is in octets.'); # XXX
+    
+    my $warn;
+    my $dieerr;
+    my $dbierr;
+    my $failed;
+    
+    $failed = 0;
+    $dieerr = undef;
+    $dbierr = undef;
+    $dbh->{HandleError} = sub { $dbierr = $_[0]; die $_[0]; };
+    eval {
+      $sth = $dbh->prepare("foo");
+      $sth->execute();
+      1;
+    } or do {
+      $dieerr = $@;
+      $failed = 1;
+    };
+    $dbh->{HandleError} = undef;
+
+    ok($failed, 'Execution of bad statement is failing (HandleError version).');
+    like(Encode::decode('UTF-8', $dbierr), $jpnErr, 'DBI error is in octets (HandleError version).'); # XXX
+    like(Encode::decode('UTF-8', $DBI::errstr), $jpnErr, 'DBI::errstr is in octets (HandleError version).'); # XXX 
+    like(Encode::decode('UTF-8', $dbh->errstr), $jpnErr, 'DBI handler errstr() method is in octets (HandleError version).'); # XXX
+    
+    SKIP : {
+      skip_rt_102404 1;
+      like(Encode::decode('UTF-8', $dieerr), $jpnErr, 'Error from eval is in octets (HandleError version).');
+    }
+    
+    $failed = 0;
+    $warn = undef;
+    $dieerr = undef;
+    $dbh->{PrintError} = 1;
+    $SIG{__WARN__} = sub { $warn = $_[0] };
+    eval {
+      $sth = $dbh->prepare("foo");
+      $sth->execute();
+      1;
+    } or do {
+      $dieerr = $@;
+      $failed = 1;
+    };
+    $dbh->{PrintError} = 0;
+    $SIG{__WARN__} = 'DEFAULT';
+    
+    ok($failed, 'Execution of bad statement is failing (PrintError version).');
+    like(Encode::decode('UTF-8', $DBI::errstr), $jpnErr, 'DBI::errstr is in octets (PrintError version).'); # XXX
+    like(Encode::decode('UTF-8', $dbh->errstr), $jpnErr, 'DBI handler errstr() method is in octets (PrintError version).'); # XXX
+    
+    SKIP : {
+      skip_rt_102404 2;
+      like(Encode::decode('UTF-8', $warn), $jpnErr, 'Warning is in octets (PrintError version).'); # XXX
+      like(Encode::decode('UTF-8', $dieerr), $jpnErr, 'Error from eval is in octets (PrintError version).'); # XXX
+    }
+    
+    $dbh->disconnect();
+}
+done_testing;