Adding support for RELPOS. See issue 11.

Author: nseidle

examples/ZED-F9P/Example5_RelativePositioningInformation/Example5_RelativePositioningInformation.ino

@@ -0,0 +1,111 @@
+/*
+  Send UBX binary commands to enable RTCM sentences on Ublox ZED-F9P module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: January 9th, 2019
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example shows how to query the module for RELPOS information in the NED frame.
+  It assumes you already have RTCM correction data being fed to the receiver.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GPS and a RedBoard Qwiic or BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GPS
+
+#include "SparkFun_Ublox_Arduino_Library.h" //http://librarymanager/All#SparkFun_Ublox_GPS
+SFE_UBLOX_GPS myGPS;
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("Ublox Base station example");
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGPS.begin() == false) //Connect to the Ublox module using Wire port
+  {
+    Serial.println(F("Ublox GPS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+}
+
+void loop()
+{
+  if (myGPS.getRELPOSNED() == true)
+  {
+    Serial.print("relPosN: ");
+    Serial.println(myGPS.relPosInfo.relPosN, 4);
+    Serial.print("relPosE: ");
+    Serial.println(myGPS.relPosInfo.relPosE, 4);
+    Serial.print("relPosD: ");
+    Serial.println(myGPS.relPosInfo.relPosD, 4);
+
+    Serial.print("accN: ");
+    Serial.println(myGPS.relPosInfo.accN, 4);
+    Serial.print("accE: ");
+    Serial.println(myGPS.relPosInfo.accE, 4);
+    Serial.print("accD: ");
+    Serial.println(myGPS.relPosInfo.accD, 4);
+
+    Serial.print("gnssFixOk: ");
+    if (myGPS.relPosInfo.gnssFixOk == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("diffSolution: ");
+    if (myGPS.relPosInfo.diffSoln == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("relPosValid: ");
+    if (myGPS.relPosInfo.relPosValid == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("carrier Solution Type: ");
+    if (myGPS.relPosInfo.carrSoln == 0)
+      Serial.println("None");
+    else if (myGPS.relPosInfo.carrSoln == 1)
+      Serial.println("Float");
+    else if (myGPS.relPosInfo.carrSoln == 2)
+      Serial.println("Fixed");
+
+    Serial.print("isMoving: ");
+    if (myGPS.relPosInfo.isMoving == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("refPosMiss: ");
+    if (myGPS.relPosInfo.refPosMiss == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("refObsMiss: ");
+    if (myGPS.relPosInfo.refObsMiss == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+  }
+  else
+    Serial.println("RELPOS request failed");
+
+  delay(4000);
+}

src/SparkFun_Ublox_Arduino_Library.cpp

@@ -1354,8 +1354,42 @@ boolean SFE_UBLOX_GPS::getRELPOSNED(uint16_t maxWait)
     return (false); //If command send fails then bail
 
   //We got a response, now parse the bits
-  Serial.print("RELPOSNED: 0x");
-  Serial.println(payloadCfg[38], HEX);
+
+  uint16_t refStationID = extractInt(2);
+  Serial.print("refStationID: ");
+  Serial.println(refStationID);
+
+  int32_t tempRelPos;
+
+  tempRelPos = extractLong(8);
+  relPosInfo.relPosN = tempRelPos / 100.0; //Convert cm to m
+
+  tempRelPos = extractLong(12);
+  relPosInfo.relPosE = tempRelPos / 100.0; //Convert cm to m
+
+  tempRelPos = extractLong(16);
+  relPosInfo.relPosD = tempRelPos / 100.0; //Convert cm to m
+
+  uint32_t tempAcc;
+
+  tempAcc = extractLong(24);
+  relPosInfo.accN = tempAcc / 10000.0; //Convert 0.1 mm to m
+
+  tempAcc = extractLong(28);
+  relPosInfo.accE = tempAcc / 10000.0; //Convert 0.1 mm to m
+
+  tempAcc = extractLong(32);
+  relPosInfo.accD = tempAcc / 10000.0; //Convert 0.1 mm to m
+
+  uint8_t flags = payloadCfg[36];
+
+  relPosInfo.gnssFixOk = flags & (1 << 0);
+  relPosInfo.diffSoln = flags & (1 << 1);
+  relPosInfo.relPosValid = flags & (1 << 2);
+  relPosInfo.carrSoln = (flags & (0b11 << 3)) >> 3;
+  relPosInfo.isMoving = flags & (1 << 5);
+  relPosInfo.refPosMiss = flags & (1 << 6);
+  relPosInfo.refObsMiss = flags & (1 << 7);
 
   return (true);
 }

src/SparkFun_Ublox_Arduino_Library.h

@@ -279,6 +279,27 @@ class SFE_UBLOX_GPS
 		float meanAccuracy;
 	} svin;
 
+	//Relative Positioning Info in NED frame specific controls
+	struct frelPosInfoStructure
+	{
+		uint16_t refStationID;
+
+		float relPosN;
+		float relPosE;
+		float relPosD;
+		float accN;
+		float accE;
+		float accD;
+
+		bool gnssFixOk;
+		bool diffSoln;
+		bool relPosValid;
+		uint8_t carrSoln;
+		bool isMoving;
+		bool refPosMiss;
+		bool refObsMiss;
+	} relPosInfo;
+
 	//The major datums we want to globally store
 	int32_t latitude;				 //Degrees * 10^-7 (more accurate than floats)
 	int32_t longitude;			 //Degrees * 10^-7 (more accurate than floats)