fix: pass auxiliary_tenant_ids to ARM client options for cross-tenant authentication

[teowa]

Fixes #419

Both AdditionallyAllowedTenants and AuxiliaryTenants needs to be set for cross-tenant auth, ref: Azure/azure-sdk-for-go#17159 (comment)

[magodo]

LGTM as long as the manual test passes.

[teowa]

test:
auth: Multi-tenant application with Service Principal and a Client Secret
test config (following the case in azure doc):

terraform {
  required_providers {
    azapi = {
      source = "Azure/azapi"
    }
  }
}

# Primary tenant/subscription variables
variable "primary_tenant_id" {
  type        = string
  description = "The tenant ID for the primary Azure provider"
  default     = ""
}

variable "primary_subscription_id" {
  type        = string
  description = "The subscription ID for the primary Azure provider"
  default     = ""
}

# Cross-tenant variables
variable "cross_tenant_id" {
  type        = string
  description = "The tenant ID for the cross-tenant Azure provider"
  default     = ""
}

variable "cross_subscription_id" {
  type        = string
  description = "The subscription ID for the cross-tenant Azure provider"
  default     = ""
}

variable "resource_name" {
  type    = string
  default = "acctest0001"
}

variable "location" {
  type    = string
  default = "westeurope"
}

provider "azapi" {
  subscription_id = var.primary_subscription_id
  tenant_id       = var.primary_tenant_id
}

provider "azapi" {
  alias                = "cross"
  subscription_id      = var.cross_subscription_id
  tenant_id            = var.cross_tenant_id
  auxiliary_tenant_ids = [var.primary_tenant_id]
}

resource "azapi_resource" "resourceGroup" {
  type     = "Microsoft.Resources/resourceGroups@2020-06-01"
  name     = var.resource_name
  location = var.location
}

resource "azapi_resource" "networkManager" {
  type      = "Microsoft.Network/networkManagers@2022-09-01"
  parent_id = azapi_resource.resourceGroup.id
  name      = var.resource_name
  location  = var.location
  body = {
    properties = {
      description = ""
      networkManagerScopeAccesses = [
        "Routing",
      ]
      networkManagerScopes = {
        managementGroups = [
        ]
        subscriptions = [
          "/subscriptions/${var.primary_subscription_id}"
        ]
      }
    }
  }
  schema_validation_enabled = false
  response_export_values    = ["*"]
}

resource "azapi_resource" "networkManagerConnection" {
  provider  = azapi.cross
  type      = "Microsoft.Network/networkManagerConnections@2022-09-01"
  parent_id = "/subscriptions/${var.cross_subscription_id}"
  name      = var.resource_name
  body = {
    properties = {
      networkManagerId = azapi_resource.networkManager.id
    }
  }
  schema_validation_enabled = false
  response_export_values    = ["*"]
}

log