pong.S

%define PAD_W 10
%define PAD_H 50
%define BALL_S 10
%define SCREEN_W 320
%define SCREEN_H 200
%define PAD_STEP 3

bits 16

mov ax, 0x07c0
mov ds, ax
mov ax, 0xa000
mov es, ax
mov ax, 0x07e0
mov ss, ax
mov sp, 0x2000

mov ah, 0x00
mov al, 0x13
int 0x10

start:
    mov ah, 0x00
    int 0x16

    mov ax, 0x00
    mov di, 0x00
    mov cx, SCREEN_W*SCREEN_H
    rep stosw

    mov [pad_y], byte 0
    mov [pad_y_last], byte 0
    mov [ball_x], word (SCREEN_W-BALL_S)/2
    mov [ball_y], byte (SCREEN_H-BALL_S)/2
    mov [ball_x_last], word 0
    mov [ball_y_last], byte 0
    mov [ball_velx], word -1
    mov [ball_vely], byte 1
    mov [pad_vel], byte 0

mainloop:
    mov ah, 0x86
    mov cx, 0x0
    mov dx, 0x2b67
    int 0x15

    mov bh, [pad_y]
    mov si, [ball_x]
    mov ch, [ball_y]
    mov di, [ball_velx]
    mov cl, [ball_vely]
    mov dl, [pad_vel]

    mov [pad_y_last], bh
    mov [ball_x_last], si
    mov [ball_y_last], ch

    cmp ch, 0
    jne _bot_bound
    mov cl, 1
    jmp _left_pad_bound
_bot_bound:
    cmp ch, SCREEN_H-BALL_S
    jne _left_pad_bound
    mov cl, -1

_left_pad_bound:
    cmp si, PAD_W
    ja _right_pad_bound
    cmp si, 0
    je start
    cmp bh, BALL_S/2
    ja _left_pad_ub_sub
    mov ah, 0x00
    jmp _left_pad_bb 
_left_pad_ub_sub:
    mov ah, bh
    sub ah, BALL_S/2
_left_pad_bb:
    mov dh, bh
    add dh, PAD_H+(BALL_S/2)
    cmp ch, ah
    jb _update_ball
    cmp ch, dh
    ja _update_ball
    mov di, 1
    jmp _collision_vel

_right_pad_bound:
    cmp si, SCREEN_W-PAD_W-BALL_S
    jb _update_ball
    cmp si, SCREEN_W-BALL_S
    je start
    cmp bh, BALL_S/2
    ja _right_pad_ub_sub
    mov ah, 0x00
    jmp _right_pad_bb 
_right_pad_ub_sub:
    mov ah, bh
    sub ah, BALL_S/2
_right_pad_bb:
    mov dh, bh
    add dh, PAD_H+(BALL_S/2)
    cmp ch, ah
    jb _update_ball
    cmp ch, dh
    ja _update_ball
    mov di, -1

_collision_vel:
    cmp dl, 0
    je _update_ball
    mov cl, dl

_update_ball:
    add si, di
    add ch, cl

_input:
    mov ah, 0x01
    int 0x16
    jz _move_none
    mov ah, 0x00
    int 0x16

    cmp ah, 0x48
    jne _move_down
    cmp bh, PAD_STEP
    ja _move_up_valid
    mov bh, 0x00
    jmp _move_up_do
_move_up_valid:
    sub bh, PAD_STEP
_move_up_do:
    mov dl, -1
    jmp _update_end

_move_down:
    cmp ah, 0x50
    jne _move_none
    cmp bh, SCREEN_H-PAD_H-PAD_STEP
    jb _move_down_valid
    mov bh, SCREEN_H-PAD_H
    jmp _move_down_do
_move_down_valid:
    add bh, PAD_STEP
_move_down_do:
    mov dl, 1
    jmp _update_end

_move_none:
    mov dl, 0

_update_end:
    mov [pad_y], bh
    mov [ball_x], si
    mov [ball_y], ch
    mov [ball_velx], di
    mov [ball_vely], cl
    mov [pad_vel], dl

    mov si, 0x00
    mov bh, [pad_y_last]
    mov ah, PAD_W
    mov bl, PAD_H
    mov al, 0x00
    call draw_rect

    mov si, 0x00
    mov bh, [pad_y]
    mov ah, PAD_W
    mov bl, PAD_H
    mov al, 0x02
    call draw_rect

    mov si, SCREEN_W-PAD_W
    mov bh, [pad_y_last]
    mov ah, PAD_W
    mov bl, PAD_H
    mov al, 0x00
    call draw_rect

    mov si, SCREEN_W-PAD_W
    mov bh, [pad_y]
    mov ah, PAD_W
    mov bl, PAD_H
    mov al, 0x02
    call draw_rect

    mov si, (SCREEN_W-PAD_W)/2
    mov bh, 0x00
    mov ah, PAD_W
    mov bl, SCREEN_H
    mov al, 0x08
    call draw_rect

    mov si, [ball_x_last]
    mov bh, [ball_y_last]
    mov ah, BALL_S
    mov bl, BALL_S
    mov al, 0x00
    call draw_rect

    mov si, [ball_x]
    mov bh, [ball_y]
    mov ah, BALL_S
    mov bl, BALL_S
    mov al, 0x0e
    call draw_rect

    jmp mainloop

cli
hlt

;x:si, y:bh, w:ah h:bl, color: al
draw_rect:
    mov di, ax
    mov ax, SCREEN_W
    mov dh, 0x00
    mov dl, bh
    mul dx
    add ax, si
    xor ax, di
    xor di, ax
    xor ax, di
    mov ch, 0x00
    mov cl, ah
    rep stosb
    inc bh
    dec bl
    cmp bl, 0
    jne draw_rect
    ret

pad_y db 0x5a
pad_y_last db 0
ball_x dw (SCREEN_W-BALL_S)/2
ball_y db (SCREEN_H-BALL_S)/2
ball_x_last dw 0
ball_y_last db 0
ball_velx dw -1
ball_vely db 1
pad_vel db 0

times 510-($-$$) db 0
dw 0xAA55