Basic map editor outliner

Missing a lot of features from the C++ version. WIll implement fully once map import and project serialization are working.

Author: Moneyl

src/Gui/Documents/MapEditorDocument.bf

@@ -22,6 +22,11 @@ namespace Nanoforge.Gui.Documents
         private StringView _loadFailureReason = .();
         public Territory Map = null;
         private Scene _scene = null;
+        private ZoneObject _selectedObject;
+        private Zone _selectedZone = null;
+
+        //Deepest tree level the outliner will draw. Need to limit to prevent accidental stack overflow
+        private const int MAX_OUTLINER_DEPTH = 7;
 
         public this(StringView mapName)
         {
@@ -180,7 +185,151 @@ namespace Nanoforge.Gui.Documents
 
         public override void Outliner(App app, Gui gui)
         {
+            if (Loading)
+            {
+                ImGui.Text("Map is loading...");
+                return;
+            }
+
+            //Set custom highlight colors for the table
+            Vec4<f32> selectedColor = .(0.157f, 0.350f, 0.588f, 1.0f);
+            Vec4<f32> highlightedColor = selectedColor * 1.1f;
+            ImGui.PushStyleColor(.Header, selectedColor);
+            ImGui.PushStyleColor(.HeaderHovered, highlightedColor);
+            ImGui.PushStyleColor(.HeaderActive, highlightedColor);
+            ImGui.TableFlags tableFlags = .ScrollY | .ScrollX | .RowBg | .BordersOuter | .BordersV | .Resizable | .Reorderable | .Hideable | .SizingFixedFit;
+            if (ImGui.BeginTable("ZoneObjectTable", 4, tableFlags))
+            {
+                ImGui.TableSetupScrollFreeze(0, 1);
+                ImGui.TableSetupColumn("Name");
+                ImGui.TableSetupColumn("Flags");
+                ImGui.TableSetupColumn("Num");
+                ImGui.TableSetupColumn("Handle");
+                ImGui.TableHeadersRow();
+
+                //Loop through visible zones
+                bool anyZoneHovered = false;
+                for (Zone zone in Map.Zones)
+                {
+                    ImGui.TableNextRow();
+                    ImGui.TableNextColumn();
+
+                    bool anyChildrenVisible = Outliner_ZoneAnyChildObjectsVisible(zone);
+                    if (!anyChildrenVisible)
+                        continue;
+
+                    bool selected = (zone == _selectedZone);
+                    ImGui.TreeNodeFlags nodeFlags = .SpanAvailWidth | (anyChildrenVisible ? .None : .Leaf);
+                    if (selected)
+                        nodeFlags |= .Selected;
+
+                    //Draw tree node for zones if there's > 1. Otherwise draw the objects at the root of the tree
+                    bool singleZone = Map.Zones.Count == 1;
+                    bool treeNodeOpen = false;
+                    if (!singleZone)
+                    {
+						treeNodeOpen = ImGui.TreeNodeEx(zone.Name.CStr(), nodeFlags);
+                    }
+
+                    if (singleZone || treeNodeOpen)
+                    {
+                        for (ZoneObject obj in zone.Objects)
+                        {
+                            //Don't draw objects with parents at the top of the tree. They'll be drawn as subnodes of their parent
+                            if (obj.Parent != null)
+                                continue;
+
+                            int depth = 0;
+                            Outliner_DrawObjectNode(obj, depth + 1);
+                        }
+                    }
+
+                    if (treeNodeOpen)
+	                    ImGui.TreePop();
+                }
+
+                ImGui.EndTable();
+            }
+
+            ImGui.PopStyleColor(3);
+        }
+
+        private bool Outliner_ZoneAnyChildObjectsVisible(Zone zone)
+        {
+            //TODO: Implement
+            return true;
+        }
+
+        private bool Outliner_ShowObjectOrChildren(ZoneObject obj)
+        {
+            //TODO: Implement
+            return true;
+        }
+
+        private void Outliner_DrawObjectNode(ZoneObject obj, int depth)
+        {
+            if (depth > MAX_OUTLINER_DEPTH)
+            {
+                ImGui.Text("Can't draw object! Hit outliner depth limit");
+                return;
+            }
+
+            bool show = Outliner_ShowObjectOrChildren(obj);
+            if (!show)
+                return;
+
+            bool selected = (obj == _selectedObject);
+            String label = scope .();
+            if (obj.GetName() case .Ok(let name))
+                label.Set(name);
+            else
+                label.Set(obj.Classname);
+
+            ImGui.TableNextRow();
+            ImGui.TableNextColumn();
 
+            bool hasChildren = obj.Children.Count > 0;
+            bool hasParent = obj.Parent != null;
+
+            //Draw node
+            ImGui.PushID(Internal.UnsafeCastToPtr(obj));
+            f32 nodeXPos = ImGui.GetCursorPosX();
+            bool nodeOpen = ImGui.TreeNodeEx(label.CStr(), .SpanAvailWidth | .OpenOnDoubleClick | .OpenOnArrow | (hasChildren ? .None : .Leaf) | (selected ? .Selected : .None));
+
+            if (ImGui.IsItemClicked())
+            {
+                if (obj == _selectedObject)
+                    _selectedObject = null;
+                else
+                    _selectedObject = obj;
+            }
+            if (ImGui.IsItemHovered())
+            {
+                ImGui.TooltipOnPrevious(obj.Classname);
+            }
+
+            //Flags
+            ImGui.TableNextColumn();
+            ImGui.Text(obj.Flags.ToString(.. scope .()));
+
+            //Num
+            ImGui.TableNextColumn();
+            ImGui.Text(obj.Num.ToString(.. scope .()));
+
+            //Handle
+            ImGui.TableNextColumn();
+            ImGui.Text(obj.Handle.ToString(.. scope .()));
+
+            //Draw child nodes
+            if (nodeOpen)
+            {
+                for (ZoneObject child in obj.Children)
+                {
+                    Outliner_DrawObjectNode(child, depth + 1);
+                }
+                ImGui.TreePop();
+            }
+            ImGui.PopID();
         }
 
         public override void Inspector(App app, Gui gui)

src/Gui/Panels/MainMenuBar.bf

@@ -191,7 +191,8 @@ namespace Nanoforge.Gui.Panels
             if (FirstDraw)
             {
                 ImGui.ID dockLeftId = ImGui.DockBuilderSplitNode(DockspaceId, .Left, 0.20f, var outIdLeft, out DockspaceId);
-                ImGui.ID dockRightId = ImGui.DockBuilderSplitNode(DockspaceId, .Right, 0.28f, var outIdRight, out DockspaceId);
+                ImGui.ID dockLeftBottomId = ImGui.DockBuilderSplitNode(dockLeftId, .Down, 0.5f, var outIdBottom, out dockLeftId);
+                //ImGui.ID dockRightId = ImGui.DockBuilderSplitNode(DockspaceId, .Right, 0.28f, var outIdRight, out DockspaceId);
                 //ImGui.ID dockRightUp = ImGui.DockBuilderSplitNode(dockRightId, .Up, 0.35f, var outIdRightUp, out dockRightId);
                 DockspaceCentralNodeId = ImGui.DockBuilderGetCentralNode(DockspaceId).ID;
                 ImGui.ID dockCentralDownSplitId = ImGui.DockBuilderSplitNode(DockspaceCentralNodeId, .Down, 0.20f, var outIdCentralDown, out DockspaceCentralNodeId);
@@ -202,7 +203,7 @@ namespace Nanoforge.Gui.Panels
                 ImGui.DockBuilderDockWindow("Dear ImGui Demo", dockLeftId);
                 ImGui.DockBuilderDockWindow(StateViewer.ID.Ptr, dockLeftId);
                 ImGui.DockBuilderDockWindow(gui.OutlinerIdentifier, dockLeftId);
-                ImGui.DockBuilderDockWindow(gui.InspectorIdentifier, dockRightId);
+                ImGui.DockBuilderDockWindow(gui.InspectorIdentifier, dockLeftBottomId);
                 ImGui.DockBuilderDockWindow("Log", dockCentralDownSplitId);
             }
         }