add motrix for aarch64

alarmcn/electron22-bin/.gitignore

@@ -0,0 +1,5 @@
+*.zip
+src/
+*.log
+pkg/
+*.pkg.*

alarmcn/electron22-bin/PKGBUILD

@@ -0,0 +1,55 @@
+# Maintainer: Yurii Kolesnykov <[email protected]>
+# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
+
+_projectname=electron
+_major=22
+_pkgname="${_projectname}${_major}"
+pkgname="${_pkgname}"-bin
+_subver="3.7"
+_pkgver="${_major}.${_subver}"
+pkgver="${_pkgver/-/.}"
+pkgrel=1
+pkgdesc="Build cross platform desktop apps with web technologies - Binary version ${_major}"
+arch=('x86_64' 'aarch64')
+url=https://electronjs.org/
+license=('MIT' 'custom')
+depends=('c-ares' 'gtk3' 'libevent' 'nss' 'wayland')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+            'libappindicator-gtk3: StatusNotifierItem support'
+            'pipewire: WebRTC desktop sharing under Wayland'
+            'qt5-base: enable Qt5 with --enable-features=AllowQt'
+            'trash-cli: file deletion support (trash-put)'
+            'xdg-utils: open URLs with desktop’s default (xdg-email, xdg-open)')
+provides=("${_pkgname}=${pkgver}" "${_projectname}=${pkgver}")
+conflicts=("${_pkgname}")
+_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
+source_x86_64=(
+	"${pkgname}-chromedriver-${pkgver}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
+	"${pkgname}-${pkgver}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
+)
+source_aarch64=(
+	"${pkgname}-chromedriver-${pkgver}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
+	"${pkgname}-${pkgver}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
+)
+sha256sums_x86_64=('03ac9d284f8102565981af295fc123866acf707379797655ab5bfbf7566dce00'
+                   'a04a8e95032e13808c6da3a244739edecbdb25e34accc8a8a53db257f225a5c9')
+sha256sums_aarch64=('2606c9c28c7f0ed71da82d3df93407695e2eb57b00306dfdbc769e5fe39c1cdc'
+                    'b5bbad04b7f0b646073e70d2abf5cef5708aa38f229604ca952dcc773c024609')
+
+package() {
+	install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
+
+	for _folder in 'locales' 'resources'; do
+		cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
+	done
+
+	chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
+	done
+}

alarmcn/motrix/PKGBUILD

@@ -0,0 +1,72 @@
+# Maintainer: zhullyb <zhullyb [at] outlook dot com>
+# Contributor: weearc <q19981121 [at] 163 dot com>
+# Contributor: JimMoen <LnJimMoen [at] outlook dot com>
+pkgname=motrix
+_pkgname=Motrix
+pkgver=1.8.19
+pkgrel=4
+epoch=
+pkgdesc="A full-featured download manager (release version)"
+arch=("aarch64")
+url="https://github.com/agalwood/Motrix"
+license=('MIT')
+groups=()
+depends=('gtk3' 'libxcb' 'electron22-bin')
+makedepends=('npm' 'yarn' 'nodejs' 'python')
+checkdepends=()
+optdepends=()
+provides=()
+conflicts=('motrix-git')
+replaces=()
+backup=()
+options=()
+install=
+changelog=
+source=("motrix.desktop"
+    "motrix"
+    "https://github.com/agalwood/Motrix/archive/v${pkgver}.tar.gz")
+noextract=()
+sha256sums=('c5f185162cdb83c387399e314be355585837a9efcd8ac35425656e4d24f7a5b3'
+            'bb1432adbac2120ef5c59d718f1cd48ef5fc920d3d1231ba32390c700465f3a5'
+            'd2a48692549d426e9dfa0fad9897dddf200b7b82198d59e64819d419114a10d8')
+validpgpkeys=()
+
+#_ensure_local_nvm() {
+    # let's be sure we are starting clean
+#    which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
+#    export NVM_DIR="${srcdir}/.nvm"
+
+    # The init script returns 3 if version specified
+    # in ./.nvrc is not (yet) installed in $NVM_DIR
+    # but nvm itself still gets loaded ok
+#    source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
+#}
+
+#prepare() {
+#    _ensure_local_nvm
+#    nvm install 14
+#}
+
+build() {
+    cd ${srcdir}/${_pkgname}-${pkgver}
+#    _ensure_local_nvm
+    export YARN_CACHE_FOLDER="${srcdir}/yarn_cache"
+    yarn
+    yarn run build:dir
+}
+
+package() {
+
+    install -Dm 644 ${srcdir}/${_pkgname}-${pkgver}/release/linux-*unpacked/resources/app.asar ${pkgdir}/usr/lib/${pkgname}/app.asar
+    install -Dm 755 ${srcdir}/${_pkgname}-${pkgver}/release/linux-*unpacked/resources/engine/aria2c ${pkgdir}/usr/lib/${pkgname}/engine/aria2c
+    install -Dm 644 ${srcdir}/${_pkgname}-${pkgver}/release/linux-*unpacked/resources/engine/aria2.conf ${pkgdir}/usr/lib/${pkgname}/engine/aria2.conf
+
+    # binary wrapper
+    install -Dm 775 ${srcdir}/motrix ${pkgdir}/usr/bin/${pkgname}
+
+    # desktop enrty
+    install -Dm 644 ${srcdir}/motrix.desktop ${pkgdir}/usr/share/applications/${pkgname}.desktop
+
+    # icons
+    install -Dm 644 ${srcdir}/${_pkgname}-${pkgver}/build/256x256.png ${pkgdir}/usr/share/icons/${pkgname}.png
+}

alarmcn/motrix/lilac.yaml

@@ -0,0 +1,12 @@
+maintainers:
+  - github: zhullyb
+
+pre_build_script: aur_pre_build(maintainers=['zhullyb'])
+
+post_build: aur_post_build
+
+update_on:
+  - source: aur
+    aur: motrix
+  - source: manual
+    manual: 1

alarmcn/motrix/motrix

@@ -0,0 +1,3 @@
+#!/bin/bash
+export ELECTRON_IS_DEV=0
+exec /usr/bin/electron22 /usr/lib/motrix/app.asar "$@"

alarmcn/motrix/motrix.desktop

@@ -0,0 +1,11 @@
+[Desktop Entry]
+Name=Motrix
+Comment=A full-featured download manager. 
+Keywords=
+Exec=motrix &U
+TryExec=
+Terminal=false
+Icon=/usr/share/icons/motrix.png
+Type=Application
+StartupNotify=false
+Categories=Network;FileTransfer;