build.gradle

buildscript {
	repositories {
		mavenCentral()
		jcenter()
	}
	dependencies {
		classpath 'com.google.protobuf:protobuf-gradle-plugin:0.7.4'
	}
}

apply plugin: 'java'
apply plugin: 'com.google.protobuf'
apply plugin: 'application'

startScripts.enabled = false
run.enabled = true
mainClassName = 'com.github.srderson.hyperledger_fabric_utxo_client_java.App'

repositories {
	mavenCentral()
	jcenter()
	mavenLocal()
	maven { url "http://oss.sonatype.org/content/repositories/snapshots" }
}

sourceSets {
	main {
		java {
			srcDir 'src/main/java'
		}
		proto {
			srcDir 'src/main/proto'
		}
	}
}

protobuf {
	generatedFilesBaseDir = "$projectDir/src"
	protoc {
		artifact = "com.google.protobuf:protoc:3.0.0-beta-2"
	}
	plugins {
		grpc {
			artifact = 'io.grpc:protoc-gen-grpc-java:0.12.0'
		}
	}
	generateProtoTasks {
		all().each { task ->
			task.builtins {
				java {
					outputSubDir = 'grpc'
				}
			}
		}
		all()*.plugins {
			grpc {}
		}
	}
}

dependencies {
	compile 'com.google.protobuf:protobuf-java:3.0.0-beta-2'
	compile 'io.grpc:grpc-all:0.13.1'
}