build.gradle

plugins {
    id 'com.android.application'
}

android {
    namespace 'com.urbanairship.sample'

    compileSdk rootProject.compileSdkVersion

    defaultConfig {
        applicationId "com.urbanairship.sample"
        minSdk rootProject.minSdkVersion
        targetSdk rootProject.targetSdkVersion
        versionCode 1
        versionName "1.0"
        vectorDrawables.useSupportLibrary = true
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    buildFeatures {
        dataBinding = true
    }

    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt')
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    lint {
        abortOnError false
        disable 'MissingTranslation', 'AppCompatResource'
    }
}

dependencies {
    implementation(libs.androidx.appcompat)
    implementation(libs.google.material)
    implementation(libs.androidx.preference)
    implementation(libs.androidx.lifecycle.viewmodel)
    implementation(libs.androidx.lifecycle.viewmodelktx)
    implementation(libs.androidx.constraintlayout)
    implementation(libs.androidx.navigation.fragment)
    implementation(libs.androidx.navigation.ui)
    implementation(libs.playservices.instantapps)
    implementation(libs.playservices.location)

    // Airship ADM
    implementation project(':urbanairship-adm')

    // Airship FCM
    implementation project(':urbanairship-fcm')

    // Airship Advertising ID tracking
    implementation project(':urbanairship-ads-identifier')

    // Airship Preferences
    implementation project(':urbanairship-preference')

    // Airship Message Center
    implementation project(':urbanairship-message-center')

    // Airship Automation (In-App)
    implementation project(':urbanairship-automation')

    // Airship Live Updates
    implementation project(':urbanairship-live-update')

    // Airship Debug: Normally this is a debug only dependency but we embed the view in sample app
    implementation project(':urbanairship-debug')

    // Testing-only dependencies

    // Espresso
    androidTestImplementation(libs.androidx.test.espresso.core)
    androidTestImplementation(libs.androidx.test.espresso.contrib) {
        // https://github.com/android/android-test/issues/861
        exclude group: 'org.checkerframework', module: 'checker'
    }
    androidTestImplementation(libs.androidx.test.espresso.web)
    androidTestImplementation(libs.androidx.test.espresso.intents)
    androidTestImplementation(libs.androidx.test.espresso.idling.concurrent)

    // AndroidJUnitRunner and JUnit Rules
    androidTestImplementation(libs.androidx.test.core)
    androidTestImplementation(libs.androidx.test.runner)
    androidTestImplementation(libs.androidx.test.rules)
    androidTestImplementation(libs.androidx.test.ext.junit)

    // Assertions
    androidTestImplementation(libs.google.truth)
    androidTestImplementation(libs.androidx.test.ext.truth)

    // Robolectric / Mockito
    testImplementation(libs.robolectric.core)
    androidTestImplementation(libs.robolectric.annotations)
    androidTestImplementation(libs.mockito.core)
    androidTestImplementation(libs.mockito.android)

    androidTestImplementation(libs.androidx.navigation.testing)
    debugImplementation(libs.androidx.fragment.testing)
}


def googleServicesFile = rootProject.file('sample/google-services.json')
if (googleServicesFile.exists()) {
    apply plugin: 'com.google.gms.google-services'  // Google Play services Gradle plugin
}