Recording wav works, but playback fails

[jonascant]

I am recording a wav file to sd. The file records fine, it can be played on a pc.
However the playback of the same file fails with:
File has 369708 bytes [E] CodecWAV.h : 446 - WAV format not supported: 0 [E] StreamCopy.h : 401 - write to target has failed after 22 retries! (1024 bytes)

I doubt, this is really a codec problem, but I cant find anything wrong in my sketch.

#include "AudioTools.h"

#include <SD.h>
#include <SPI.h>

//Audio Setup
AudioInfo info(48000, 2, 32);
AudioInfo sd_info(48000, 1, 32);
I2SStream in;
I2SStream out; 
VolumeMeter meter(in);
VolumeStream volume(out);
ConverterFillLeftAndRight<int32_t> filler(RightIsEmpty); // fill both channels - or change to RightIsEmpty
//StreamCopy copier(volume, meter); // copies sound into i2s

//for recoreding
File file;  // final output stream
EncodedAudioStream out2SD(&file, new WAVEncoder());
FormatConverterStream conv(out2SD);
const char* file_name = "/rec.wav";
bool recording = false;
bool started = false;

//For Playback
WAVDecoder wav;
EncodedAudioStream encoded(&volume, &wav); // Decoding stream

MultiOutput multi_out;
StreamCopy copier(volume, meter); 

void recordingHandler(){
  if (millis() < 2000){
    if (!started){
      // Initialize Recording
      Serial.println ("Starting to record");
      recording = true;
      started = true;
      
      // Cleanup if necessary
      if (SD.exists(file_name))
	SD.remove(file_name);

      // open file
      file = SD.open(file_name, FILE_WRITE);
      if (!file){
	Serial.println("file failed!");
	stop();
      }
      //record to sd and monitor audio simultanously
      copier.begin(multi_out,meter);
    }
  }else if (millis() < 4000){
    if (recording){
      //Recording just stopped, play back recording
      recording = false;
      if (file) {
	file.flush();
	Serial.print("File has ");
	Serial.print(file.size());
	Serial.println(" bytes");
	file.close();
      }
      file = SD.open(file_name);
      if (!file){
	Serial.println("file failed!");
	stop();
      }
      encoded.begin();
      copier.begin(encoded,file);
    }
 }else{
    //go back to audio monitoring
    copier.begin(volume, meter);
 }
}

// Arduino Setup
void setup(void) { 
  // Open Serial 
  Serial.begin(115200);

  // change to Warning to improve the quality
  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // start I2S in
  Serial.println("starting I2S...");
  auto config_in = in.defaultConfig(RX_MODE);
  config_in.copyFrom(info); 
  config_in.i2s_format = I2S_STD_FORMAT;
  config_in.is_master = true;
  config_in.port_no = 0;
  config_in.pin_bck = 14;
  config_in.pin_ws = 27;
  config_in.pin_data = 12;

  // start I2S out
  auto config_out = out.defaultConfig(TX_MODE);
  config_out.copyFrom(info); 
  config_out.port_no = 1;
  config_out.pin_bck = 26;
  config_out.pin_ws = 25;
  config_out.pin_data = 22;

  auto configvol = volume.defaultConfig();
  configvol.allow_boost = true; 
  //configvol.bits_per_sample = 16;

  // Open SD drive
  if (!SD.begin(5)) {
    Serial.println("Initialization failed!");
    stop();
  }

  //MultiOut
  multi_out.add(volume);
  multi_out.add(conv);


  //Hardware Connections
  in.begin(config_in);
  out.begin(config_out);
  out2SD.begin(sd_info);

  //Helpers
  conv.begin(info, sd_info);
  meter.begin(info);
  volume.begin(configvol);

  volume.setVolume(20.0); 

  Serial.println("I2S started...");
  copier.begin(volume, meter);

}

// Arduino loop - copy sound to out 
void loop() {
  recordingHandler();
  copier.copy(filler);
}

[pschatzmann]

Display a hex dump of the header of the WAV file: there seems to be something wrong!
The WAV format is supposed to be 1 and the value 0 is not valid. If this is wrong, I would expect the whole header to be messed up...

I see the following problems:

• There is a lot of unnecessary complexity: try to simplify the whole thing. If you want to record 1 channel only then just use I2S in the 1 channel mode. So you can get rid of the ConverterFillLeftAndRight and FormatConverterStream to achieve the same thing.
• You seem to be undecided to how use the VolumeMeter. If you want to use it in the chain, don't use it in the MultiOutput or if you want to measure also the output volume, add a separate VolumeMeter w/o argument.
• You forgot to call begin on the MultiOutput
• I would move at least the out2SD.begin(sd_info); to the recoringHandler after you deleted the file, to make it dead sure that the WAV header record is created.

Finally set the log level to info so that you can check what's happening. I guess your logic just deletes the file with the valid WAV header.

[jonascant]

I will do that. Just a note: the ConverterFillLeftAndRight is because i need two channels for the live monitoring via headphones, while its recording. Thats also the reason for the MultiOut. I would like to just work with one channel, but the Headphones need two and i need monitoring all the time, no matter if a recording is running or not.

[pschatzmann]

If you have only 1 microphone: 1 channel should be good enough and you will still get the output on the left and right of your headphone using i2s output.

[jonascant]

at the beginning i only used one channel, but only heard it on on channel too. maybe my out_config was wrong then.

[pschatzmann]

You are right: this has changed with the new driver for 3.0

[jonascant]

00000000  52 49 46 46 1c 00 ff 7f  57 41 56 45 66 6d 74 20  |RIFF....WAVEfmt |
00000010  10 00 00 00 01 00 01 00  80 bb 00 00 00 ee 02 00  |................|
00000020  04 00 20 00 64 61 74 61  24 00 ff 7f 00 46 b0 ff  |.. .data$....F..|
00000030  00 38 c4 ff 00 88 b0 ff  00 28 ec ff 00 18 d8 ff  |.8.......(......|

[pschatzmann]

This looks right: maybe the file position is wrong when you read the data back...

[jonascant]

is there a pointer, that has to be reset? Or should i reinitialize the sd card?

[pschatzmann]

try with file.seek(0)

[jonascant]

I did, same result unfortunately.

      file = SD.open(file_name);
      file.seek(0);
      if (!file){
	Serial.println("file failed!");
	stop();
      }
      encoded.begin(info);
      copier.begin(encoded,file);

Results:

File has 370220 bytes
[E] CodecWAV.h : 446 - WAV format not supported: 0
[E] StreamCopy.h : 401 - write  to target has failed after 22 retries! (1024 bytes)
[E] StreamCopy.h : 401 - write  to target has failed after 22 retries! (1024 bytes)
[E] StreamCopy.h : 401 - write  to target has failed after 22 retries! (1024 bytes)

Wav Header:

$ xxd -l 64 /media/jonas/ED3B-7811/rec.wav 
00000000: 5249 4646 1c00 ff7f 5741 5645 666d 7420  RIFF....WAVEfmt 
00000010: 1000 0000 0100 0100 80bb 0000 00ee 0200  ................
00000020: 0400 2000 6461 7461 2400 ff7f 0000 0000  .. .data$.......
00000030: 0000 0000 0000 0000 0000 0000 0000 0000  ................

[jonascant]

in Debug mode:

[D] BaseStream.h : 118 - virtual void audio_tools::AudioStream::setAudioInfo(audio_tools::AudioInfo)
[I] AudioTypes.h : 128 - in: sample_rate: 48000 / channels: 2 / bits_per_sample: 32
[I] AudioTypes.h : 128 - out: sample_rate: 48000 / channels: 2 / bits_per_sample: 32
[D] AudioIO.h : 30 - void audio_tools::TransformationReader<T>::begin(T*, Stream*) [with T = audio_tools::ReformatBaseStream]
[D] AudioEncoded.h : 140 - virtual bool audio_tools::EncodedAudioOutput::begin()
[D] AudioEncoded.h : 142 - virtual bool audio_tools::EncodedAudioOutput::begin()
[D] AudioCodecsBase.h : 27 - virtual void audio_tools::AudioDecoder::setAudioInfo(audio_tools::AudioInfo)
[D] CodecWAV.h : 302 - virtual bool audio_tools::WAVDecoder::begin()
[D] AudioStreams.h : 26 - audio_tools::AudioStreamWrapper::AudioStreamWrapper(Stream&)
[I] StreamCopy.h : 70 - buffer_size=1024
[D] StreamCopy.h : 192 - available: 6188
[D] StreamCopy.h : 384 - write: 1024
[I] AudioEncoded.h : 75 - virtual void audio_tools::EncodedAudioOutput::addNotifyAudioChange(audio_tools::AudioInfoSupport&)
[D] Allocator.h : 68 - Allocated 4
[D] AudioEncoded.h : 187 - EncodedAudioOutput::write: 1024
[D] CodecWAV.h : 323 - virtual size_t audio_tools::WAVDecoder::write(const uint8_t*, size_t)
[I] CodecWAV.h : 56 - WAVHeader::write: 1024 -> 44 -> 44
[I] CodecWAV.h : 63 - WAVHeader::begin: 44
[I] CodecWAV.h : 220 - WAVHeader sound_pos: 0
[I] CodecWAV.h : 221 - WAVHeader channels: 0 
[I] CodecWAV.h : 222 - WAVHeader bits_per_sample: 0
[I] CodecWAV.h : 223 - WAVHeader sample_rate: 0 
[I] CodecWAV.h : 224 - WAVHeader format: 0
[I] CodecWAV.h : 420 - WAV sample_rate: 0
[I] CodecWAV.h : 421 - WAV data_length: 0
[I] CodecWAV.h : 422 - WAV is_streamed: 0
[I] CodecWAV.h : 423 - WAV is_valid: false
[E] CodecWAV.h : 446 - WAV format not supported: 0
[D] VolumeStream.h : 145 - VolumeStream::write: 1024
[D] I2SStream.h : 114 - I2SStream::write: 1024
[D] I2SESP32V1.h : 104 - size_t audio_tools::I2SDriverESP32V1::writeBytes(const void*, size_t)
[D] AudioEncoded.h : 199 - EncodedAudioOutput::write: 1024 -> 1024
[D] StreamCopy.h : 390 - write: 1024 -> 1024
[I] StreamCopy.h : 489 - StreamCopy::copy 1024 bytes - in 1 hops

[jonascant]

I created a new wav file with audacity:

00000000: 5249 4646 4802 1e00 5741 5645 666d 7420  RIFFH...WAVEfmt 
00000010: 1000 0000 0300 0100 80bb 0000 00ee 0200  ................
00000020: 0400 2000 6661 6374 0400 0000 8080 0700  .. .fact........
00000030: 5045 414b 1000 0000 0100 0000 b723 a666  PEAK.........#.f
00000040: 00f0 7f3f 6f56 0000 6461 7461 0002 1e00  ...?oV..data....

and a new minimalistic sketch to just play it:

#include "AudioTools.h"
#include <SD.h>
#include <SPI.h>

//Audio Setup
AudioInfo info(48000, 2, 32);

AudioInfo sd_info(48000, 1, 32);
I2SStream out; 

WAVDecoder wav;
EncodedAudioStream encoded(&out, &wav); // Decoding stream

File file;  // final output stream
StreamCopy copier(encoded, file); 
const char* file_name = "/rec.wav";

// Arduino Setup
void setup(void) { 
  // Open Serial 
  Serial.begin(115200);

  // change to Warning to improve the quality
  AudioLogger::instance().begin(Serial, AudioLogger::Debug);

  // start I2S out
  auto config_out = out.defaultConfig(TX_MODE);
  config_out.copyFrom(info); 
  config_out.port_no = 1;
  config_out.pin_bck = 26;
  config_out.pin_ws = 25;
  config_out.pin_data = 22;

  // Open SD drive
  if (!SD.begin(5)) {
    Serial.println("Initialization failed!");
    stop();
  }
  file = SD.open(file_name);
  if (!file){
    Serial.println("file failed!");
    stop();
  }
  //Hardware Connections
  out.begin(config_out);

  Serial.println("I2S started...");
  encoded.begin(info);
  copier.begin(encoded, file);
}

// Arduino loop - copy sound to out 
void loop() {
  copier.copy();
}

This also does not play, but the headers is at least recognized now:

I2S started...
[D] BaseStream.h : 118 - virtual void audio_tools::AudioStream::setAudioInfo(audio_tools::AudioInfo)
[I] AudioTypes.h : 128 - in: sample_rate: 48000 / channels: 2 / bits_per_sample: 32
[I] AudioTypes.h : 128 - out: sample_rate: 48000 / channels: 2 / bits_per_sample: 32
[D] AudioIO.h : 30 - void audio_tools::TransformationReader<T>::begin(T*, Stream*) [with T = audio_tools::ReformatBaseStream]
[D] AudioEncoded.h : 140 - virtual bool audio_tools::EncodedAudioOutput::begin()
[D] AudioEncoded.h : 142 - virtual bool audio_tools::EncodedAudioOutput::begin()
[D] AudioCodecsBase.h : 27 - virtual void audio_tools::AudioDecoder::setAudioInfo(audio_tools::AudioInfo)
[D] CodecWAV.h : 302 - virtual bool audio_tools::WAVDecoder::begin()
[D] AudioStreams.h : 26 - audio_tools::AudioStreamWrapper::AudioStreamWrapper(Stream&)
[I] StreamCopy.h : 70 - buffer_size=1024
[D] StreamCopy.h : 98 - copy 1024 bytes 
[D] StreamCopy.h : 192 - available: 1966672
[D] StreamCopy.h : 384 - write: 1024
[I] AudioEncoded.h : 75 - virtual void audio_tools::EncodedAudioOutput::addNotifyAudioChange(audio_tools::AudioInfoSupport&)
[D] Allocator.h : 68 - Allocated 4
[D] AudioEncoded.h : 187 - EncodedAudioOutput::write: 1024
[D] CodecWAV.h : 323 - virtual size_t audio_tools::WAVDecoder::write(const uint8_t*, size_t)
[I] CodecWAV.h : 56 - WAVHeader::write: 1024 -> 44 -> 44
[I] CodecWAV.h : 63 - WAVHeader::begin: 44
[I] CodecWAV.h : 220 - WAVHeader sound_pos: 0
[I] CodecWAV.h : 221 - WAVHeader channels: 1 
[I] CodecWAV.h : 222 - WAVHeader bits_per_sample: 32
[I] CodecWAV.h : 223 - WAVHeader sample_rate: 48000 
[I] CodecWAV.h : 224 - WAVHeader format: 3
[I] CodecWAV.h : 420 - WAV sample_rate: 48000
[I] CodecWAV.h : 421 - WAV data_length: 0
[I] CodecWAV.h : 422 - WAV is_streamed: 0
[I] CodecWAV.h : 423 - WAV is_valid: true
[E] CodecWAV.h : 446 - WAV format not supported: 3
[D] I2SStream.h : 114 - I2SStream::write: 1024
[D] I2SESP32V1.h : 104 - size_t audio_tools::I2SDriverESP32V1::writeBytes(const void*, size_t)
[D] AudioEncoded.h : 199 - EncodedAudioOutput::write: 1024 -> 1024
[D] StreamCopy.h : 390 - write: 1024 -> 1024

This might be a completely different issue.

[pschatzmann]

Did you double check the header ?

[pschatzmann]

Maybe it is caused by this change ?
812b698

[jonascant]

I unfortunately deleted that file now. However, i made progress:
I recorded a new wave file with a sketch:

00000000: 5249 4646 1c00 ff7f 5741 5645 666d 7420  RIFF....WAVEfmt 
00000010: 1000 0000 0100 0100 80bb 0000 00ee 0200  ................
00000020: 0400 2000 6461 7461 2400 ff7f 0008 b0ff  .. .data$.......
00000030: 00b0 c4ff 0020 0000 0080 6400 00a8 2800  ..... ....d...(.

and the minimalistic playback sketch (above) does play it! So the last problem with the audacity file seems unrelated. There must be a problem with my original sketch. I will try to expand the minimalistic example until i can pinpoint the issue.

[pschatzmann]

Format 3 is IEEE_FLOAT = 0x0003, /* Microsoft Corporation */
You need to use PCM = 0x0001 !

[jonascant]

Got it!

[jonascant]

So i narrowed it down to the ConverterFillLeftAndRight object. The following sketch runs without any problems (only on one channel). BUT: As soon as the "filler" is added to the copier in the loop, the old Error occurs (Wav Format 0 not supported).
'''
#include "AudioTools.h"
#include <SD.h>
#include <SPI.h>

//Audio Setup
AudioInfo info(48000, 2, 32);

AudioInfo sd_info(48000, 1, 32);

I2SStream out;
I2SStream in;

VolumeMeter meter(in);
VolumeStream volume(out);

WAVDecoder wav;
EncodedAudioStream encoded(&volume, &wav); // Decoding stream

File file; // final output stream
EncodedAudioStream out2SD(&file, new WAVEncoder());
FormatConverterStream conv(out2SD);
const char* file_name = "/rec.wav";

MultiOutput multi_out;

StreamCopy copier;

ConverterFillLeftAndRight<int32_t> filler(RightIsEmpty); // fill both channels - or change to RightIsEmpty

// Arduino Setup
void setup(void) {
// Open Serial
Serial.begin(115200);

// change to Warning to improve the quality
AudioLogger::instance().begin(Serial, AudioLogger::Warning);

// start I2S out
auto config_out = out.defaultConfig(TX_MODE);
config_out.copyFrom(info);
config_out.port_no = 1;
config_out.pin_bck = 26;
config_out.pin_ws = 25;
config_out.pin_data = 22;

auto config_in = in.defaultConfig(RX_MODE);
config_in.copyFrom(info);
config_in.i2s_format = I2S_STD_FORMAT;
config_in.is_master = true;
// config_in.bits_per_sample = 32;
config_in.port_no = 0;
config_in.pin_bck = 14;
config_in.pin_ws = 27;
config_in.pin_data = 12;

auto configvol = volume.defaultConfig();
configvol.allow_boost = true;

multi_out.add(volume);
multi_out.add(conv);
multi_out.begin();

//Start I2S Devices
in.begin(config_in);
out2SD.begin(sd_info);
out.begin(config_out);

conv.begin(info, sd_info);
meter.begin(info);
volume.begin(configvol);

volume.setVolume(20.0);

// Open SD drive
if (!SD.begin(5)) {
Serial.println("Initialization failed!");
stop();
}
Serial.println("I2S started...");

record();
}
void record(){
//Start recording
Serial.println ("Starting to record");

// Cleanup if necessary
if (SD.exists(file_name))
SD.remove(file_name);

// open file
file = SD.open(file_name, FILE_WRITE);
if (!file){
Serial.println("file failed!");
stop();
}

copier.begin(multi_out,meter);
}

void play(){
//finish recording
if (file) {
file.flush();
Serial.print("File has ");
Serial.print(file.size());
Serial.println(" bytes");
file.close();
}

//open File to play
file = SD.open(file_name);
if (!file){
Serial.println("file failed!");
stop();
}

encoded.begin(info);

copier.begin(encoded, file);
}

bool playing = false;
// Arduino loop - copy sound to out
void loop() {
if(millis() > 5000 && !playing){
playing = true;
play();
}
copier.copy();
// This causes the Error ----> copier.copy(filler);
}
'''
So how can i get headphone output to both channels?

[jonascant]

I guess, i could disable the filler for file playback, and just playback on one channel as last resort. How does the filler interfere with the wav-header though?

[pschatzmann]

Using the filler when you play back is a big mistake: this changes the signal which also includes the header!
Use 2 separate copiers or a ConverterStream on the recording side only

[jonascant]

then how can i play the mono recording on both channels?

[pschatzmann]

e.g. with a ChannelFormatConverterStream or just record in stereo

[jonascant]

Awesome! Thank you! It wokrs. I got rid of the filler, changed the system to just one channel (to avoid allot of converting) and simply replaced the out with a ChannelFormatConverterStream stereoOut. Here is the sketch, should anyone be interested:

#include "AudioTools.h"
#include <SD.h>
#include <SPI.h>

//Audio Setup
AudioInfo info(48000, 1, 32);

AudioInfo stereo_info(48000, 2, 32);

I2SStream out; 
I2SStream in; 

VolumeMeter meter(in);
VolumeStream volume(out);

WAVDecoder wav;
EncodedAudioStream encoded(&volume, &wav); // Decoding stream

File file;  // final output stream
EncodedAudioStream out2SD(&file, new WAVEncoder());
//FormatConverterStream conv(out2SD);
ChannelFormatConverterStream stereoOut(volume);
//ChannelFormatConverterStream conv3(encoded);
const char* file_name = "/rec.wav";

MultiOutput multi_out;

StreamCopy copier; 

ConverterFillLeftAndRight<int32_t> filler(RightIsEmpty); // fill both channels - or change to RightIsEmpty

// Arduino Setup
void setup(void) { 
  // Open Serial 
  Serial.begin(115200);

  // change to Warning to improve the quality
  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // start I2S out
  auto config_out = out.defaultConfig(TX_MODE);
  config_out.copyFrom(stereo_info); 
  config_out.port_no = 1;
  config_out.pin_bck = 26;
  config_out.pin_ws = 25;
  config_out.pin_data = 22;

  auto config_in = in.defaultConfig(RX_MODE);
  config_in.copyFrom(info); 
  config_in.i2s_format = I2S_STD_FORMAT;
  config_in.is_master = true;
  // config_in.bits_per_sample = 32;
  config_in.port_no = 0;
  config_in.pin_bck = 14;
  config_in.pin_ws = 27;
  config_in.pin_data = 12;

  auto configvol = volume.defaultConfig();
  configvol.allow_boost = true; 

  stereoOut.begin(info, 2);

  multi_out.add(stereoOut);
  multi_out.add(out2SD);
  multi_out.begin();
  
  //Start I2S Devices
  in.begin(config_in);
  out2SD.begin(info);
  out.begin(config_out);

  //conv.begin(info, sd_info);
  //conv3.begin(info, 2);
  meter.begin(info);
  volume.begin(configvol);

  volume.setVolume(20.0); 

  // Open SD drive
  if (!SD.begin(5)) {
    Serial.println("Initialization failed!");
    stop();
  }
  Serial.println("I2S started...");

  record();
}
void record(){
  //Start recording
  Serial.println ("Starting to record");
      
  // Cleanup if necessary
  if (SD.exists(file_name))
    SD.remove(file_name);

  // open file
  file = SD.open(file_name, FILE_WRITE);
  if (!file){
    Serial.println("file failed!");
    stop();
  }

  copier.begin(multi_out,meter);
}


void play(){
  //finish recording
  if (file) {
    file.flush();
    Serial.print("File has ");
    Serial.print(file.size());
    Serial.println(" bytes");
    file.close();
  }

  //open File to play
  file = SD.open(file_name);
  if (!file){
    Serial.println("file failed!");
    stop();
  }

  encoded.begin(info);

  copier.begin(stereoOut, file);
}

bool playing = false;
// Arduino loop - copy sound to out 
void loop() {
  if(millis() > 5000 && !playing){
    playing = true;
    play();
  }
  copier.copy();
}