Books.xrm

output r2rml

map Book from wikibus.books {
	subject template bookId with Id;

	graphs
		template bookId with Id;

	properties
	    rdf.^type template "api/Book" ;
		bibo.pages from Pages;
		dcterms.date from Year with datatype xsd.gYear;
		dcterms.description from Notes;
		dcterms.title from BookTitle;
		schema.isbn from BookISBN;
		dcterms.language template languageId with Language;
		schema.image template imageId with SourceType LegacyImage;
}

map BookGenerated from wikibus.books {
	subject template bookId with Id;

	graphs
		template bookGenerated with Id;

	properties
		dcterms.created from DateCreated;
		dcterms.modified from DateUpdated;
		wbo.migrated constant "true";
}

map BookAuthors from wikibus.bookAuthors {
	subject template bookId with Id;

	graphs
		template bookId with Id;

	properties
		schema.author template "book-{0}-author" with AuthorId as BlankNode;
}

map BookAuthorNames from wikibus.bookAuthors {
	subject template "book-{0}-author" with AuthorId as BlankNode;

	graphs
		template bookId with Id;

	properties
		schema.name from Author;
}