Add setVal function and example.

Author: nseidle

examples/ZED-F9P/Example6_GetVal/Example6_GetVal.ino

@@ -0,0 +1,86 @@
+/*
+  Send UBX binary commands to enable RTCM sentences on Ublox ZED-F9P module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: January 9th, 2019
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  Ublox changed how to configure their modules in 2019. As of version 23 of the UBX protocol the
+  UBX-CFG commands are deprecated; they still work, they just recommend using VALSET, VALGET, and VALDEL
+  commands instead. This example shows how to use this new command structure.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GPS and a RedBoard Qwiic or BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GPS
+
+#include "SparkFun_Ublox_Arduino_Library.h" //http://librarymanager/All#SparkFun_Ublox_GPS
+SFE_UBLOX_GPS myGPS;
+
+long lastTime = 0; //Simple local timer. Limits amount if I2C traffic to Ublox module.
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("Ublox getVal example");
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGPS.begin() == false) //Connect to the Ublox module using Wire port
+  {
+    Serial.println(F("Ublox GPS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  myGPS.enableDebugging(); //Enable debug messages over Serial (default)
+  //myGPS.enableDebugging(SerialUSB); //Enable debug messages over Serial USB
+
+  uint8_t currentI2Caddress = myGPS.getVal8(0x20510001);
+  Serial.print("Current I2C address (should be 0x42): 0x");
+  Serial.println(currentI2Caddress >> 1, HEX); //Ublox module returns a shifted 8-bit address. Make it 7-bit unshifted.
+
+  while(1);
+
+}
+
+void loop()
+{
+  //Query module only every second. Doing it more often will just cause I2C traffic.
+  //The module only responds when a new position is available
+  if (millis() - lastTime > 1000)
+  {
+    lastTime = millis(); //Update the timer
+
+    long latitude = myGPS.getLatitude();
+    Serial.print(F("Lat: "));
+    Serial.print(latitude);
+
+    long longitude = myGPS.getLongitude();
+    Serial.print(F(" Long: "));
+    Serial.print(longitude);
+    Serial.print(F(" (degrees * 10^-7)"));
+
+    long altitude = myGPS.getAltitude();
+    Serial.print(F(" Alt: "));
+    Serial.print(altitude);
+    Serial.print(F(" (mm)"));
+
+    byte SIV = myGPS.getSIV();
+    Serial.print(F(" SIV: "));
+    Serial.print(SIV);
+
+    Serial.println();
+  }
+}

examples/ZED-F9P/Example7_SetVal/Example7_SetVal.ino

@@ -0,0 +1,75 @@
+/*
+  Send UBX binary commands to enable RTCM sentences on Ublox ZED-F9P module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: January 9th, 2019
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  Ublox changed how to configure their modules in 2019. As of version 23 of the UBX protocol the
+  UBX-CFG commands are deprecated; they still work, they just recommend using VALSET, VALGET, and VALDEL
+  commands instead. This example shows how to use this new command structure.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GPS and a RedBoard Qwiic or BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GPS
+
+#include "SparkFun_Ublox_Arduino_Library.h" //http://librarymanager/All#SparkFun_Ublox_GPS
+SFE_UBLOX_GPS myGPS;
+
+long lastTime = 0; //Simple local timer. Limits amount if I2C traffic to Ublox module.
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("Ublox getVal example");
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGPS.begin() == false) //Connect to the Ublox module using Wire port
+  {
+    Serial.println(F("Ublox GPS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  myGPS.enableDebugging(); //Enable debug messages over Serial (default)
+  //myGPS.enableDebugging(SerialUSB); //Enable debug messages over Serial USB
+
+  bool setValueSuccess;
+
+  //These key values are hard coded. You can obtain them from the ZED-F9P interface description doc
+  //or from u-center's Messages->CFG->VALSET window. Keys must be 32-bit.
+  //setValueSuccess = myGPS.setVal(0x10930006, 0); //Enable high precision NMEA
+  setValueSuccess = myGPS.setVal(0x30210001, 100); //Set measurement rate to 100ms (10Hz update rate)
+  //setValueSuccess = myGPS.setVal(0x30210001, 1000); //Set measurement rate to 1000ms (1Hz update rate)
+
+  //Below is the original way we enabled the RTCM message on the I2C port. After that, we show how to do the same
+  //but with setVal().
+  //myGPS.enableRTCMmessage(UBX_RTCM_1005, COM_PORT_I2C, 1); //Enable message 1005 to output through I2C port, message every second
+  //setValueSuccess = myGPS.setVal(0x209102bd, 1); //Set output rate of msg 1005 over the I2C port to once per second
+
+  if(setValueSuccess == true)
+  {
+    Serial.println("Value was successfully set");
+  }
+  else
+    Serial.println("Value set failed");
+    
+}
+
+void loop()
+{
+
+}

keywords.txt

@@ -62,6 +62,7 @@ setUSBOutput	KEYWORD2
 setSPIOutput	KEYWORD2
 
 getVal8	KEYWORD2
+setVal  KEYWORD2
 
 getSurveyMode	KEYWORD2
 setSurveyMode	KEYWORD2

src/SparkFun_Ublox_Arduino_Library.cpp

@@ -876,6 +876,42 @@ uint8_t SFE_UBLOX_GPS::getVal8(uint32_t key, uint8_t layer, uint16_t maxWait)
   return (extractByte(8));
 }
 
+//Given a key, set an 8-bit value
+//This function takes a full 32-bit key
+//Default layer is BBR
+//Configuration of modern Ublox modules is now done via getVal/setVal/delVal, ie protocol v27 and above found on ZED-F9P
+uint8_t SFE_UBLOX_GPS::setVal(uint32_t key, uint16_t value, uint8_t layer, uint16_t maxWait)
+{
+  packetCfg.cls = UBX_CLASS_CFG;
+  packetCfg.id = UBX_CFG_VALSET;
+  packetCfg.len = 4 + 4 + 2; //4 byte header, 4 byte key ID, 2 bytes of value
+  packetCfg.startingSpot = 0;
+
+  //Clear packet payload
+  for (uint8_t x = 0; x < packetCfg.len; x++)
+    packetCfg.payload[x] = 0;
+
+  payloadCfg[0] = 0;     //Message Version - set to 0
+  payloadCfg[1] = layer; //By default we ask for the BBR layer
+
+  //Load key into outgoing payload
+  payloadCfg[4] = key >> 8 * 0; //Key LSB
+  payloadCfg[5] = key >> 8 * 1;
+  payloadCfg[6] = key >> 8 * 2;
+  payloadCfg[7] = key >> 8 * 3;
+
+  //Load user's value
+  payloadCfg[8] = value >> 8 * 0; //Value LSB
+  payloadCfg[9] = value >> 8 * 1;
+
+  //Send VALSET command with this key and value
+  if (sendCommand(packetCfg, maxWait) == false)
+    return (false); //If command send fails then bail
+
+  //All done
+  return (true);
+}
+
 //Get the current TimeMode3 settings - these contain survey in statuses
 boolean SFE_UBLOX_GPS::getSurveyMode(uint16_t maxWait)
 {

src/SparkFun_Ublox_Arduino_Library.h

@@ -249,6 +249,7 @@ class SFE_UBLOX_GPS
 	//General configuration (used only on protocol v27 and higher - ie, ZED-F9P)
 	uint8_t getVal8(uint16_t group, uint16_t id, uint8_t size, uint8_t layer = VAL_LAYER_BBR, uint16_t maxWait = 250); //Returns the value at a given group/id/size location
 	uint8_t getVal8(uint32_t keyID, uint8_t layer = VAL_LAYER_BBR, uint16_t maxWait = 250);														 //Returns the value at a given group/id/size location
+	uint8_t setVal(uint32_t keyID, uint16_t value, uint8_t layer = VAL_LAYER_BBR, uint16_t maxWait = 250);						 //Returns the value at a given group/id/size location
 
 	//Functions used for RTK and base station setup
 	boolean getSurveyMode(uint16_t maxWait = 250);																																 //Get the current TimeMode3 settings