build.gradle

buildscript {
    repositories {
        jcenter()
        maven { url = "https://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'

def buildnumber = System.getenv('TRAVIS_BUILD_NUMBER')
def suffix = buildnumber != null ? ".$buildnumber" : "-SNAPSHOT"
version = "1.0.1$suffix"
group = "uk.bobbytables.arcfurnacepatch"
archivesBaseName = "arcfurnacepatch"
def displayName = "Arc Furnace Patch"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "1.12.2-14.23.5.2831"
    runDir = "run"
    
    mappings = "stable_39"
    makeObfSourceJar = false

    replaceIn "Reference.java"
    replace "@VERSION@", project.version
    replace "@MODID@", project.archivesBaseName
    replace "@MODNAME@", project.displayName

    def args = [
        '-Dfml.coreMods.load=uk.bobbytables.arcfurnacepatch.core.ArcFurnacePatchLoadingPlugin'
    ]

    clientJvmArgs.addAll(args)
    serverJvmArgs.addAll(args)
}

repositories {
    maven {
        url 'http://blamejared.com/maven'
    }
}

dependencies {
    deobfCompile 'blusunrize:ImmersiveEngineering:0.12-89-+'
}

jar {
    manifest.attributes(
            "FMLCorePluginContainsFMLMod": "true",
            "FMLCorePlugin": "uk.bobbytables.arcfurnacepatch.core.ArcFurnacePatchLoadingPlugin",
            "ForceLoadAsMod": "true"
    )
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version
    inputs.property "displayName", project.displayName
    inputs.property "id", project.archivesBaseName

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version, 'name':project.displayName, 'id':project.archivesBaseName
    }
        
    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}