🍱 [Mob372] ツタンカーメンv2を作成

Asset/data/asset/functions/mob/0372.tutankhamen/_index.d.mcfunction

@@ -0,0 +1,88 @@
+#> asset:mob/0372.tutankhamen/_index.d
+# @private
+
+#> tag
+# @within function asset:mob/0372.tutankhamen/**
+#>スキルリスト
+#declare tag AC.Laser
+#declare tag AC.ManyShoot
+#declare tag AC.GiantSkull
+#declare tag AC.HyperLaser
+#declare tag AC.DashSlash
+#declare tag AC.DashSlash.IsNearPlayer
+#declare tag AC.ManyLaser
+#declare tag AC.Charge
+#> ダッシュリスト
+#declare tag AC.Dash.Left
+#declare tag AC.Dash.Right
+#declare tag AC.Dash.Side
+#declare tag AC.Dash.Slash
+#declare tag AC.Dash.Charge
+#> 状態タグ
+#declare tag AC.Health.50Per
+#> 動作タグ
+#declare tag AC.Moveset.Transition
+#>その他タグ
+#declare tag AC.InAction
+#declare tag AC.DashUsed
+#declare tag AC.LaserDisplay
+#declare tag AC.Coffin
+#declare tag AC.CoffinPoint
+#declare tag AC.SpawnMarker
+#declare tag AC.AJ
+#declare tag AC.AJLink
+#declare tag AC.Opening
+#declare tag AC.Hit
+#declare tag AC.RotationMarker
+#declare tag Target
+#declare score_holder $Recursive
+#declare score_holder $Random
+#declare score_holder $Interval
+#>Animated Java
+#declare function animated_java:tutankhamen/summon
+#declare function animated_java:tutankhamen/remove/this
+#declare function animated_java:tutankhamen/summon
+#declare function animated_java:tutankhamen/animations/neutral/play
+#declare function animated_java:tutankhamen/animations/neutral/tween
+#declare function animated_java:tutankhamen/animations/neutral/stop
+#declare function animated_java:tutankhamen/animations/spawn/play
+#declare function animated_java:tutankhamen/animations/spawn/stop
+#declare function animated_java:tutankhamen/animations/death/play
+#declare function animated_java:tutankhamen/animations/death/stop
+#declare function animated_java:tutankhamen/animations/beam_shot/play
+#declare function animated_java:tutankhamen/animations/beam_shot/stop
+#declare function animated_java:tutankhamen/animations/beam_end/stop
+#declare function animated_java:tutankhamen/animations/soul_shot/play
+#declare function animated_java:tutankhamen/animations/soul_shot/stop
+#declare function animated_java:tutankhamen/animations/beam_long/play
+#declare function animated_java:tutankhamen/animations/beam_long/stop
+#declare function animated_java:tutankhamen/animations/beam_long/tween
+#declare function animated_java:tutankhamen/animations/beam_long_charge/play
+#declare function animated_java:tutankhamen/animations/beam_long_charge/stop
+#declare function animated_java:tutankhamen/animations/beam_long_shot/play
+#declare function animated_java:tutankhamen/animations/beam_long_shot/stop
+#declare function animated_java:tutankhamen/animations/rod_ground/tween
+#declare function animated_java:tutankhamen/animations/rod_ground_end/tween
+#declare function animated_java:tutankhamen/animations/dash/play
+#declare function animated_java:tutankhamen/animations/dash/tween
+#declare function animated_java:tutankhamen/animations/dash/stop
+#declare function animated_java:tutankhamen/animations/dash_slash/play
+#declare function animated_java:tutankhamen/animations/dash_slash/tween
+#declare function animated_java:tutankhamen/animations/dash_slash/stop
+#declare function animated_java:tutankhamen/animations/dash_end/play
+#declare function animated_java:tutankhamen/animations/dash_end/tween
+#declare function animated_java:tutankhamen/animations/dash_end/stop
+#declare function animated_java:tutankhamen/animations/attack_melee_1/tween
+#declare function animated_java:tutankhamen/animations/attack_dash_1/tween
+#declare function animated_java:tutankhamen/animations/attack_dash_2/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_windup/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_loop/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_end/tween
+#declare function animated_java:tutankhamen/animations/damage/tween
+#declare function animated_java:tutankhamen/animations/soul_shot/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_2_windup/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_2_loop/tween
+#declare function animated_java:tutankhamen/animations/attack_laser_2_end/tween
+
+#declare tag AC.ModelLocator.Body
+#declare tag AC.ModelLocator.Weapon

Asset/data/asset/functions/mob/0372.tutankhamen/death/.mcfunction

@@ -0,0 +1,24 @@
+#> asset:mob/0372.tutankhamen/death/
+#
+# Mobの死亡時の処理
+#
+# @within function asset:mob/alias/372/death
+
+# super.death呼び出し
+    function asset:mob/super.death
+
+# SpawnMarkerを削除
+    kill @e[type=marker,tag=AC.SpawnMarker,distance=..128]
+
+# CoffinPointを削除
+    kill @e[type=marker,tag=AC.CoffinPoint,distance=..128]
+
+# 付近の棺を全部片付ける
+    execute as @e[type=polar_bear,scores={MobID=374},distance=..128] run function api:mob/kill
+
+# 自分のモデルを片付ける
+    execute as @e[type=item_display,tag=AC.AJ,distance=..100,sort=nearest,limit=1] run function animated_java:tutankhamen/remove/this
+
+# 撃破演出用オブジェクトを召喚
+    data modify storage api: Argument.ID set value 2093
+    execute facing entity @p[distance=..64] eyes run function api:object/summon

Asset/data/asset/functions/mob/0372.tutankhamen/hurt/.mcfunction

@@ -0,0 +1,24 @@
+#> asset:mob/0372.tutankhamen/hurt/
+#
+# Mobのダメージ時の処理
+#
+# @within function asset:mob/alias/372/hurt
+
+#>ヘルス割合用のスコアホルダー
+# @private
+    #declare score_holder $HealthPercent
+
+# HP割合を取得
+    function api:mob/get_health_percent
+
+# 代入する
+    execute store result score $HealthPercent Temporary run data get storage api: Return.HealthPer 100
+
+# HP50%以下時
+    execute if entity @s[tag=!AC.Health.50Per] if score $HealthPercent Temporary matches ..50 run function asset:mob/0372.tutankhamen/hurt/active_50per
+
+# リセット
+    scoreboard players reset $HealthPercent Temporary
+
+# super.hurt呼び出し
+    function asset:mob/super.hurt

Asset/data/asset/functions/mob/0372.tutankhamen/hurt/active_50per.mcfunction

@@ -0,0 +1,23 @@
+#> asset:mob/0372.tutankhamen/hurt/active_50per
+#
+#
+#
+# @within function asset:mob/0372.tutankhamen/hurt/
+
+# フェイズ移行動作を実行
+    tag @s add AC.Moveset.Transition
+
+# 無敵になる
+    data modify entity @s Invulnerable set value 1b
+    tag @s add Uninterferable
+
+# サウンド
+    playsound minecraft:entity.blaze.hurt hostile @a ~ ~ ~ 1.5 0.5
+    playsound minecraft:entity.wither_skeleton.death hostile @a ~ ~ ~ 1.5 1.5
+    playsound minecraft:entity.player.breath hostile @a ~ ~ ~ 1.5 0.8
+
+# 全動作強制リセット
+    function asset:mob/0372.tutankhamen/tick/skill/reset
+
+# スコアリセット
+    scoreboard players set @s General.Mob.Tick -1

Asset/data/asset/functions/mob/0372.tutankhamen/init/.mcfunction

@@ -0,0 +1,35 @@
+#> asset:mob/0372.tutankhamen/init/
+#
+# Mobのinit時の処理
+#
+# @within asset:mob/alias/372/init
+
+# super.init呼び出し
+    function asset:mob/super.init
+
+# 召喚位置を記録するマーカーを召喚
+    summon marker ~ ~ ~ {Tags:["AC.SpawnMarker"]}
+
+# 棺召喚位置用markerを召喚
+    execute rotated ~0 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[180.0f,0.0f]}
+    execute rotated ~45 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[225.0f,0.0f]}
+    execute rotated ~90 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[270.0f,0.0f]}
+    execute rotated ~135 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[315.0f,0.0f]}
+    execute rotated ~180 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[0.0f,0.0f]}
+    execute rotated ~225 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[45.0f,0.0f]}
+    execute rotated ~270 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[90.0f,0.0f]}
+    execute rotated ~315 0 positioned ^ ^ ^12 run summon marker ~ ~ ~ {Tags:["AC.CoffinPoint"],Rotation:[135.0f,0.0f]}
+
+# AJ召喚
+    execute rotated ~ 0 run function animated_java:tutankhamen/summon {args:{}}
+
+# tpさせる
+# AC.AJはAJリポジトリ側で召喚時に付与されている
+    execute at @s as @e[type=item_display,tag=AC.AJ,sort=nearest,limit=1] run tp @s ~ ~ ~
+
+# スコア初期化
+    scoreboard players set @s General.Mob.Tick -1
+    scoreboard players set @s AC.Count.Dash 0
+
+# 召喚モーション用Tagを自身に付与
+    tag @s add AC.Opening

Asset/data/asset/functions/mob/0372.tutankhamen/load.mcfunction

@@ -0,0 +1,10 @@
+#> asset:mob/0372.tutankhamen/load
+#
+# Mobに利用するスコアボード等の初期化処理
+#
+# @within tag/function asset:mob/load
+
+#> 定義類はここに
+# @within function asset:mob/0372.tutankhamen/**
+    scoreboard objectives add AC.TargetID dummy
+    scoreboard objectives add AC.Count.Dash dummy

Asset/data/asset/functions/mob/0372.tutankhamen/register.mcfunction

@@ -0,0 +1,69 @@
+#> asset:mob/0372.tutankhamen/register
+#
+# Mobのデータを指定
+#
+# @within function asset:mob/alias/372/register
+
+# 継承　
+    data modify storage asset:mob Extends append value 2000
+    function asset:mob/extends
+
+# 他のモブに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:mob ExtendsSafe set value
+# 継承されることを前提とした、抽象的なモブであるかどうか(boolean)
+    data modify storage asset:mob IsAbstract set value false
+# ID (int)
+    data modify storage asset:mob ID set value 372
+# Type (string) Wikiを参照
+    data modify storage asset:mob Type set value "Enemy.Boss"
+# 干渉可能か否か (boolean)
+    data modify storage asset:mob Interferable set value true
+# 名前 (TextComponentString) (オプション)
+    data modify storage asset:mob Name set value '{"text":"ツタンカーメン","color":"#13b3aa"}'
+# Mobの説明文 (TextComponentString[]) (オプション)
+    data modify storage asset:mob Lore set value ['{"text":"その名は有名なファラオを彷彿とさせるが、","color":"white"}','{"text":"この天使は、様々な歴史や、人々の持つイメージなどを元に作り上げられた存在でしかない。","color":"white"}','{"text":"一体どんなイメージが紛れ込んだのか、この天使は魔術と剣術、両方に秀でている。","color":"white"}']
+# 武器
+    # メインハンド (Compound(Item)) (オプション)
+        # data modify storage asset:mob Weapon.Mainhand set value
+    # オフハンド (Compound(Item)) (オプション)
+        # data modify storage asset:mob Weapon.Offhand set value
+# 武器ドロップ率 ([float, float]) (オプション)
+    # data modify storage asset:mob WeaponDropChances set value
+# 防具
+    # 頭 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Head set value
+    # 胴 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Chest set value
+    # 脚 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Legs set value
+    # 足 (Compound(Item)) (オプション)
+        # data modify storage asset:mob Armor.Feet set value
+# 防具ドロップ率 ([float, float]) (オプション)
+    # data modify storage asset:mob ArmorDropChances set value
+# 体力 (double) (オプション)
+    data modify storage asset:mob Health set value 350000d
+# 攻撃力 (double) (オプション)
+    data modify storage asset:mob AttackDamage set value 0.0d
+# 防御力 (double) (オプション) // 被ダメージがある程度大きい場合1ptにつき0.8%カット、小さい場合1ptにつき約4%カット 20pt以上は頭打ち
+    # data modify storage asset:mob Defense set value
+# 特殊防御力 (double) (オプション) // 4pointにつきダメージを大きく減らす
+    # data modify storage asset:mob SpecialDefense set value
+# 移動速度 (double) (オプション)
+    data modify storage asset:mob Speed set value 0.0d
+# 索敵範囲 (double) (オプション)
+    # data modify storage asset:mob FollowRange set value
+# ノックバック耐性 (double) (オプション)
+    # data modify storage asset:mob KnockBackResist set value
+# 属性倍率 // 1.0fで100% 最低でも25%は軽減されずに入る
+    # 物理倍率 (float) (オプション)
+        # data modify storage asset:mob Resist.Physical set value
+    # 魔法倍率 (float) (オプション)
+        # data modify storage asset:mob Resist.Magic set value
+    # 火倍率 (float) (オプション)
+        # data modify storage asset:mob Resist.Fire set value
+    # 水倍率 (float) (オプション)
+        # data modify storage asset:mob Resist.Water set value
+    # 雷倍率 (float) (オプション)
+        # data modify storage asset:mob Resist.Thunder set value
+# フィールド
+    data modify storage asset:mob Field.Damage.ManyShoot set value 25f

Asset/data/asset/functions/mob/0372.tutankhamen/remove/.mcfunction

@@ -0,0 +1,17 @@
+#> asset:mob/0372.tutankhamen/remove/
+#
+# 天使が居なくなる際に実行される処理
+#
+# @within asset:mob/alias/372/remove
+
+# super.remove呼び出し
+    function asset:mob/super.remove
+
+# SpawnMarkerを削除
+    kill @e[type=marker,tag=AC.SpawnMarker]
+
+# CoffinPointを削除
+    kill @e[type=marker,tag=AC.CoffinPoint]
+
+# AJ削除
+    execute at @s as @e[type=item_display,tag=AC.AJ,distance=..100,sort=nearest,limit=1] run function animated_java:tutankhamen/remove/this

Asset/data/asset/functions/mob/0372.tutankhamen/summon/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:mob/0372.tutankhamen/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:mob/alias/372/summon
+
+# 元となるEntityを召喚する
+    summon wither_skeleton ~ ~ ~ {NoAI:1b,Tags:["MobInit","AlwaysInvisible"],DeathLootTable:"empty"}

Asset/data/asset/functions/mob/0372.tutankhamen/summon/debug.mcfunction

@@ -0,0 +1,10 @@
+#> asset:mob/0372.tutankhamen/summon/debug
+#
+# 動作チェック用の召喚処理 使い終わったら消してもいいかも
+#
+# @user
+# @private
+
+# 召喚
+   data modify storage api: Argument.ID set value 372
+   function api:mob/summon

Asset/data/asset/functions/mob/0372.tutankhamen/tick/.mcfunction

@@ -0,0 +1,39 @@
+#> asset:mob/0372.tutankhamen/tick/
+#
+# Mobのtick時の処理
+#
+# @within asset:mob/alias/372/tick
+
+# スコア
+    scoreboard players add @s General.Mob.Tick 1
+
+# AJモデルとの紐づけ
+    execute at @s run tag @e[type=item_display,tag=AC.AJ,distance=..16,sort=nearest,limit=1] add AC.AJLink
+
+# モデルを追従
+    execute at @s run tp @e[type=item_display,tag=AC.AJLink,distance=..16,sort=nearest,limit=1] ~ ~ ~ ~ ~
+
+# フェイズ移行動作
+    execute if entity @s[tag=AC.Moveset.Transition] run function asset:mob/0372.tutankhamen/tick/phase_transition/
+
+# スキル選択 開幕は実行しない
+    execute if entity @s[tag=AC.DashUsed,tag=!AC.Moveset.Transition,tag=!AC.InAction,tag=!AC.Opening] if score @s General.Mob.Tick matches 0 run function asset:mob/0372.tutankhamen/tick/skill_select
+
+# ダッシュ選択 開幕は実行しないし、スキル中も使用しない
+    execute if entity @s[tag=!AC.InAction,tag=!AC.Moveset.Transition,tag=!AC.Opening] if score @s General.Mob.Tick matches 0 run function asset:mob/0372.tutankhamen/tick/dash_select
+
+# スキル実行
+    execute if entity @s[tag=!AC.Moveset.Transition] if score @s General.Mob.Tick matches 0.. run function asset:mob/0372.tutankhamen/tick/skill_branch
+
+# 本気のパーティクル
+    execute if entity @s[tag=AC.Health.50Per,tag=!AC.Moveset.Transition] if predicate lib:random_pass_per/50 run particle soul_fire_flame ~ ~1 ~ 0.3 0.5 0.3 0.02 1 force @a[distance=..64]
+    execute if entity @s[tag=AC.Health.50Per,tag=!AC.Moveset.Transition] if predicate lib:random_pass_per/50 run particle dust 0 1 1 1 ~ ~1 ~ 0.3 0.5 0.3 0.02 1 force @a[distance=..64]
+
+# 足元に何もなければ
+    execute if block ~ ~-0.2 ~ #lib:no_collision run particle minecraft:enchant ~ ~ ~ 0.4 0 0.4 0 10
+
+# 足元が埋まっている間は上にちょっとずつ登る
+    execute unless block ~ ~ ~ #lib:no_collision run tp @s ~ ~0.1 ~
+
+# AJモデルとの紐づけ解除
+    execute at @s run tag @e[type=item_display,tag=AC.AJLink,distance=..0.01,sort=nearest,limit=1] remove AC.AJLink

Asset/data/asset/functions/mob/0372.tutankhamen/tick/dash_select.mcfunction

@@ -0,0 +1,34 @@
+#> asset:mob/0372.tutankhamen/tick/dash_select
+#
+#
+#
+# @within function asset:mob/0372.tutankhamen/tick/
+
+#> private
+# @private
+    #declare score_holder $Random
+
+# 行動中扱いにする
+    tag @s add AC.InAction
+
+# ダッシュ使ったことにする
+    tag @s add AC.DashUsed
+
+# 乱数によるスキル選択
+    data modify storage lib: Args.key set value "0372.Dash"
+    data modify storage lib: Args.max set value 4
+    data modify storage lib: Args.scarcity_history_size set value 3
+    execute store result score $Random Temporary run function lib:random/with_biased/manual.m with storage lib: Args
+
+# デバッグのコマンド
+#    scoreboard players set $Random Temporary 3
+
+# スキル選択
+    execute if score $Random Temporary matches 0..1 run tag @s add AC.Dash.Side
+    execute if score $Random Temporary matches 0 run tag @s add AC.Dash.Left
+    execute if score $Random Temporary matches 1 run tag @s add AC.Dash.Right
+    execute if score $Random Temporary matches 2 run tag @s add AC.Dash.Slash
+    execute if score $Random Temporary matches 3 run tag @s add AC.Dash.Charge
+
+# リセット
+    scoreboard players reset $Random Temporary