Merge pull request #461 from susliko/tags-queries

feat: Add tags.scm queries

Author: susliko

.gitignore

@@ -38,3 +38,11 @@ dist/
 *.tar.gz
 *.tgz
 *.zip
+
+# Scala tooling
+.metals
+.bsp
+.scala-build
+
+# AI assistants
+.aider*

queries/tags.scm

@@ -0,0 +1,66 @@
+; Definitions
+
+(package_clause
+  name: (package_identifier) @name) @definition.module
+
+(trait_definition
+  name: (identifier) @name) @definition.interface
+
+(enum_definition
+  name: (identifier) @name) @definition.enum
+
+(simple_enum_case
+  name: (identifier) @name) @definition.class
+
+(full_enum_case
+  name: (identifier) @name) @definition.class
+
+(class_definition
+  name: (identifier) @name) @definition.class
+
+(object_definition
+  name: (identifier) @name) @definition.object
+
+(function_definition
+  name: (identifier) @name) @definition.function
+
+(val_definition
+  pattern: (identifier) @name) @definition.variable
+
+(given_definition
+  name: (identifier) @name) @definition.variable
+
+(var_definition
+  pattern: (identifier) @name) @definition.variable
+
+(val_declaration
+  name: (identifier) @name) @definition.variable
+
+(var_declaration
+  name: (identifier) @name) @definition.variable
+
+(type_definition
+  name: (type_identifier) @name) @definition.type
+
+(class_parameter
+  name: (identifier) @name) @definition.property
+
+; References 
+
+(call_expression
+  (identifier) @name) @reference.call
+
+(instance_expression
+  (type_identifier) @name) @reference.interface
+
+(instance_expression
+  (generic_type
+    (type_identifier) @name)) @reference.interface
+
+(extends_clause
+  (type_identifier) @name) @reference.class
+
+(extends_clause
+  (generic_type
+    (type_identifier) @name)) @reference.class
+

test/tags/basics.scala

@@ -0,0 +1,44 @@
+package com.example
+//      ^definition.module
+
+enum Color:
+//   ^definition.enum
+  case Red
+  //   ^definition.class
+  case Green
+  //   ^definition.class
+  case Yellow
+  //   ^definition.class
+
+trait Fruit:
+//    ^definition.interface
+  val color: Color
+//    ^definition.variable
+
+object Fruit:
+//     ^definition.object
+  case object Banana extends Fruit {
+  //          ^definition.object
+  //                         ^reference.class
+    val color = Color.Yellow
+    //  ^definition.variable
+  }
+  case class Apple(c: Color.Red | Color.Green) extends Fruit {
+  //         ^definition.class
+  //               ^definition.property
+  //                                                   ^reference.class
+    val color = c
+  //    ^definition.variable
+  }
+
+  given show: Show[Fruit] = new Show[Fruit] {  }
+  //    ^definition.variable
+  //                            ^reference.interface
+
+  def color(fruit: Fruit): String = ???
+  //  ^definition.function
+
+  var flag: Boolean = true
+  //  ^definition.variable
+
+

tree-sitter.json

@@ -10,7 +10,8 @@
         "sbt"
       ],
       "highlights": "queries/highlights.scm",
-      "locals": "queries/locals.scm"
+      "locals": "queries/locals.scm",
+      "tags": "queries/tags.scm"
     }
   ],
   "metadata": {