Playing an mp3 and generating sine waves in the same sketch

[fifex-ltd]

I have a sketch that plays an mp3 on the sucessful input of a code on the matrix keypad , along with this it plays a tone every time a key is pressed using the sine wave generator.
It all works but the tones are really quiet , I've tried the streams-generator-i2s example and that works well and is much louder
The volume setting is stored in a text file on the sd card so it can be changed by the user.
I'm using a ESP32 S3 on a custom pcb with a built in amp and i/o etc

my code is here -

#include <SPI.h>
#include <SD.h>
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"
#include <Keypad.h>

const int ledPin = 13;
const int stbyPin = 21;
#define VOLUME_FILE "/config/volume.txt"  // File to store volume

const byte ROWS = 4;
const byte COLS = 3;
char keys[ROWS][COLS] = {
  {'1', '2', '3'},
  {'4', '5', '6'},
  {'7', '8', '9'},
  {'*', '0', '#'}
};
byte rowPins[ROWS] = {8, 45, 46, 17};
byte colPins[COLS] = {16, 7, 18};
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

#define SCK  36
#define MISO  37
#define MOSI  35
#define CS  5

I2SStream i2s;
VolumeStream volume(i2s);
EncodedAudioStream decoder(&volume, new MP3DecoderHelix());
StreamCopy copier;
File audioFile;

// Sine wave generator
AudioInfo info(44100, 2, 16);
SineWaveGenerator<int16_t> sineWave(32000);
GeneratedSoundStream<int16_t> sound(sineWave);
StreamCopy soundCopier(i2s, sound);

String inputSequence = "";
const String correctSequence = "7636#";
float volumeLevel = 0.2; // Default volume (20%)

bool isI2SInitialized = false;

void startI2S() {
  if (!isI2SInitialized) {
    Serial.println("Starting I2S...");
    auto config = i2s.defaultConfig(TX_MODE);
    config.pin_ws = 39;
    config.pin_bck = 4;
    config.pin_data = 40;
    config.sample_rate = 44100;
    config.bits_per_sample = 16;
    config.channels = 2;

    i2s.begin(config);
    volume.begin(config);
    volume.setVolume(volumeLevel);
    isI2SInitialized = true;
  }
}

void stopTone() {
  Serial.println("Stopping tone...");
  sineWave.end();
}

void playMP3(const char* filename) {
  stopTone();  // Stop tone before playing MP3

  if (audioFile) audioFile.close();
  audioFile = SD.open(filename);

  if (!audioFile) {
    Serial.println("Failed to open MP3 file!");
    return;
  }

  Serial.println("MP3 file opened, starting playback...");
  startI2S();

  decoder.begin();
  copier.begin(decoder, audioFile);

  while (copier.copy()) {
    // Playing...
  }

  Serial.println("MP3 playback finished.");
  audioFile.close();
}

// Read volume from SD card
float loadVolumeFromSD() {
  Serial.println("Loading volume from SD...");
  if (!SD.exists(VOLUME_FILE)) {
    Serial.println("Volume file not found. Using default.");
    return volumeLevel;
  }

  File file = SD.open(VOLUME_FILE, FILE_READ);
  if (!file) {
    Serial.println("Failed to open volume file.");
    return volumeLevel;
  }

  String volString = file.readStringUntil('\n');
  file.close();
  
  float vol = volString.toFloat();
  if (vol < 0.0 || vol > 1.0) {
    Serial.println("Invalid volume value. Using default.");
    return volumeLevel;
  }

  Serial.print("Loaded volume: ");
  Serial.println(vol);
  return vol;
}

// Save volume to SD card
void saveVolumeToSD(float newVolume) {
  Serial.println("Saving volume to SD...");
  File file = SD.open(VOLUME_FILE, FILE_WRITE);
  if (!file) {
    Serial.println("Failed to open volume file for writing.");
    return;
  }
  file.println(newVolume, 2); // Save with 2 decimal places
  file.close();
  Serial.println("Volume saved.");
}

void setup() {
  Serial.begin(115200);
  while (!Serial);

  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Warning);

  pinMode(ledPin, OUTPUT);
  pinMode(stbyPin, OUTPUT);

  SPI.begin(SCK, MISO, MOSI, CS);

  Serial.println(" Initializing SD card...");
  if (!SD.begin(CS)) {
    Serial.println("SD card initialization failed!");
    return;
  }
  Serial.println("SD card initialized.");

  volumeLevel = loadVolumeFromSD(); // Load volume from file
  startI2S(); // Initialize I2S correctly
  sineWave.begin(info, N_B4);

  Serial.println("Setup Complete");
}

void playTone() {
  Serial.println("Playing tone...");
  unsigned long startTime = millis();
  while (millis() - startTime < 100) {
    soundCopier.copy();
  }
}

void loop() {
  char key = keypad.getKey();

  if (key) {
    Serial.print("Key Pressed: "); Serial.println(key);
    playTone(); // Play sine wave tone on keypress
    inputSequence += key;

    if (inputSequence.length() > correctSequence.length()) {
      inputSequence = inputSequence.substring(1);
    }

    if (inputSequence == correctSequence) {
      Serial.println("Correct sequence entered! Playing MP3...");
      digitalWrite(stbyPin, HIGH);
      digitalWrite(ledPin, LOW);
      playMP3("/Music/320k_test.mp3");
      digitalWrite(ledPin, HIGH);
      inputSequence = "";
    }
  }
}

Any ideas as to what Im doing wrong?

[pschatzmann]

I would not know: please follow the advice given in the Wiki!

[fifex-ltd]

problem solved , it was caused by the digitalWrite(stbyPin, HIGH); only being in the MP3 section