-
Notifications
You must be signed in to change notification settings - Fork 4
/
Copy pathcProvers.pro
174 lines (134 loc) · 3.24 KB
/
cProvers.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
% provers using embedded Horn Clauses or customized
% for also handling negation and classic proofs
% via Glivenko's translation from classical to intuitionistic
% propositional calculus
gprove(T0):-dneg_expand(T0,T),ljk(T).
dneg(X,((X->false)->false)).
dneg_expand(T0,T):-expand_neg(T0,T1),dneg(T1,T).
kprove(T0):-expand_neg(T0,T),ljk(T).
ljk(T):-ljk(T,[]),!.
ljk(_,Vs):-memberchk(false,Vs),!.
ljk(A,Vs):-memberchk(A,Vs),!.
ljk((A->B),Vs):-!,ljk(B,[A|Vs]).
ljk(G,Vs1):-
select((A->B),Vs1,Vs2),
ljk_imp(A,B,Vs2),
!,
ljk(G,[B|Vs2]).
ljk_imp((C->D),B,Vs):-!,ljk((C->D),[(D->B)|Vs]).
ljk_imp(A,_,Vs):-memberchk(A,Vs).
expand_neg(~A,R):-!,expand_neg(A,B),R=(B->false).
expand_neg((A->B),(X->Y)):-!,expand_neg(A,X),expand_neg(B,Y).
%expand_neg(f,false):-!.
expand_neg(A,R):-R=A.
% classicall logic propositional prover
% using Glivenko's double negation translation
% Glivenko's translation of a classical tautology
% is an intuitionistic tautology
cgprove(T0):-dneg(T0,T),cprove(T).
% handles also the atom "false" as a special case
% supports also negation seen as A->false
cprove(T0):-
expand_neg(T0,T),
ljc(T,[]),
!.
ljc(_,Vs):-memberchk(false,Vs),!.
ljc(A,Vs):-memberchk(A,Vs),!.
ljc((A->B),Vs):-!,ljc(B,[A|Vs]).
ljc(G,Vs1):- % atomic(G),
select((A->B),Vs1,Vs2),
ljc_imp(A,B,Vs2),
!,
ljc(G,[B|Vs2]).
ljc_imp((C->D),B,Vs):-!,ljc((C->D),[(D->B)|Vs]).
ljc_imp(A,_,Vs):-memberchk(A,Vs).
tprove(F):-toImp(F,I),dneg(I,NNI),kprove(NNI).
toImp(X,R):-atomic(X),!,R=X.
toImp((X->Y),(A->B)):-toImp(X,A),toImp(Y,B).
toImp(~(X),(A->false)):-toImp(X,A).
toImp(X*Y, ((A -> (B -> false))->false)):-
toImp(X,A),
toImp(Y,B).
toImp(X+Y, (A->false)->B) :-
toImp(X,A),
toImp(Y,B).
toImp(X=Y,R):-
toImp((X->Y)*(Y->X),R).
toImp(X^Y, R):-
toImp(~(X->Y) + ~(Y->X), R).
% simple evaluator / truth table generator
% for classic formulas
classEval(G):-
varvars(G,F),
term_variables(F,Vs),
evalT(F,R),
ppp(Vs:R),
fail.
taut(X):- \+ eval(X,0).
taut0(G):-must_be(ground,G),
varvars(G,X),
term_variables(X,Vs),
ppp(X:Vs),
evalT(X,R),
ppp(X:Vs=R),fail;true.
eval(G,R):-varvars(G,T),evalT(T,R).
evalT(X,X):-var(X),!,bit(X).
evalT(false,R):-!,R=0.
evalT(true,R):-!,R=1.
evalT(X,R):-integer(X),!,R=X.
evalT(~A,R):- evalT(A,X),neg(X,R).
evalT((A->B),R):-
evalT(A,X),
evalT(B,Y),
impl(X,Y,R).
evalT((A&B),R):-
evalT(A,X),
evalT(B,Y),
conj(X,Y,R).
evalT((A v B),R):-
evalT(A,X),
evalT(B,Y),
disj(X,Y,R).
evalT((A<->B),R):-
evalT(A,X),
evalT(B,Y),
equiv(X,Y,R).
evalT((A<-B),R):-
evalT(A,X),
evalT(B,Y),
rev_impl(X,Y,R).
neg(0,1).
neg(1,0).
impl(0,0,1).
impl(0,1,1).
impl(1,0,0).
impl(1,1,1).
conj(0,0,0).
conj(0,1,0).
conj(1,0,0).
conj(1,1,1).
disj(0,0,0).
disj(0,1,1).
disj(1,0,1).
disj(1,1,1).
equiv(0,0,1).
equiv(0,1,0).
equiv(1,0,0).
equiv(1,1,1).
rev_impl(0,0,1).
rev_impl(0,1,1).
rev_impl(1,0,0).
rev_impl(1,1,1).
bit(0).
bit(1).
% if taut succeeds -> all vars the same succeeds
% if all vars the same fails, tautology cannot succeed
fforce(A):-
flag(fval,_,0),force(A),
flag(fval,_,1),force(A).
force(A & B):-!,force(A),force(B).
force(~A):-!,\+force(A).
force(A->B):-!, (\+force(A);force(B)),!.
force(A v B):-!,force(~(~A & ~B)).
force(A <-> B):-!,force(A->B),force(B->A).
force(_):-flag(fval,X,X),X=1.