Add load-annotations function

Author: weavejester

src/integrant/core.cljc

@@ -266,6 +266,28 @@
           (doseq [[tag parents] hierarchy, parent parents]
             (derive tag parent)))))))
 
+#?(:clj
+   (defn load-annotations
+     "Search the base classpath for all resources that share the same path
+     (by default `integrant/annotations.edn`), and use their contents to
+     add annotations to namespaced keywords via [[annotate]]. This allows
+     annotations to be specified without needing to load every namespace.
+
+     The annoation resources should be edn files that map namespaced keywords
+     to maps of annotation metadata. For example:
+
+         {:example/keyword {:doc \"An example keyword.\"}}
+
+     This is equivalent to:
+
+         (annotate :example/keyword {:doc \"An example keyword.\"})"
+     ([] (load-annotations "integrant/annotations.edn"))
+     ([path]
+      (doseq [url (resources path)]
+        (let [annotations (edn/read-string (slurp url))]
+          (doseq [[kw metadata] annotations]
+            (annotate kw metadata)))))))
+
 (defn- missing-refs-exception [config refs]
   (ex-info (str "Missing definitions for refs: " (str/join ", " refs))
            {:reason ::missing-refs

test/integrant/annotations.edn

@@ -0,0 +1 @@
+{:integrant.core-test/a {:doc "A test keyword."}}

test/integrant/core_test.cljc

@@ -129,6 +129,14 @@
          (underive :example/child :example/father)
          (underive :example/child :example/mother)))))
 
+#?(:clj
+   (deftest load-annotations-test
+     (try
+       (ig/load-annotations)
+       (is (= {:doc "A test keyword."} (ig/describe ::a)))
+       (finally
+         (ig/annotate ::a {})))))
+
 #?(:clj
    (deftest load-namespaces-test
      (testing "all namespaces"