Portaudio lib on macOS : incompatible function pointer types

[AudioNiceMicroController]

Hello,

I try to listen 440hz with this code bellow and I get an error.

Thanks for your help....

The code

module main
import math
import time

#flag -L/opt/homebrew/Cellar/portaudio/19.7.0/lib
#flag -lportaudio
#flag -I/opt/homebrew/Cellar/portaudio/19.7.0/include

#include <stdio.h>
#include <portaudio.h>

const two_pi          = 6.283185307179586
const sample_rate     = 44100
const frames_per_buf  = 64
const nb_channels     = 1
const pa_int16        = 0x00000008
const pa_no_error     = 0

struct ToneData {
    mut:
    phase     f32
    frequency f32
}

// Define PortAudio structures
struct C.PaStreamCallbackTimeInfo {
    input_buffer_adc_time f64
    current_time f64
    output_buffer_dac_time f64
}
fn C.Pa_Initialize() int
fn C.Pa_Terminate()
fn C.Pa_GetErrorText(err int) &char
fn C.Pa_StartStream(stream voidptr) int
fn C.Pa_StopStream(stream voidptr) int
fn C.Pa_CloseStream(stream voidptr) int
fn C.Pa_Sleep(msecs int)
fn C.Pa_OpenDefaultStream(
    stream_ptr &voidptr,
    num_input_channels int,
    num_output_channels int,
    sample_format u64,
    sample_rate f64,
    frames_per_buffer u64,
    stream_callback voidptr,
    user_data voidptr
)int


fn audio_callback( input voidptr, output voidptr, frame_count u64, time_info &C.PaStreamCallbackTimeInfo, status_flags u64, user_data voidptr) int {
    mut data := unsafe { &ToneData(user_data) }
    out := &i16(output)

    for i := 0; i < int(frame_count); i++ {
        sample := f32(math.sin(f64(data.phase)) * 32767)
        unsafe {
            out[i] = i16(sample)
        }
        data.phase += f32(two_pi * f64(data.frequency) / sample_rate)
        if data.phase > f32(two_pi) {
            data.phase -= f32(two_pi)
        }
    }
    return 0 // paContinue
}

fn main() {
    mut data := ToneData{
        phase: 0
        frequency: 440
    }

    // Initialiser PortAudio
    mut err := C.Pa_Initialize()
    if err != pa_no_error {
        println('Error Pa_Initialize: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        return
    }
    mut stream := voidptr(0)

    // Ouvrir le flux audio
    err = C.Pa_OpenDefaultStream(&stream, 0, nb_channels, pa_int16, sample_rate,
                                 frames_per_buf, &audio_callback, &data)
    if err != pa_no_error {
        println('Erreur Pa_OpenDefaultStream: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        C.Pa_Terminate()
        return
    }

    err = C.Pa_StartStream(stream)
    if err != pa_no_error {
        println('Error Pa_StartStream: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        C.Pa_Terminate()
        return
    }

    println('PLay a sound of ${int(data.frequency)} Hz...')
    time.sleep(5 * time.second) // joue 5 secondes

    C.Pa_StopStream(stream)
    C.Pa_CloseStream(stream)
    C.Pa_Terminate()
}
/* RUN Vlang PROGRAM

v run 440hz.v

*/

The error

% v run 440hz.v
================== C compilation error (from cc): ==============
cc: /tmp/v_501/440hz.01JYFHDASMNK58NDXRQM2DWTQY.tmp.c:7468:145: error: incompatible function pointer types passing 'int (*)(voidptr, voidptr, u64, struct PaStreamCallbackTimeInfo *, u64, voidptr)' (aka 'int (*)(void *, void *, unsigned long long, struct PaStreamCallbackTimeInfo *, unsigned long long, void *)') to parameter of type 'PaStreamCallback *' (aka 'int (*)(const void *, void *, unsigned long, const struct PaStreamCallbackTimeInfo *, unsigned long, void *)') [-Wincompatible-function-pointer-types]
cc:  7468 |         err = Pa_OpenDefaultStream(&stream, 0, _const_main__nb_channels, _const_main__pa_int16, _const_main__sample_rate, _const_main__frames_per_buf, &main__audio_callback, &data);
cc:       |                                                                                                                                                        ^~~~~~~~~~~~~~~~~~~~~
cc: /opt/homebrew/Cellar/portaudio/19.7.0/include/portaudio.h:941:49: note: passing argument to parameter 'streamCallback' here
cc:   941 |                               PaStreamCallback *streamCallback,
cc:       |                                                 ^
cc: 1 error generated.
================================================================
(You can pass `-cg`, or `-show-c-output` as well, to print all the C error messages).
builder error: 
==================
C error found. It should never happen, when compiling pure V code.
This is a V compiler bug, please report it using `v bug file.v`,
or goto https://github.com/vlang/v/issues/new/choose .
You can also use #help on Discord: https://discord.gg/vlang .

The types in C

https://en.wikipedia.org/wiki/C_data_types
int : 4 bytes
double : 8 bytes or 64 bits
PaError Pa_OpenDefaultStream (
    PaStream ** stream,
    int numInputChannels,
    int numOutputChannels,
    PaSampleFormat 	sampleFormat,
    double 	sampleRate,
    unsigned long framesPerBuffer,
    PaStreamCallback * streamCallback,
    void * userData 
    )

typedef void PaStream;
typedef unsigned long PaSampleFormat; = 8 bytes

typedef int PaStreamCallback(const void *input, 
    void *output, 
    unsigned long frameCount, 
    const PaStreamCallbackTimeInfo *timeInfo, 
    PaStreamCallbackFlags statusFlags, 
    void *userData)


typedef struct PaStreamCallbackTimeInfo{
    PaTime inputBufferAdcTime;  
    PaTime currentTime;         
    PaTime outputBufferDacTime; 
} PaStreamCallbackTimeInfo;

typedef double PaTime;

[jorgeluismireles]

I tested your code in Ubuntu linux and worked. I put the speakers and heard the beep. Changed only this:

#flag -L/opt/homebrew/Cellar/portaudio/19.7.0/lib
#flag -lportaudio
#flag -I/opt/homebrew/Cellar/portaudio/19.7.0/include

by this:

#pkgconfig portaudio-2.0

• Installed last tgz v19.7.0
• Unpacked and inside folder run

./configure && make
sudo make install

• Then Check lib was installed

$ pkg-config --list-all | grep portaudio
portaudio-2.0                  PortAudio - Portable audio I/O

• Very important in linux in order recent lib is found:

sudo ldconfig

• Run your program (the beep is heard):

$ v run 440hz.v 
ALSA lib pcm_dsnoop.c:601:(snd_pcm_dsnoop_open) unable to open slave
ALSA lib pcm_dmix.c:1032:(snd_pcm_dmix_open) unable to open slave
ALSA lib pcm.c:2664:(snd_pcm_open_noupdate) Unknown PCM cards.pcm.rear
ALSA lib pcm.c:2664:(snd_pcm_open_noupdate) Unknown PCM cards.pcm.center_lfe
ALSA lib pcm.c:2664:(snd_pcm_open_noupdate) Unknown PCM cards.pcm.side
Cannot connect to server socket err = No such file or directory
Cannot connect to server request channel
jack server is not running or cannot be started
JackShmReadWritePtr::~JackShmReadWritePtr - Init not done for -1, skipping unlock
JackShmReadWritePtr::~JackShmReadWritePtr - Init not done for -1, skipping unlock
Cannot connect to server socket err = No such file or directory
Cannot connect to server request channel
jack server is not running or cannot be started
JackShmReadWritePtr::~JackShmReadWritePtr - Init not done for -1, skipping unlock
JackShmReadWritePtr::~JackShmReadWritePtr - Init not done for -1, skipping unlock
ALSA lib pcm_oss.c:397:(_snd_pcm_oss_open) Cannot open device /dev/dsp
ALSA lib pcm_oss.c:397:(_snd_pcm_oss_open) Cannot open device /dev/dsp
ALSA lib confmisc.c:160:(snd_config_get_card) Invalid field card
ALSA lib pcm_usb_stream.c:482:(_snd_pcm_usb_stream_open) Invalid card 'card'
ALSA lib confmisc.c:160:(snd_config_get_card) Invalid field card
ALSA lib pcm_usb_stream.c:482:(_snd_pcm_usb_stream_open) Invalid card 'card'
ALSA lib pcm_dmix.c:1032:(snd_pcm_dmix_open) unable to open slave
PLay a sound of 440 Hz...
^CTerminated by signal  2 (SIGINT)

So I think your code is Ok, maybe a MAC (I don't have) issue.

[AudioNiceMicroController]

Hello,

Here the solution : define the callback type :

type PaStreamCallback = fn (input voidptr, output voidptr, frame_count u64, time_info &C.PaStreamCallbackTimeInfo, status_flags u64, user_data voidptr) int

and

tream_callback PaStreamCallback,// or stream_callback &PaStreamCallback (with &)

in

fn C.Pa_OpenDefaultStream(
    stream &PaStream,
    num_input_channels int,
    num_output_channels int,
    sample_format PaSampleFormat,
    sample_rate f64,
    frames_per_buffer u64,
    stream_callback PaStreamCallback,// or stream_callback &PaStreamCallback (with &)
    user_data voidptr
)int

Final code :

module main
import math
import time

#flag -L/opt/homebrew/Cellar/portaudio/19.7.0/lib
#flag -lportaudio
#flag -I/opt/homebrew/Cellar/portaudio/19.7.0/include

#include <stdio.h>
#include <portaudio.h>

const two_pi          = 6.283185307179586
const sample_rate     = 44100
const frames_per_buf  = 64
const nb_channels     = 1
const pa_int16        = 0x00000008
const pa_no_error     = 0

type PaStream = voidptr
type PaSampleFormat = u64
struct C.PaStreamCallbackTimeInfo {
    input_buffer_adc_time f64
    current_time f64
    output_buffer_dac_time f64
}
type PaStreamCallback = fn (input voidptr, output voidptr, frame_count u64, time_info &C.PaStreamCallbackTimeInfo, status_flags u64, user_data voidptr) int
fn audio_callback( input voidptr, output voidptr, frame_count u64, time_info &C.PaStreamCallbackTimeInfo, status_flags u64, user_data voidptr) int {
    mut data := unsafe { &ToneData(user_data) }
    out := &i16(output)

    for i := 0; i < int(frame_count); i++ {
        sample := f32(math.sin(f64(data.phase)) * 32767)
        unsafe {
            out[i] = i16(sample)
        }
        data.phase += f32(two_pi * f64(data.frequency) / sample_rate)
        if data.phase > f32(two_pi) {
            data.phase -= f32(two_pi)
        }
    }
    return 0 // paContinue
}

fn C.Pa_Initialize() int
fn C.Pa_Terminate()
fn C.Pa_GetErrorText(err int) &char
fn C.Pa_StartStream(stream voidptr) int
fn C.Pa_StopStream(stream voidptr) int
fn C.Pa_CloseStream(stream voidptr) int
fn C.Pa_Sleep(msecs int)
fn C.Pa_OpenDefaultStream(
    stream &PaStream,
    num_input_channels int,
    num_output_channels int,
    sample_format PaSampleFormat,
    sample_rate f64,
    frames_per_buffer u64,
    stream_callback PaStreamCallback,// or stream_callback &PaStreamCallback (with &)
    user_data voidptr
)int


struct ToneData {
    mut:
    phase     f32
    frequency f32
}


fn main() {
    mut data := ToneData{
        phase: 0
        frequency: 440
    }

    // Initialiser PortAudio
    mut err := C.Pa_Initialize()
    if err != pa_no_error {
        println('Error Pa_Initialize: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        return
    }
    mut stream := voidptr(0)

    // Ouvrir le flux audio
    err = C.Pa_OpenDefaultStream(&stream, 0, nb_channels, pa_int16, sample_rate,
                                 frames_per_buf, &audio_callback, &data)
    if err != pa_no_error {
        println('Erreur Pa_OpenDefaultStream: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        C.Pa_Terminate()
        return
    }

    err = C.Pa_StartStream(stream)
    if err != pa_no_error {
        println('Error Pa_StartStream: ' + unsafe {cstring_to_vstring(C.Pa_GetErrorText(err))})
        C.Pa_Terminate()
        return
    }

    println('PLay a sound of ${int(data.frequency)} Hz...')
    time.sleep(1 * time.second)

    C.Pa_StopStream(stream)
    C.Pa_CloseStream(stream)
    C.Pa_Terminate()
}