build.gradle

plugins {
    id "org.jetbrains.kotlin.jvm" version "1.3.20"
    id "edu.wpi.first.GradleRIO" version "2019.3.2"
    id "idea"
}

def ROBOT_MAIN_CLASS = "org.team5499.frc2019.Main"

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project EmbeddedTools.
deploy {
    targets {
        roboRIO("roborio") {
            // Team number is loaded either from the .wpilib/wpilib_preferences.json
            // or from command line. If not found an exception will be thrown.
            // You can use getTeamOrDefault(team) instead of getTeamNumber if you
            // want to store a team number in this file.
            team = frc.getTeamNumber()
        }
    }
    artifacts {
        // We still use FRCJavaArtifact since kotlin does respond as a Java build.
        frcJavaArtifact('frcKotlin') {
            targets << "roborio"
            // Debug can be overridden by command line, for use with VSCode
            debug = frc.getDebugOrDefault(false)
        }
        // Built in artifact to deploy arbitrary files to the roboRIO.
        fileTreeArtifact('frcStaticFileDeploy') {
            // The directory below is the local directory to deploy
            files = fileTree(dir: 'src/main/deploy')
            // Deploy to RoboRIO target, into /home/lvuser/deploy
            targets << "roborio"
            directory = '/home/lvuser/deploy'
        }
    }
}

// Set this to true to enable desktop support.
def includeDesktopSupport = true

// Maven central needed for JUnit
repositories {
    mavenLocal()
    mavenCentral()
    maven {
        url 'https://maven.team5499.org'
    }
    maven {
        url "http://devsite.ctr-electronics.com/maven/release/"
    }
    maven {
        url "https://repo1.maven.org/maven2/"
    }
}

// Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
// Also defines JUnit 4.
dependencies {
    // We need to add the Kotlin stdlib in order to use most Kotlin language features.
    compile 'org.jetbrains.kotlin:kotlin-stdlib:1.3.20'

    compile 'org.team5499:monkey-lib:2.10.4'
    compile 'org.team5499:forest:0.12.3'

    compile 'org.tinylog:tinylog-api:2.0.0-M3'
    compile 'org.tinylog:tinylog-impl:2.0.0-M3'

    // wpilib specific
    compile wpi.deps.wpilib()
    compile wpi.deps.vendor.java()
    nativeZip wpi.deps.vendor.jni(wpi.platforms.roborio)
    nativeDesktopZip wpi.deps.vendor.jni(wpi.platforms.desktop)

    // test framework = JUnit5
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.1.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.1.1'
}

// Setting up my Jar File. In this case, adding all libraries into the main jar ('fat jar')
// in order to make them all available at runtime. Also adding the manifest so WPILib
// knows where to look for our Robot Class.
jar {
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    manifest edu.wpi.first.gradlerio.GradleRIOPlugin.javaManifest(ROBOT_MAIN_CLASS)
}

test {
    dependsOn 'cleanTest'

    useJUnitPlatform()

    testLogging {
        events 'PASSED', 'FAILED', 'SKIPPED'
        showStandardStreams true
    }

    afterSuite { desc, result ->
        if (!desc.parent) {
            println "\nTest result: ${result.resultType}"
            println "Test summary: ${result.testCount} tests, " +
                    "${result.successfulTestCount} succeeded, " +
                    "${result.failedTestCount} failed, " +
                    "${result.skippedTestCount} skipped"
        }
    }

    finalizedBy 'tox'
}

task tox {
    doLast {
        exec {
            executable 'tox'
        }
    }
}

task install_hooks(dependsOn: 'tox')

compileTestJava {
    sourceCompatibility = 1.11
    targetCompatibility = 1.11
    options.compilerArgs += '-parameters'
}